Excel-VBA-Funktion drucken Sie ein array, um die Arbeitsmappe

Ich habe ein makro geschrieben, das dauert ein 2-dimensionales array, und "druckt" es entspricht Zellen in einer excel-Arbeitsmappe.

Ist es ein eleganter Weg, dies zu tun?

Sub PrintArray(Data, SheetName, StartRow, StartCol)

    Dim Row As Integer
    Dim Col As Integer

    Row = StartRow

    For i = LBound(Data, 1) To UBound(Data, 1)
        Col = StartCol
        For j = LBound(Data, 2) To UBound(Data, 2)
            Sheets(SheetName).Cells(Row, Col).Value = Data(i, j)
            Col = Col + 1
        Next j
            Row = Row + 1
    Next i

End Sub


Sub Test()

    Dim MyArray(1 To 3, 1 To 3)
    MyArray(1, 1) = 24
    MyArray(1, 2) = 21
    MyArray(1, 3) = 253674
    MyArray(2, 1) = "3/11/1999"
    MyArray(2, 2) = 6.777777777
    MyArray(2, 3) = "Test"
    MyArray(3, 1) = 1345
    MyArray(3, 2) = 42456
    MyArray(3, 3) = 60

    PrintArray MyArray, "Sheet1", 1, 1

End Sub

InformationsquelleAutor Zach | 2011-05-19

Auf dem gleichen Thema wie die anderen Antworten, es einfach zu halten,

Sub PrintArray(Data As Variant, Cl As Range)
    Cl.Resize(UBound(Data, 1), UBound(Data, 2)) = Data
End Sub


Sub Test()
    Dim MyArray() As Variant

    ReDim MyArray(1 To 3, 1 To 3) ' make it flexible

    ' Fill array
    '  ...

    PrintArray MyArray, ActiveWorkbook.Worksheets("Sheet1").[A1]
End Sub

Für OLE-Automatisierung Willen, die Zuordnung zu Range tatsächlich bedeutet die Zuordnung zu seiner .Value.

InformationsquelleAutor chris neilsen

3

Erstellen Sie ein variant-array (am einfachsten durch Lesen von gleichem range in eine variant-variable).

Füllen Sie dann das array, und weisen Sie das array direkt zu dem Bereich.
```
Dim myArray As Variant

myArray = Range("blahblah")

Range("bingbing") = myArray
```
Den variant-array wird am Ende als 2-D-matrix.

InformationsquelleAutor Lance Roberts

Eine elegantere Möglichkeit ist die Zuordnung, die das gesamte array auf einmal:

Sub PrintArray(Data, SheetName, StartRow, StartCol)

    Dim Rng As Range

    With Sheets(SheetName)
        Set Rng = .Range(.Cells(StartRow, StartCol), _
            .Cells(UBound(Data, 1) - LBound(Data, 1) + StartRow, _
            UBound(Data, 2) - LBound(Data, 2) + StartCol))
    End With
    Rng.Value2 = Data

End Sub

Aber watch out: es funktioniert nur bis zu einer Größe von etwa 8.000 Zellen. Excel wirft einen seltsamen Fehler. Die maximale Größe ist nicht festgelegt und unterscheidet sich sehr von Excel-installation auf Excel-installation.

InformationsquelleAutor Codo

Können Sie einen Bereich definieren, der die Größe des Arrays, und verwenden Sie die value-Eigenschaft:

Sub PrintArray(Data, SheetName As String, intStartRow As Integer, intStartCol As Integer)

    Dim oWorksheet As Worksheet
    Dim rngCopyTo As Range
    Set oWorksheet = ActiveWorkbook.Worksheets(SheetName)

    ' size of array
    Dim intEndRow As Integer
    Dim intEndCol As Integer
    intEndRow = UBound(Data, 1)
    intEndCol = UBound(Data, 2)

    Set rngCopyTo = oWorksheet.Range(oWorksheet.Cells(intStartRow, intStartCol), oWorksheet.Cells(intEndRow, intEndCol))
    rngCopyTo.Value = Data

End Sub

InformationsquelleAutor Steve Mallory

Meine getestete version

Sub PrintArray(RowPrint, ColPrint, ArrayName, WorkSheetName)

Sheets(WorkSheetName).Range(Cells(RowPrint, ColPrint), _
Cells(RowPrint + UBound(ArrayName, 2) - 1, _
ColPrint + UBound(ArrayName, 1) - 1)) = _
WorksheetFunction.Transpose(ArrayName)

End Sub

InformationsquelleAutor Andrew Strathclyde

Als andere haben vorgeschlagen, die Sie direkt schreiben können, ein 2-dimensionales array in einen Bereich auf dem Blatt, aber wenn Ihr array eindimensionales dann haben Sie zwei Möglichkeiten:

Konvertieren Sie Ihre 1D-array in ein 2D-array zuerst, dann drucken Sie es auf dem Blatt (als Bereich).
Konvertieren Sie Ihre 1D-array in einen string und drucken Sie es in einer einzelnen Zelle (als String).

Hier ist ein Beispiel der Darstellung der beiden Optionen:

Sub PrintArrayIn1Cell(myArr As Variant, cell As Range)
    cell = Join(myArr, ",")
End Sub
Sub PrintArrayAsRange(myArr As Variant, cell As Range)
    cell.Resize(UBound(myArr, 1), UBound(myArr, 2)) = myArr
End Sub
Sub TestPrintArrayIntoSheet()  '2dArrayToSheet
    Dim arr As Variant
    arr = Split("a  b  c", "  ")

    'Printing in ONE-CELL: To print all array-elements as a single string separated by comma (a,b,c):
    PrintArrayIn1Cell arr, [A1]

    'Printing in SEPARATE-CELLS: To print array-elements in separate cells:
    Dim arr2D As Variant
    arr2D = Application.WorksheetFunction.Transpose(arr) 'convert a 1D array into 2D array
    PrintArrayAsRange arr2D, Range("B1:B3")
End Sub

Hinweis: Hierbei wird bewirkt, dass die Spalte-für-Spalte-Ausgang, um Zeile für Zeile die Ausgabe transponieren es wieder - hoffe, das macht Sinn.

HTH

InformationsquelleAutor Eddie Kumar

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.