Knappste Art und Weise zu verändern eine CSV-Zeichenfolge in eine Tabelle in TSQL?

-- Given a CSV string like this:

declare @roles varchar(800)
select  @roles = 'Pub,RegUser,ServiceAdmin'

-- Question: How to get roles into a table view like this:

select  'Pub'
union
select  'RegUser'
union
select  'ServiceAdmin'

Nachdem dieses posting, ich begann das Spiel mit einigen dynamischen SQL. Dies scheint zu funktionieren, aber scheint, wie es könnte einige Sicherheitsrisiken durch die Verwendung von dynamischen SQL - Gedanken auf?

declare @rolesSql varchar(800)
select  @rolesSql = 'select ''' + replace(@roles, ',', ''' union select ''') + ''''
exec(@rolesSql)

InformationsquelleAutor Paul Fryer | 2010-09-17

  1. 9

    Siehe meine Antwort von hier

    Aber im Grunde genommen würde:

    Erstellen diese Funktion in deine DB:

    CREATE FUNCTION dbo.Split(@origString varchar(max), @Delimiter char(1))     
returns @temptable TABLE (items varchar(max))     
as     
begin     
    declare @idx int     
    declare @split varchar(max)     

    select @idx = 1     
        if len(@origString )<1 or @origString is null  return     

    while @idx!= 0     
    begin     
        set @idx = charindex(@Delimiter,@origString)     
        if @idx!=0     
            set @split= left(@origString,@idx - 1)     
        else     
            set @split= @origString

        if(len(@split)>0)
            insert into @temptable(Items) values(@split)     

        set @origString= right(@origString,len(@origString) - @idx)     
        if len(@origString) = 0 break     
    end 
return     
end

    und rufen dann die Funktion auf und übergeben die Zeichenkette, die Sie aufteilen möchten.

    Select * From dbo.Split(@roles, ',')
    Danke, das ist eine tolle Funktion.
    TVF ja? Wäre es nicht SELECT * FROM dbo.Split(@Rollen ',') ??

    InformationsquelleAutor codingbadger

  2. 9

    Wenn Sie arbeiten mit SQL Server-Kompatibilität Stufe 130 dann die STRING_SPLIT Funktion ist jetzt die prägnanteste Methode zur Verfügung.

    Referenz-link: https://msdn.microsoft.com/en-gb/library/mt684588.aspx

    Verwendung:

    SELECT * FROM string_split('Pub,RegUser,ServiceAdmin',',')

RESULT:

value
-----------
Pub
RegUser
ServiceAdmin
    Ich benutze diese Funktion so es produziert die gleiche Ausgabe, ob die Eingabe eine führende Komma oder nicht: SELECT * FROM string_split(@csv_string,','), wo Wert <> "

    InformationsquelleAutor sqlconsumer.net

  3. 5

    Hier ist eine Gründliche Diskussion der Optionen:

    InformationsquelleAutor LukeH

  4. 1

    Mithilfe der SQL Server-built-in XML-parsing ist auch eine option. Natürlich, diese Glossen über alle Nuancen eines RFC 4180-konform CSV.

    -- Given a CSV string like this:
declare @roles varchar(800)
select  @roles = 'Pub,RegUser,ServiceAdmin'

-- Here's the XML way
select split.csv.value('.', 'varchar(100)') as value
from (
     select cast('<x>' + replace(@roles, ',', '</x><x>') + '</x>' as xml) as data
) as csv
cross apply data.nodes('/x') as split(csv)

    Wenn Sie SQL 2016+, mit string_split ist besser, aber dies ist ein gemeinsamer Weg, dies zu tun vor SQL 2016.

    InformationsquelleAutor mattmc3

  5. 0

    Mithilfe von BULK INSERT, importieren Sie eine csv-Datei in der sql-Tabelle -

    http://blog.sqlauthority.com/2008/02/06/sql-server-import-csv-file-into-sql-server-using-bulk-insert-load-comma-delimited-file-into-sql-server/

    Was? Der OP sagte, eine CSV - string keine Datei

    InformationsquelleAutor Sachin Shanbhag

Schreibe einen Kommentar