Wie finden Sie die Anzahl der Vorkommen von Slash von strings

Wie finde ich die Anzahl der Vorkommen von Zeichen ( /) aus dem string in VBA-Excel-Makros.

InformationsquelleAutor Code Hungry | 2012-02-13

  1. 13

    Verwenden Sie die unter-Funktion, wie in count = CountChrInString(yourString, "/").

    '''
''' Returns the count of the specified character in the specified string.
'''
Public Function CountChrInString(Expression As String, Character As String) As Long
'
' ? CountChrInString("a/b/c", "/")
'  2
' ? CountChrInString("a/b/c", "\")
'  0
' ? CountChrInString("//////", "/")
'  6
' ? CountChrInString(" a /b /c ", "/")
'  2
' ? CountChrInString("a/b/c", " /")
'  0
'
    Dim iResult As Long
    Dim sParts() As String

    sParts = Split(Expression, Character)

    iResult = UBound(sParts, 1)

    If (iResult = -1) Then
    iResult = 0
    End If

    CountChrInString = iResult

End Function
    Nicht ein großer fan der ungarischen Schreibweise, aber danke für die Kommentare 🙂

    InformationsquelleAutor assylias

  2. 30

    Alte Frage, aber ich dachte, ich würde hinzufügen, um die Qualität der Antwort durch die Antwort fand ich in einem excel-forum. Offenbar ist die Zählung kann auch gefunden werden mit.

        count =Len(string)-Len(Replace(string,"/",""))

    Volle Punktzahl für die Antwort geht an den ursprünglichen Autor:http://www.ozgrid.com/forum/showthread.php?t=45651

    Ha! Ich dachte nur, dass man, aber ich kam hier, um zu sehen, ob es eine bessere Lösung.
    Die Schönheit dieser ist, dass Sie problemlos verwenden können, es in Formeln, ohne VBA, mit SUBSTITUTE()

    InformationsquelleAutor Santhosh Divakar

  3. 8
    Function Count(str as string, character as string) as integer
      Count = UBound(Split(str, character))
End Function
    Dies ist die beste. Sie können sich gruppiert Gruppen von Zeichen als gut.
    Ich nicht Folgen. Diese ubound(split("x x "," ")) gibt 4, die ist, was Sie wollen (string x[Leertaste][Leertaste][Leertaste]x[Leertaste]). Können Sie uns ein Beispiel, wie es nicht funktionieren würde?
    tatsächlich es funktioniert, sry, ich dachte über etwas anderes, in Replace() den Räumen vereint sind.
    Ihnen fehlt ein code-Zeile: im Fall von str = "", das Ergebnis ist -1. Auch würde ich die name-Parameter inThis und countThis, weil der zweite beschränkt sich nicht auf den Charakter, es funktioniert auch als längere Zeichenfolge.

    InformationsquelleAutor maracuja

  4. 1

    BTW, wenn Sie in die Leistung, die folgenden 20% schneller als mit split oder ersetzen, um zu bestimmen, die zählen:

    Private Function GetCountOfChar( _
  ByRef ar_sText As String, _
  ByVal a_sChar As String _
) As Integer
  Dim l_iIndex As Integer
  Dim l_iMax As Integer
  Dim l_iLen As Integer

  GetCountOfChar = 0
  l_iMax = Len(ar_sText)
  l_iLen = Len(a_sChar)
  For l_iIndex = 1 To l_iMax
    If (Mid(ar_sText, l_iIndex, l_iLen) = a_sChar) Then 'found occurrence
      GetCountOfChar = GetCountOfChar + 1
      If (l_iLen > 1) Then l_iIndex = l_iIndex + (l_iLen - 1) 'if matching more than 1 char, need to move more than one char ahead to continue searching
    End If
  Next l_iIndex
End Function

    InformationsquelleAutor user9338905

  5. 0

    Dies ist eine einfache Lösung für VBA-Excel-Makros.

    Function CharCount(str As String, chr As String) As Integer
     CharCount = Len(str) - Len(Replace(str, chr, ""))
End Function
    Und was machen deine Antwort unterscheidet sich von Santhosh Divakar?

    InformationsquelleAutor Shawn Smith

Schreibe einen Kommentar