Wie kann ich mit Proc SQL finden Sie alle Datensätze, die es nur in einer Tabelle, aber nicht den anderen?

Ich versuche, dies zu tun im Enterprise Guide, mit einer Aufgabe, sonst würde ich nur verwenden Sie eine Daten-Schritt.

In einem data step, das wäre:

data names;
 input name $;
 datalines;
  John
  Mary
  Sally
  Fred
  Paul
 ;
run;

data check;
 input name $;
 datalines;
  Mary
  Fred
 ;

Proc sort data=names; by name; run;
Proc sort data=check; by name; run;

Data work.not_in_check;
 merge names(in=n) check(in=c);
 by name;
 if n and not c;
run;

InformationsquelleAutor Jay Corbett | 2012-01-20

  1. 9

    Hier ist ein Weg. Es gibt sicherlich viele andere.

    proc sql;
 create table not_in_check as
 select name
 from names
 where name not in (select name from check);
quit;
    Das ist deutlich eleganter als die Daten Schritt, wenn Sie mich Fragen...

    InformationsquelleAutor itzy

  2. 7

    Andere leichte variation ist:

    proc sql;
create table not_in_check as select 
 a.* from names as a left join 
          check as b on
          a.name=b.name
          where b.name is null;
quit;
    Dies ist die Methode, die ich am Ende mit in ZB. In der Filtern von Daten Abschnitt b verwendet.name fehlt. Es wäre schön zu sehen, eine Erklärung darüber, warum, wenn ich eine will.name nicht vorhanden in b, b.name null ist(fehlende) macht, dass passieren....
    Es ist, weil 2 Spalten eingelesen werden, ein.name und b.name. Diese werden dann aufeinander abgestimmt und daher, wenn ein name existiert in a, aber nicht b, dann b.name-record fehlt. Der left join mit is null where-Klausel stellt sicher, Sie halten nur die Namen, die in a, aber nicht b. Wählen Sie ein.* stellt sicher, es gibt nur Daten aus der Tabelle ein, auch wenn es beim Lesen der Daten aus beiden Tabellen. Hoffe, das hilft.
    gute Erklärung...danke

    InformationsquelleAutor Longfish

  3. 1

    Folgende Methode ist ziemlich einfacher Weg, um Datensätze in einer Tabelle und nicht in der anderen.

    Erstellte Tabelle mit neuen Datensätzen, die Geschlecht = M, das Ergebnis nach der Abfrage werden die Datensätze mit sex = F.

    Beispiel:

    data new;
set sashelp.class;
where sex = 'M';
run;
proc sql;
create table new1 as
select * from sashelp.class
except all 
select * from new;
quit;

    Wird den code zu testen, auf meinem eigentlichen Datensätze, die von rund 100k obs und aktualisieren das Ergebnis.

    P. S: ich weiß die Frage wurde gefragt, geantwortet und vergessen,ich war auf der Suche nach einem Weg, um die oben und konnte Sie nicht finden, eine direkte Antwort. So, hinzufügen, so dass es kann sehr praktisch sein. 🙂

    Meine erste Antwort auch. 🙂

    InformationsquelleAutor user2239912

  4. 0
    proc sql;
 create table inNamesNotIncheck
 as
 select *
 from names n
 where not exists
 (select name
 from check c
 where n.name=c.name);
quit;
    Hallo, dein post wurde gekennzeichnet als "low-quality", wahrscheinlich, weil es besteht nur aus code. Sie könnte Massiv verbessern Sie Ihre Antwort, indem Sie eine Erklärung, wie und warum diese Antworten die Frage?
    Ich Schätze die Ergänzung des code. Es zeigt eine andere, aber brauchbarer Ansatz zu dem bereits beschriebenen problem. Dankeschön.

    InformationsquelleAutor user2781854

Schreibe einen Kommentar