Erste Fehlermeldung Prozedur zu groß " in VBA-Makros (Excel)

Ich bin immer Procedure too Large Error in einem VBA-makro.

Ich bin mit MS-Excel 2003.

Bitte schreiben Sie niemals Prozeduren, die mehr als 65534 Zeilen code.
Ich glaube, es ist nicht die Anzahl der Zeilen zählt. Kann man diesen Fehler in 4k-Linien als auch. Es ist die Größe des Verfahrens. Die Verfahren, die bei der Kompilierung nicht überschreiten 64kilobytes. Niraj, brechen Sie Ihr Verfahren in kleinere Teile und wenn Sie ein makro aufgezeichnet haben, dann löschen Sie irrelevante code.
Dank Siddharth
Mehr als 64kb. Ich bin beeindruckt. Und ratlos.
Nur als Randbemerkung, wenn Sie hierher kommen, von google - es ist wahrscheinlich, dass Sie sehen, dieses weil Sie Links den makro-recorder laufen für eine lange Zeit

InformationsquelleAutor Code Hungry | 2012-07-12

Erhalten Sie diesen Fehler, wenn Ihre Vorgehensweise ist mehr als 64kb. Dies sind einige der Dinge, die Sie zum komprimieren der code

1) loszuwerden, sich wiederholenden code. Siehe dieses Beispiel

Sub Sample()
    Range("A1") = "Blah Blah"
    Range("A2") = "Blah Blah"
    Range("A3") = "Blah Blah"
    Range("A4") = "Blah Blah"
    Range("A5") = "Blah Blah"
    Range("A6") = "Blah Blah"
    Range("A7") = "Blah Blah"
End Sub

Dieser code kann geschrieben werden als

Sub Sample()
    For i = 1 To 7
        Range("A" & i) = "Blah Blah"
    Next i
End Sub

Weiteres Beispiel

Sub Sample()
    Range("A1") = (Range("A1") * 10) + (Range("A1") + 30) + (Range("A1") / 30)
    Range("A5") = (Range("A5") * 10) + (Range("A5") + 30) + (Range("A5") / 30)
    Range("A11") = (Range("A11") * 10) + (Range("A11") + 30) + (Range("A11") / 30)
    Range("A6") = (Range("A6") * 10) + (Range("A6") + 30) + (Range("A6") / 30)
    Range("A8") = (Range("A8") * 10) + (Range("A8") + 30) + (Range("A8") / 30)
    Range("A56") = (Range("A56") * 10) + (Range("A56") + 30) + (Range("A56") / 30)
End Sub

Dieser code kann geschrieben werden als

Sub Sample()
    Range("A1") = GetVal(Range("A1"))
    Range("A5") = GetVal(Range("A5"))
    Range("A11") = GetVal(Range("A11"))
    Range("A6") = GetVal(Range("A6"))
    Range("A8") = GetVal(Range("A8"))
    Range("A56") = GetVal(Range("A56"))
End Sub

Function GetVal(rng As Range) As Variant
    GetVal = (rng.Value * 10) + (rng.Value + 30) + (rng.Value / 30)
End Function

Dadurch wird sichergestellt, dass Sie nach unten geschnitten auf Raum und schreiben Sie keine sich wiederholenden code.

2) Wenn du den code generiert, über den makro dann bekommen Sie vielleicht so etwas wie dieses. Loszuwerden, die nutzlos code wie ActiveWindow.ScrollRow = 8968

Option Explicit

'~~> This procedure fills Excel's 10000 cells with random values and then removes the duplicates
Sub FillExcelCells()
    Dim rowCount As Long

    '~~> Activate the necesary Sheet
    Sheets("Sheet1").Activate

    '~~> Loop through all the cells and store random numbers
    For rowCount = 1 To 10000
        Sheets("Sheet1").Range("A" & rowCount).Select
        Sheets("Sheet1").Range("A" & rowCount).Value = Int((10000 - 1) * Rnd() + 1)
    Next rowCount

    '~~> Sort the Range
    Sheets("Sheet1").Range("A1").Select
    Sheets("Sheet1").Range(Selection, Selection.End(xlDown)).Select
    Application.CutCopyMode = False

    Range(Selection, Selection.End(xlDown)).Select
    ActiveWindow.SmallScroll Down:=-39
    ActiveWindow.ScrollRow = 9838
    ActiveWindow.ScrollRow = 9709
    ActiveWindow.ScrollRow = 9449
    ActiveWindow.ScrollRow = 8968
    ActiveWindow.ScrollRow = 8319
    ActiveWindow.ScrollRow = 7245
    ActiveWindow.ScrollRow = 6003
    ActiveWindow.ScrollRow = 4818
    ActiveWindow.ScrollRow = 4040
    ActiveWindow.ScrollRow = 3317
    ActiveWindow.ScrollRow = 3076
    ActiveWindow.ScrollRow = 2521
    ActiveWindow.ScrollRow = 2298
    ActiveWindow.ScrollRow = 2113
    ActiveWindow.ScrollRow = 1724
    ActiveWindow.ScrollRow = 1372
    ActiveWindow.ScrollRow = 1038
    ActiveWindow.ScrollRow = 872
    ActiveWindow.ScrollRow = 668
    ActiveWindow.ScrollRow = 538
    ActiveWindow.ScrollRow = 464
    ActiveWindow.ScrollRow = 446
    ActiveWindow.ScrollRow = 427
    ActiveWindow.ScrollRow = 409
    ActiveWindow.ScrollRow = 390
    ActiveWindow.ScrollRow = 353
    ActiveWindow.ScrollRow = 334
    ActiveWindow.ScrollRow = 297
    ActiveWindow.ScrollRow = 279
    ActiveWindow.ScrollRow = 242
    ActiveWindow.ScrollRow = 223
    ActiveWindow.ScrollRow = 205
    ActiveWindow.ScrollRow = 168
    ActiveWindow.ScrollRow = 149
    ActiveWindow.ScrollRow = 112
    ActiveWindow.ScrollRow = 94
    ActiveWindow.ScrollRow = 57
    ActiveWindow.ScrollRow = 20
    ActiveWindow.ScrollRow = 1

    Selection.Sort Key1:=Sheets("Sheet1").Range("A1"), Order1:=xlAscending, Header:=xlGuess, _
    OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom, _
    DataOption1:=xlSortNormal

    '~~> Delete duplicates
    For rowCount = 10000 To 2 Step -1
        Sheets("Sheet1").Range("A" & rowCount).Select
        If Range("A" & rowCount).Value = Range("A" & rowCount - 1).Value Then
            Sheets("Sheet1").Rows(rowCount).Delete shift:=xlUp
        End If
    Next rowCount
End Sub

Oben kann geschrieben werden als

'~~> This procedure fills Excel's 10000 cells with random values and then removes the duplicates
Sub FillExcelCells()
    Dim rowCount As Long

    With Sheets("Sheet1")
        '~~> Loop through all the cells and store random numbers
        For rowCount = 1 To 10000
            .Range("A" & rowCount).Value = Int((10000 - 1) * Rnd() + 1)
        Next rowCount

        '~~> Sort Range
        .Range("A1:A10000").Sort Key1:=.Range("A1"), Order1:=xlAscending, Header:=xlGuess, _
        OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom, DataOption1:=xlSortNormal

        '~~> Delete duplicates
        For rowCount = 10000 To 2 Step -1
            If .Range("A" & rowCount).Value = .Range("A" & rowCount - 1).Value Then
                .Rows(rowCount).Delete shift:=xlUp
            End If
        Next rowCount
    End With
End Sub

3) Erklären Sie die Objekte so, dass Sie nicht haben, um halten Sie auf, Sie zu wiederholen. Siehe dieses Beispiel

Sub Sample()
    Range("A1").Select
    ActiveCell.FormulaR1C1 = "sdasds"
    Range("A1").Select
    With Selection.Interior
        .Pattern = xlSolid
        .PatternColorIndex = xlAutomatic
        .Color = 65535
        .TintAndShade = 0
        .PatternTintAndShade = 0
    End With
    Selection.Font.Bold = True
    Selection.Font.Italic = True
    Selection.Font.Underline = xlUnderlineStyleSingle
    With Selection
        .HorizontalAlignment = xlGeneral
        .VerticalAlignment = xlBottom
        .WrapText = True
        .Orientation = 0
        .AddIndent = False
        .IndentLevel = 0
        .ShrinkToFit = False
        .ReadingOrder = xlContext
        .MergeCells = False
    End With
End Sub

Diese kann geschrieben werden als

Sub Sample()
    Dim ws As Worksheet, rng As Range

    Set ws = Sheet1

    Set rng = ws.Range("A1")

    With rng
        .FormulaR1C1 = "sdasds"
        With .Interior
            .Pattern = xlSolid
            .PatternColorIndex = xlAutomatic
            .Color = 65535
            .TintAndShade = 0
            .PatternTintAndShade = 0
        End With
        .Font.Bold = True
        .Font.Italic = True
        .Font.Underline = xlUnderlineStyleSingle
        .HorizontalAlignment = xlGeneral
        .VerticalAlignment = xlBottom
        .WrapText = True
        .Orientation = 0
        .AddIndent = False
        .IndentLevel = 0
        .ShrinkToFit = False
        .ReadingOrder = xlContext
        .MergeCells = False
    End With
End Sub

4) Brechen Ihre Vorgehensweise, wenn es sein muss. und rufen Sie die 2. Vorgehensweise aus dem 1.

5) Vermeiden Sie die Verwendung .Select und .Activate Sie nicht nur Ihr code langsamer, aber auch viel Platz in Ihrem code, wenn Sie intensiv genutzt. Wie zu verwenden Wählen Sie in der Excel-VBA-Makros

dieser hat einige gute Tipps
+1 Wo bekommen Sie die Zeit, zu schreiben, wie langwierig Antworten?
lol@PradeepKumar
Ich hatte eine Methode mit viel Round(ThisWorkbook.Worksheets("Sheet5").Range("NamedRange").Value, 5). Ich ersetzte Sie alle mit einem einzigen integer variable, so dass Round(...) war nur einmal aufgerufen. Auch dies machte die Methode leichter zu pflegen. Es läuft wahrscheinlich jetzt schneller als gut.

InformationsquelleAutor Siddharth Rout

0

Makros Größe ist beschränkt auf 64 Kb, nach denen man eine Fehlermeldung von Excel.

Ich lief in ein Problem, für das es keine Erklärung oder Fehlermeldung von Excel, wenn Excel nicht in der Lage war zu vollständig berechnen einer Arbeitsmappe für möchten von Ressourcen, wenn ich ein makro geschrieben, dass Anrufe auf mehrere andere Makros.

Ich bin davon ausgegangen, dass die Summe der Länge aller Makros in der Kette berücksichtigt werden müssen.

Dieses sieht wie Sie versuchten, Ihre eigenen Fragen stellen, anstatt eine Antwort geben.

InformationsquelleAutor Mike Benstead

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.