Wie Sie manuell initialisieren einer Sammlung der Datensätze in PL/SQL?

Jungs. Hier ist ein einfaches Beispiel, zwei-dimensionalen Arrays in PL/SQL, die perfekt funktioniert.

declare
  type a is table of number;
  type b is table of a;

  arr b := b(a(1, 2), a(3, 4));
begin
  for i in arr.first .. arr.last loop
    for j in arr(i).first .. arr(i).last loop
      dbms_output.put_line(arr(i) (j));
    end loop;
  end loop;
end;

Was ich tun müssen, ist, um etwas ähnliches zu erschaffen für Sie eine Tabelle der RECORDS. Wie diese: 

 type a is record(a1 number, a2 number);
 type b is table of a;

Die Frage ist, kann ich auch manuell initialisieren, diese Art von array, oder soll es gefüllt werden, indem bulk collects oder ähnliches? Die gleiche syntax wie oben scheint nicht zu funktionieren, und ich war nicht in der Lage zu finden keine Initialisierung Beispiel in Handbüchern.

InformationsquelleAutor der Frage be here now | 2010-09-14

  1. 16

    Gibt es keinen "Konstruktor" - syntax für die Einträge, so müssen Sie füllen Sie wie folgt:

    declare
 type a is record(a1 number, a2 number);
 type b is table of a;
 arr b := b();
begin
 arr.extend(2);
 arr(1).a1 := 1;
 arr(1).a2 := 2;
 arr(2).a1 := 3;
 arr(2).a2 := 4;
end;

    InformationsquelleAutor der Antwort Tony Andrews

  2. 12

    Dies funktioniert ohne Objekte, aber Sie haben zu erklären, eine Konstruktorfunktion für den Typ 'a' - Werte.

    declare  
  type a is record(a1 number, a2 number);
  type b is table of a;

  arr b;

  --Constructor for type a
  function a_(a1 number, a2 number) return a is
    r_a a;
  begin
    r_a.a1 := a1;
    r_a.a2 := a2;

    return(r_a);
  end;

begin
  arr := b(a_(1, 2), a_(3, 4), a_(5, 6), a_(7, 8));

  for i in arr.first .. arr.last loop
    dbms_output.put_line(arr(i).a1||', '||arr(i).a2);
  end loop;
end;

    InformationsquelleAutor der Antwort Shallow

Schreibe einen Kommentar