Finden der max in einer Liste - Prolog

Ich wurde nur eingeführt, um Prolog und bin versucht zu schreiben, ein Prädikat, findet die Max-Wertes einer Liste von ganzen zahlen. Ich muss eins schreiben, der vergleicht von Anfang an und die andere, vergleicht am Ende. Bisher habe ich:

max2([],R).
max2([X|Xs], R):- X > R, max2(Xs, X).
max2([X|Xs], R):- X <= R, max2(Xs, R).

Merke ich, dass R noch nicht eingeleitet worden, noch, so es ist nicht in der Lage, einen Vergleich. Brauche ich 3 Argumente, um diese abzuschließen?

X <= R Lesen sollte X =< R
Siehe auch die Verwandte Frage: mindestens in einer Liste

InformationsquelleAutor user2796815 | 2013-11-05

meta-predicate prolog

my_max([], R, R). %end
my_max([X|Xs], WK, R):- X >  WK, my_max(Xs, X, R). %WK is Carry about
my_max([X|Xs], WK, R):- X =< WK, my_max(Xs, WK, R).
my_max([X|Xs], R):- my_max(Xs, X, R). %start

anderen Weg

%max of list
max_l([X],X) :- !, true.
%max_l([X],X). %unuse cut
%max_l([X],X):- false.
max_l([X|Xs], M):- max_l(Xs, M), M >= X.
max_l([X|Xs], X):- max_l(Xs, M), X >  M.

max2([],R). erste Abfrage :-max2([],R) match max2([],R) Aber es ist nicht möglich zu bestimmen, die R.
Danke. Dies wäre als Vergleich vom Anfang oder Ende? Wie würden Sie gehen über das tun es in die andere Richtung?
Ich werde verglichen werden, die von Anfang an auf diese Weise.
Grund für den downvote?

InformationsquelleAutor BLUEPIXY

4

Ignorieren die Hausaufgaben Einschränkungen etwa ab dem Anfang oder am Ende, die richtige Art und Weise zu implementieren, die ein Prädikat, erhält das numerische maximum ist wie folgt:
```
list_max([P|T], O) :- list_max(T, P, O).

list_max([], P, P).
list_max([H|T], P, O) :-
    (    H > P
    ->   list_max(T, H, O)
    ;    list_max(T, P, O)).
```
InformationsquelleAutor salva
3

Als alternative zu BLUEPIXY' Antwort, SWI-Prolog ist ein builtin-Prädikat, max_list/2, das macht die Suche für Sie. Sie könnten auch erwägen, eine langsamere Methode, IMO nützlich, zu gewinnen Vertrautheit mit mehr gelieferten und nondeterminism (und dann backtracking):
```
slow_max(L, Max) :-
   select(Max, L, Rest), \+ (member(E, Rest), E > Max).
```
Erträge
```
2 ?- slow_max([1,2,3,4,5,6,10,7,8],X).
X = 10 ;
false.

3 ?- slow_max([1,2,10,3,4,5,6,10,7,8],X).
X = 10 ;
X = 10 ;
false.
```
Bearbeiten

Beachten Sie nicht streng müssen drei Argumente, sondern nur über ordnungsgemäß instanziiert Variablen der Vergleich durchzuführen. Dann können Sie 'reverse' die flow-Werte:
```
max2([R], R).
max2([X|Xs], R):- max2(Xs, T), (X > T -> R = X ; R = T).
```
wieder, das ist langsamer, als die drei Argumente Schleifen, schlug im anderen Antworten, weil es zu besiegen 'tail recursion optimization'. Auch spielt es nur finden eine von maxima:
```
2 ?- max2([1,2,3,10,5,10,6],X).
X = 10 ;
false.
```
InformationsquelleAutor CapelliC

Hier ist, wie es mit lambda-Ausdrücke und meta-Prädikat foldl/4, und, Optional, clpfd:

:- use_module([library(lambda),library(apply),library(clpfd)]).

numbers_max([Z|Zs],Max) :- foldl(\X^S^M^(M is max(X,S)),Zs,Z,Max).
fdvars_max( [Z|Zs],Max) :- foldl(\X^S^M^(M #= max(X,S)),Zs,Z,Max).

Lasst uns laufen einige Abfragen!

?- numbers_max([1,4,2,3],M). % ganzen zahlen: alle sind Verschieden 
M = 4. % gelingt deterministisch 
?- fdvars_max( [1,4,2,3],M). 
M = 4. % gelingt deterministisch 

?- numbers_max([1,4,2,3,4],M). % ganzen zahlen: M zweimal vorkommt 
M = 4. % gelingt deterministisch 
?- fdvars_max( [1,4,2,3,4],M). 
M = 4. % gelingt deterministisch

Was ist, wenn die Liste leer ist?

?- numbers_max([],M).
false.
?- fdvars_max( [],M).
false.

Endlich, einige Abfragen zeigen Unterschiede zwischen numbers_max/2 und fdvars_max/2:

?- numbers_max([1,2,3,10.0],M). % int + float 
M = 10.0. 
?- fdvars_max( [1,2,3,10.0],M). % int + float 
FEHLER: Domain-Fehler: `clpfd_expression' erwartet, `10.0' 

?- numbers_max([Ein,B,C],M). % Allgemeine Anwendung 
ERROR: is/2: Arguments nicht ausreichend instanziiert 
?- fdvars_max( [Ein,B,C],M). 
"M#" >=_X, M# " >=C, M#=max(C,_X), _X#>=A, _X#>=B, _X#=max(B,Ein). % Rest-Ziele

InformationsquelleAutor repeat

2

Einen sehr einfachen Ansatz, bei dem von Anfang an) ist die folgende:
```
maxlist([],0).

maxlist([Head|Tail],Max) :-
    maxlist(Tail,TailMax),
    Head > TailMax,
    Max is Head.

maxlist([Head|Tail],Max) :-
    maxlist(Tail,TailMax),
    Head =< TailMax,
    Max is TailMax.
```
Als Sie sagte, Sie muss die Variablen instanziiert, wenn Sie auswerten wollen einen arithmetischen Ausdruck. Um dieses Problem zu lösen, müssen Sie zuerst, um den rekursiven Aufruf, und dann vergleichen Sie.

Hoffe, es hilft!

InformationsquelleAutor toioski

list_max([L|Ls], Max) :- foldl(num_num_max, Ls, L, Max).

num_num_max(X, Y, Max) :- Max is max(X, Y).

%Query will be

?-list_max([4,12,5,3,8,90,10,11],Max).
Max=90

InformationsquelleAutor Tanusree Roy

 maximum_no([],Max):-

    write("Maximum No From the List is:: ",Max).
maximum_no([H|T],Max):-
    H>Max,
    N = H,
    maximum_no(T,N).
maximum_no(L,Max):-
    maximum_no(L,Max).

InformationsquelleAutor Harsh Mehta

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.