Sortieren Combobox VBA

Ich habe darüber nachgedacht, wie das Sortieren der Werte in eine combobox.

Ich Elemente hinzufügen, um das Kombinationsfeld, wenn ich initilize form, da die Anzahl der Werte sind stetig auf ein Blatt Papier.

Ich benutze folgenden code, um die Elemente hinzu:

With ComboBox1
lastcell = ThisWorkbook.Sheets("1").Range("F1000000").End(xlUp).Row + 1
For i = 2 To lastcell 
.AddItem ThisWorkbook.Sheets("1").Cells(i, 6)
Next i
End With

Dachte ich kopieren Sie die Werte, die ich bin, gehen, um add-on die ComoBox auf einem anderen Blatt und dort Sortieren Sie Sie in das neue Blatt, es funktioniert gut, aber es scheint nicht zu sein, eine smart-option, also, ich erstelle ein weiteres Blatt und kopiere dann die Werte und Sortieren Sie diese anstelle der Sortierung direkt.

Meine Frage ist, weiß jemand wie man es direkt von der original-Platte? Ich weiß nicht, etwas von API, also, bitte, nur VBA-code. Ich alredy schauen Sie auf der MSDN-Website, aber ich kann nicht herausfinden, wie es funktioniert.

Dank und wenn mehr Infos benötigt wird, bitte, lassen Sie es mich wissen.

PS: ich kann nicht Sortieren, die Sie direkt von der original-Platte, da diese Platte werden mit einer statischen Reihenfolge

InformationsquelleAutor themolestones | 2013-03-21

Lesen Sie die Werte aus der Tabelle in ein array, Sortiere diese mit code und fügen Sie den Artikel.

Dieser code wird dies tun, mit einem Quicksort:

Private Sub UserForm_Initialize()
    Dim varRange() As Variant
    Dim lngLastRow As Long
    Dim i As Long

    lngLastRow = Range("F:F").Find(What:="*", SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row
    varRange = Range("F:F").Resize(lngLastRow).Cells

    subQuickSort varRange

    Me.ComboBox1.List = varRange
End Sub


Public Sub subQuickSort(var1 As Variant, _
    Optional ByVal lngLowStart As Long = -1, _
    Optional ByVal lngHighStart As Long = -1)

    Dim varPivot As Variant
    Dim lngLow As Long
    Dim lngHigh As Long

    lngLowStart = IIf(lngLowStart = -1, LBound(var1), lngLowStart)
    lngHighStart = IIf(lngHighStart = -1, UBound(var1), lngHighStart)
    lngLow = lngLowStart
    lngHigh = lngHighStart

    varPivot = var1((lngLowStart + lngHighStart) \ 2, 1)

    While (lngLow <= lngHigh)
        While (var1(lngLow, 1) < varPivot And lngLow < lngHighStart)
            lngLow = lngLow + 1
        Wend

        While (varPivot < var1(lngHigh, 1) And lngHigh > lngLowStart)
            lngHigh = lngHigh - 1
        Wend

        If (lngLow <= lngHigh) Then
            subSwap var1, lngLow, lngHigh
            lngLow = lngLow + 1
            lngHigh = lngHigh - 1
        End If
    Wend

    If (lngLowStart < lngHigh) Then
        subQuickSort var1, lngLowStart, lngHigh
    End If
    If (lngLow < lngHighStart) Then
        subQuickSort var1, lngLow, lngHighStart
    End If

End Sub

Private Sub subSwap(var As Variant, lngItem1 As Long, lngItem2 As Long)
    Dim varTemp As Variant
    varTemp = var(lngItem1, 1)
    var(lngItem1, 1) = var(lngItem2, 1)
    var(lngItem2, 1) = varTemp
End Sub

danke, lassen Sie mich schauen, und ich werde die Antwort akzeptieren
Sie brauchen nicht, um eine Schleife. Sie können Me.ComboBox1.List = varRange
Guter Punkt, ich aktualisierte den code.

InformationsquelleAutor Peter Albert

Kommt es auf die Umstände, Art und Struktur der Daten. Aber ich bevorzuge es zu tun auf diese Weise:

Könnte man alternativ verwenden Sie ein array und bubble sort algo 🙂

ändern Sie den code ein bisschen anpassen Ihr Fall

Option Explicit

Sub WITH_COMBOBOX()

    Dim i As Long
    Dim arr() As String

    Dim lastCell As Long
    lastCell = 500

    ReDim arr(lastCell)
    Call FillAndSortArray(arr)

    For i = 2 To lastCell
        .AddItem arr(i - 2)
    Next i
End Sub

Sub FillAndSortArray(ByRef myArray() As String)

    Dim i As Long

    For i = LBound(myArray) To UBound(myArray)
        myArray(i) = CStr(ThisWorkbook.Sheets(1).Range("F" & i + 2).Value)
    Next i

    Call BubbleSort(myArray)
End Sub


Sub BubbleSort(ByRef myArray() As String)

    Dim i As Long, j As Long
    Dim Temp As String

    For i = LBound(myArray) To UBound(myArray) - 1
        For j = i + 1 To UBound(myArray) - 1
            If myArray(i) > myArray(j) Then
                Temp = myArray(j)
                myArray(j) = myArray(i)
                myArray(i) = Temp
            End If
        Next j
    Next i
End Sub

InformationsquelleAutor

Versuchen folgenden code :

Sub GetAction()

    Dim rng As Range, lastcell As Long
    lastcell = Range("F1000").End(xlUp).Row + 1
    Set rng = Range("F1:F" & lastcell)  ' assuming to start from F1

    If Not rng Is Nothing Then
        rng.Sort Range("F1")
        ComboBox1.ListFillRange = rng.Address
    End If

End Sub

Ich glaube nicht, dass die Daten Sortieren...

InformationsquelleAutor

für die Sortierung 123 für die Anzahl

For Each cell In ThisWorkbook.Sheets("sheet1").Range("list1")

Me.ComboBox1.AddItem cell

Next cell

With Me.ComboBox1

 For x = LBound(.list) To UBound(.list)

   For y = x To UBound(.list)

   If .list(y, 0) + 0 < .list(x, 0) + 0 Then

     blah = .list(y, 0)

    .list(y, 0) = .list(x, 0)

    .list(x, 0) = blah

   End If

 Next y

Next x

 End With

für die Sortierung von text abcd

For Each cell In ThisWorkbook.Sheets("sheet1").Range("list1")

Me.ComboBox1.AddItem cell

Next cell

With Me.ComboBox1

 For x = LBound(.list) To UBound(.list)

   For y = x To UBound(.list)

   If .list(y, 0)  < .list(x, 0)  Then

     blah = .list(y, 0)

    .list(y, 0) = .list(x, 0)

    .list(x, 0) = blah

   End If

 Next y

Next x

 End With

InformationsquelleAutor Zafar Janjua

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.