Ada: Erste Benutzereingabe, um einen String(1..10) und füllen den rest mit Leerzeichen

Ich habe

subtype String10 is String(1..10);

und ich bin versucht zu bekommen Tastatur-Eingaben auf, ohne dass manuell eingeben von Leerzeichen drücken Sie enter. Ich habe versucht, get_line (), aber aus irgendeinem Grund würde es nicht eigentlich warten, bis Eingang vor der Ausgabe der get put () - Befehl, und ich denke auch, es wird nur verlassen, was war in der Zeichenfolge, bevor Sie es und nicht füllen Sie ihn mit Leerzeichen.

Ich kennen und benutzt haben Bounded_String und Unbounded_String, aber ich Frage mich, ob es einen Weg gibt, um diese Arbeit zu machen.

Ich habe versucht, eine Funktion für Sie:

--getString10--
procedure getString10(s : string10) is
   c : character;
   k : integer;
begin
   for i in integer range 1..10 loop
      get(c);
      if Ada.Text_IO.End_Of_Line = false then
         s(i) := c;
      else
         k := i;
         exit;
      end if;
   end loop;

   for i in integer range k..10 loop
      s(i) := ' ';
   end loop;
end getString10;

aber, ich weiß, hier die s(i) funktioniert nicht, und ich glaube nicht, dass die

"if Ada.Text_IO.End_Of_Line = false then"

tut, was ich hoffe, es wird entweder zu tun. Es ist irgendwie nur ein Platzhalter, während ich für die tatsächliche Art und Weise, es zu tun.

Ich war auf der Suche für ein paar Stunden jetzt, aber Ada Dokumentation ist nicht als verfügbar oder klar als andere Sprachen. Ich habe eine Menge über erste-Zeichenfolgen, aber nicht das, was ich Suche.

Vergleiche auf Gleichheit zu true und false sind nicht besonders klar. Anstatt if Ada.Text_IO.End_Of_Line = false then haben, schreiben Sie einfach if not Ada.Text_IO.End_Of_Line then. (Obwohl ich glaube nicht, dass Sie brauchen, um zu verwenden End_Of_Line sowieso.)

InformationsquelleAutor user1279914 | 2012-12-01

7

Nur pre-initialisieren Sie die Zeichenfolge mit Leerzeichen vor dem Aufruf Get_Line.

Hier ein kleines Programm, das ich nur warf zusammen:
```
with Ada.Text_IO; use Ada.Text_IO;
procedure Foo is
    S: String(1 .. 10) := (others => ' ');
    Last: Integer;
begin
    Put("Enter S: ");
    Get_Line(S, Last);
    Put_Line("S = """ & S & """");
    Put_Line("Last = " & Integer'Image(Last));
end Foo;
```
und die Ausgabe die ich bekomme, wenn ich es:
```
Enter S: hello
S = "hello     "
Last =  5
```
Andere Möglichkeit, eher als pre-Initialisierung der string ist, ist der Rest zu Räumen nach die Get_Line nennen:
```
with Ada.Text_IO; use Ada.Text_IO;
procedure Foo is
    S: String(1 .. 10);
    Last: Integer;
begin
    Put("Enter S: ");
    Get_Line(S, Last);
    S(Last+1 .. S'Last) := (others => ' ');
    Put_Line("S = """ & S & """");
    Put_Line("Last = " & Integer'Image(Last));
end Foo;
```
Für sehr große arrays, die zweite Methode kann effizienter sein, weil es nicht weisen der erste Teil der saite zweimal, aber in der Praxis ist der Unterschied kaum erheblich sein.
- Danke. Ich bin mir nicht sicher, warum ich nicht denke, dass nur pre-initialisieren. Die "(andere =>',') " füllen Sie einfach S mit Leerzeichen? Ich habe es nur verwendet in case-Strukturen, so weit, so bin ich nicht sicher, was es tut.
- +1 für die Beantwortung der Frage. 🙂 @user1279914: Siehe auch 4.3.3 Array Aggregate.
- Ja, ein others Klausel in einem array Aggregat bezieht sich auf alle Elemente, die nicht anderweitig angegeben. Wenn es nur ein others Klausel bezieht sich auf alle Elemente des Arrays.
InformationsquelleAutor Keith Thompson
3

Als alternative, verwenden Sie entweder Funktion Get_Line, die gibt einen mit fester Länge String das "hat einer unteren Grenze von 1 und einer oberen Schranke für die Anzahl der Zeichen Lesen." Das Beispiel Line_By_Line verwendet die Variante, die aus einer Datei liest. Wenn es sein muss, dann können Sie procedure Move zu kopieren Source string an die Target string; das Verfahren automatisch pads mit Platz standardmäßig.

Nachtrag: Zum Beispiel, dies Line_Test pads mit * still und leise kürzt lange Linien auf der rechten Seite.
```
with Ada.Integer_Text_IO;
with Ada.Strings.Fixed;
with Ada.Text_IO;

procedure Line_Test is
   Line_Count : Natural := 0;
   Buffer: String(1 .. 10);
begin
   while not Ada.Text_IO.End_Of_File loop
      declare
         Line : String := Ada.Text_IO.Get_Line;
      begin
         Line_Count := Line_Count + 1;
         Ada.Integer_Text_IO.Put(Line_Count, 0);
         Ada.Text_IO.Put_Line(": " & Line);
         Ada.Strings.Fixed.Move(
            Source  => Line,
            Target  => Buffer,
            Drop    => Ada.Strings.Right,
            Justify => Ada.Strings.Left,
            Pad     => '*');
         Ada.Integer_Text_IO.Put(Line_Count, 0);
         Ada.Text_IO.Put_Line(": " & Buffer);
      end;
   end loop;
end Line_Test;
```
- Ich habe versucht, get_line(), aber es hielt drucken die folgenden put (), bevor Sie auf eine Eingabe wartet, aus irgendeinem Grund. Ich bin eigentlich immer input von der Tastatur, aber manchmal mithilfe einer input-Datei auch. Ich werde sehen, ob ich kann, damit es funktioniert mit Move(). Danke.
- Sie können sehen, dass der Effekt beschrieben, hier. Ping mich hier, wenn Sie Ihre Frage aktualisieren mit neuen Codes.
InformationsquelleAutor trashgod

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.