Wie "pad" eine Zeichenfolge variabler Länge haben eine ausgerichtete letzten Spalte

Habe ich eine Eingabe im folgenden format:

09:08:11        XXXXXXXXXXXXX  1.1.1.1          
09:09:03        YYYYYYYY  2.2.2.2         
09:12:37        ZZZZ   3.3.3.3

Ich bin in der Lage, extrahieren Sie diese Individuen Felder einfach mit der regex /(\S+)\s+(\S+)\s+(\S+)\s+/. Ich benannte Sie $time, $name, und $number. Mein problem ist, ich möchte die Anzeige so, dass die $number richtet perfekt. Da die $name beliebig lang sein können, was ist die beste Lösung für dieses?

Ich würde gerne die Ausgabe wie folgt Aussehen. Bitte beachten Sie, dass ich hatte, um Punkte für das ausrichten des letzten Feldes, da war ich nicht in der Lage, verwenden Sie die Leertaste, um dies zu tun, nicht sicher, warum. Anyhoo.

09:08:11        XXXXXXXXXXXXX    1.1.1.1          
09:09:03        YYYYYYYY         2.2.2.2         
09:12:37        ZZZZ             3.3.3.3

Dachte ich über das setzen der $name in ein array. Und dann eine Funktion zu finden, die mit der längsten Anzahl Zeichen. Schließlich würde ich die Pads aus dem kürzeren Namen übereinstimmen, den längsten Namen. Gibt es eine bessere und effizientere Methode, dies zu tun?

Verwenden Sie die Code-Formatierung option, um anzugeben, dass die Feste Breite-schriftart und preformatting verwendet werden soll. 🙂
Ich war nur zu machen diese zu Bearbeiten auf meinem Handy, bis ich merkte, es war zu schwierig.
Sind die zahlen immer eine Ziffer pro? Wenn nicht, was möchten Sie tun?
Vielen Dank für den edit. Gut zu wissen ich hinzufügen kann, die Leerzeichen in den code-option.

InformationsquelleAutor qdog | 2009-10-02

perl

20

Für die Formatierung, versuchen Sie es mit der sprintf Funktion, wie in
```
$line = sprintf "%-12s %-20s %-s\n", $time, $name, $number;
```
(das Minuszeichen bedeutet Linksbündig)

danke!!! das ist genau das, was ich suchte.

InformationsquelleAutor Jim Garrison

Es wurde von jemand hier:

my($name, $telephone, $stime);

format Infos =
@<<<<<<<<<<<<<<<<<<@<<<<<<<<<<<<<<<<<<<@<<<<<<<<<<<<<<<
$name,             $telephone,         $stime
.

$~ = 'Infos';

($name, $telephone, $stime) = ('Name:', 'Telephone:', 'Start Time:');
write;

($name, $telephone, $stime) = ('Mike Bax', 'tel-41596', 'Fri 8/22 13:31');
write;

Können Sie ändern, Variablen-Namen, und es sollte für Sie arbeiten.

Wow, die Menschen immer noch verwenden Formate? Wie sehr perl-4 von Euch 🙂

InformationsquelleAutor Ashwin

Haben Sie einen Blick auf Perl6::Form.

Dieser Ansatz wird empfohlen, über die Verwendung format. Siehe diesen früheren Stack Overflow Antwort: Welche anderen Sprachen haben Eigenschaften und/oder Bibliotheken, die ähnlich wie Perl-format?

Hier ist ein Beispiel, Perl6::Form tut genau das, was Sie wollen, mit Ihren Daten:

use Perl6::Form;

my ($time, $name, $number);

my @data = (
    [ qw(09:08:11 XXXXXXXXXXXXX 1.1.1.1) ],
    [ qw(09:09:03 YYYYYYYY 2.2.2.2)      ],
    [ qw(09:12:37 ZZZZ 3.3.3.3)          ],
);

for my $line (@data) {
    push @$time,   $line->[0];
    push @$name,   $line->[1];
    push @$number, $line->[2];
}

print form
    '{[[[[[[}    {[[[[[[[[[[[[[[[[[[[[}    {[[[[[[}',
    $time,       $name,                    $number;

NB. Wenn Ihre Daten Felder immer größer als die form-Felder angegeben, dann läuft man in Probleme mit der Formatierung (und das gleiche gilt auch für die sprintf-und format-Lösungen).

Es ist einfach zu beheben, je nachdem, was Ihre Ausgabe-Anforderungen sind. Zum Beispiel, wenn Sie pflegen wollen, ist die tabellarische Stabilität dann...

print form { layout => 'tabular' },
    '{[[[[[[}    {[[[[[[[[[[[[[[[[[[[[}    {[[[[[[}',
    $time,       $name,                    $number;

...word wickeln Sie jede Spalte für Sie.

InformationsquelleAutor draegtun

Wenn Sie nicht wissen, die maximale Breite des mittleren Feldes, haben Sie, um zwei Durchgänge über die Daten als @ijw Noten.

#!/usr/bin/perl

use strict;
use warnings;

use Fcntl qw( :seek );

my $max_length = 0;
my $data_pos = tell DATA;

while ( my $line = <DATA> ) {
    last unless $line =~ /\S/;
    my $name = (split ' ', $line)[1];
    my $name_length = length $name;
    $max_length = $name_length if $name_length > $max_length;
}

seek DATA, $data_pos, SEEK_SET;

while ( my $line = <DATA> ) {
    last unless $line =~ /\S/;
    my ($date, $name, $ip) = split ' ', $line;
    printf "%s %-${max_length}s %s\n", $date, $name, $ip;
}

__DATA__
09:08:11        XXXXXXXXXXXXX  1.1.1.1
09:09:03        YYYYYYYY  2.2.2.2
09:12:37        ZZZZ   3.3.3.3

InformationsquelleAutor Sinan Ünür

0

Was auch immer Sie tun, Sie gehen zu müssen, zu tun mit zwei Durchgängen zu finden, die Länge, die man zum drucken verwenden, die Länge der Formatierung. Ich würde mit dem sprintf Antwort bereits gegeben, für die Formatierung, persönlich, nur die Variation der Anzahl.

Genau, wie Sie die zwei Durchgänge hängt eher davon ab, wo die Daten herkommen - Lesen einer Datei zweimal könnte klüger sein, als der Vorverarbeitung in den Arbeitsspeicher, wenn die Datei riesig ist, aber die array-Lösung, die Sie vorschlagen, klingt gut für mich.

InformationsquelleAutor ijw

      $lineLength = length($line1);
      write;
}
close FD1;

format STDOUT =
@>>>>> @*
$lineLength,$line1
.
;

So, in obigem Beispiel, "$lineLength" ist nach rechts verschoben mit führenden Leerzeichen.

InformationsquelleAutor James Burchell

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.