Alle Spalten excelsheet sind nicht angebracht, in derselben Seite des pdf; während der Konvertierung mit Excel-VBA

Versuche zu konvertieren microsoft excel-Datei mit einer großen Anzahl von Spalten (70+) in ein pdf-Dokument über eine Excel-VBA-code.

In der aktiven Arbeitsmappe, bin versucht zu retten, 'Tabelle1', um das PDF-format am gewünschten Pfad. Ich habe den folgenden code.

Sub GetSaveAsFilename()

Dim fileName As String

fileName = Application.GetSaveAsFilename(InitialFileName:="", _
                                         FileFilter:="PDF Files (*.pdf), *.pdf", _
                                         Title:="Select Path and FileName to save")

    If fileName <> "False" Then

        With ActiveWorkbook

           .Worksheets("Sheet1").ExportAsFixedFormat Type:=xlTypePDF, fileName:= _
           fileName, Quality:=xlQualityStandard, _
           IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=False

        End With

    End If
End Sub

Beim laufen bin den VBA-code und speichern Sie die pdf-Datei, sehe ich das; die ganze excelsheet ist nicht angebracht, auf derselben Seite. Es ist die Anzeige einiger Inhalte in der nächsten Seite.

(Nur wenige Spalten erscheinen in der ersten Seite, die restlichen erscheinen auf der nächsten Seite und so weiter..).

Ich habe mit So veröffentlichen Sie ein breites Arbeitsblatt im PDF-format?.

Aber, die Einstellung Seitenlayout auf Querformat und konvertieren von excel-Datei manuell zu PDF; zeigt auch einige Spalten in nächsten Seiten.

Gibt es viele Kostenlose Excel to PDF Converters verfügbar online, die geben mir die gleichen Ergebnisse.

Gibt es eine Funktion in VBA, mit der ich passen alle Spalten in eine einzelne Seite der PDF-Datei?

Haben Sie die Seite Setup von Ihrem Arbeitsblatt? Es ist möglich, dass Sie große Margen, eine nicht-angemessene Seitengröße, etc. Sie können auch die Kontrolle der druckbereich des Blattes, durch auswählen von Ansicht --> Page Layout
Meine Seite, die Größe ist A4-Format und Seitenlayout --> Orientierung festgelegt ist Landscape vielen Dank für die Beratung. Jetzt werde ich auch überprüfen, mit anderen "Seite einrichten", wie "skalieren", wird überprüft, ob ich die konvertieren kann excel manuell zu PDF und wieder zu Euch zurück kommen
Ja, manchmal nur über trial-and-error, bis Sie es genau so, wie Sie es brauchen ... 🙂
Ya @ScottHoltzman. Ich habe versucht, mit sinkenden Skala bis 10% und ich war in der Lage zu veröffentlichen die fast 55 Spalten in eine einzelne Seite der pdf-Datei. Hätte ich noch veröffentlichen paar mehr Spalten in der gleichen Seite 🙂 Und excel ändert automatisch die Skala auf 10%, wenn ich versuche, untere Skala, als es 🙂
können Sie veröffentlichen es auf beiden Seiten (bei 10% ist nicht wirklich unlesbar überhaupt???) wenn Sie halten einige Spalten auf der linken Seite zu drucken, für jedes Blatt die Zeile identifizieren der Daten auf der 2. Platte?
Es gibt eine option zum drucken zu zwingen, Ihre Daten werden 1 Seite breit und 1 Seite hoch. Wenn Sie auf diese [unter layout -> scale to fit], es zeigt Ihnen, wie viel es schrumpft Ihre Daten passen auf 1 Seite. Wenn Sie ein makro aufzeichnen, mit der Sie dies tun, wird es Ihnen der VBA-code festlegen, dass die option.
Ya. Viele Plätze waren nicht mehr lesbar. Zu keep some columns on the left to print for each sheet to identify the row of data on the 2nd sheet ist eine gute Idee. Einzige Sache ist, dass ich anpassen, um solche Spalten manuell. Wenn ich nicht bekommen, jede andere Lösung, bin sicher für Sie. 🙂

InformationsquelleAutor Charvi | 2015-10-14

3

Ist das problem mit der Seite Setup-Einstellungen, ich habe getan, einige kleinere änderungen an Ihrem code und fügte hinzu, ein Verfahren zur Durchführung der Seite setup-Einstellungen beim Start der Prozedur können Sie das Papierformat auswählen, beachten Sie jedoch den minimalen zoom erlaubt ist, ist 10% (siehe PageSetup-Mitglieder (Excel -)). Daher, wenn selbst bei 10% der druckbereich passt nicht in eine Seite schlage ich vor, zur Wahl mit einem größeren Papierformat (z.B. A3) zum erzeugen einer PDF-Seite, dann beim drucken der Pdf-Datei wählen Sie an Seite anpassen. Das Verfahren gibt Ihnen auch die Veränderung zum spielen mit den Rändern, beim generieren von PDF ' s die ich setzen Sie alle Ränder auf 0, aber Sie können geändert, wie es Ihren Zielen entspricht.
```
Sub Wsh_LargePrintArea_To_Pdf()
Dim WshTrg As Worksheet
Dim sFileName As String

    sFileName = Application.GetSaveAsFilename( _
        InitialFileName:="", _
        FileFilter:="PDF Files (*.pdf), *.pdf", _
        Title:="Select Path and FileName to save")

    If sFileName <> "False" Then

        Rem Set Worksheet Target
        Set WshTrg = ActiveWorkbook.Worksheets("Sheet1")

        Rem Procedure Update Worksheet Target Page Setup
        'To Adjust the Page Setup Zoom select the Paper Size as per your requirements
        'Call Wsh_Print_Setting_OnePage(WshTrg, xlPaperLetter)
        'Call Wsh_Print_Setting_OnePage(WshTrg, xlPaperA4)
        'To Adjust the Page Setup Zoom select the Paper Size as per your requirements
        'If the Print Still don't fit in one page then use a the largest Paper Size (xlPaperA3)
        'When printing the Pdf you can still selet to fix to the physical paper size of the printer.
        'Call Wsh_Print_Setting_OnePage(WshTrg, xlPaperA3)
        'This is the largest paper i can see in my laptop is 86.36 cm x 111.76 cm
        Call Wsh_Print_Setting_OnePage(WshTrg, xlPaperEsheet)

        Rem Export Wsh to Pdf
        WshTrg.ExportAsFixedFormat _
            Type:=xlTypePDF, _
            fileName:=sFileName, _
            Quality:=xlQualityStandard, _
            IncludeDocProperties:=True, _
            IgnorePrintAreas:=False, _
            OpenAfterPublish:=False
    End If

End Sub


Sub Wsh_Print_Setting_OnePage(WshTrg As Worksheet, ePaperSize As XlPaperSize)
On Error Resume Next
    Application.PrintCommunication = False
    With ActiveSheet.PageSetup
        .LeftMargin = Application.InchesToPoints(0)
        .RightMargin = Application.InchesToPoints(0)
        .TopMargin = Application.InchesToPoints(0)
        .BottomMargin = Application.InchesToPoints(0)
        .HeaderMargin = Application.InchesToPoints(0)
        .FooterMargin = Application.InchesToPoints(0)
        '.Orientation = xlLandscape
        .Orientation = xlPortrait
        .PaperSize = ePaperSize
        .Zoom = False
        .FitToPagesWide = 1
        .FitToPagesTall = 1
    End With
    Application.PrintCommunication = True
End Sub
```
- Danke für diese Antwort und Erklärung. Obwohl immer noch in der Lage bin zu exportieren, bis nur 50-60 Spalten (nach der Auswahl von A3-Größe der Seite), es hat mir geholfen, zu lernen, wie man ein makro aufzeichnen, passen Sie Seite einrichten. +1 für ihn. Einige der Spalten, die exportiert werden, unlesbar; ist es möglich, erweitern Sie die Breite der Seite? So, dass ich in der Lage wäre zu Lesen, diese richtig? (wenn man bedenkt, - bin nicht zu drucken, generierten PDF-Datei auf Papier und ich brauche Sie nur zu sehen, wie eine weiche Kopie)
- Wenn das drucken auf A3 Papier mit minimaler zoom (d.h. 10%) noch immer passt nicht alles in eine Seite, was hat man dann von Vorsatz ist nicht machbar. Deine ursprüngliche Frage hat mit dem Arbeitsblatt gedruckt auf einer Seite, und dass das, was diese Antwort ist. Jetzt sind Sie zeigt sich besorgt über die Lesbarkeit, dann müssen Sie das Spiel mit der .FitToPagesWide und .FitToPagesTall und entscheiden, was die beste Kompression, die es ermöglicht die Lesbarkeit zu verbessern.
- entschuldigt, habe nicht realisiert, die ursprüngliche Frage ist eigentlich nicht verkaufen. Als ich sagte früher, die minimale Vergrößerung möglich ist 10%, versuchen Sie mit dem adjust-Seite Einstellung und lassen Sie es uns wissen. Fragen, 1) wie groß ist der druckbereich nicht nur in den Spalten Nummer, aber auch neben der die Breite aller Spalten; 2) wie viele Zeilen hat die print-Bereich und 3) welche Schriftgröße verwendet wird. Benötigen diese, um zu versuchen, zu replizieren Ihrem Fall. Aber es wird besser, wenn Sie teilen können Ihre Datei...
- Danke @EEM für die Führung. Ich werde überprüfen Sie mit Eigenschaften .FitToPagesWide und .FitToPagesTall - ob ich in der Lage, passen unsere Daten in eine breitere Seite. An diesem Punkt, ich glaube in deinem Satz: what I intent is not doable., aber bin immer noch neugierig, ob es möglich ist, durch eine Verbreiterung der Größe(Breite) der Seite. (Ich don ' T haben, um es zu drucken körperlich; nur in einer softcopy - PDF)
- Ich gegangen durch diesen post: stackoverflow.com/questions/5116828/... und 1) Width of all columns together is 2750 pixels. (Gesamt keine. der Spalten - 100). 2) There are around 1500 rows. 3) Arial und Calibri, Schriftgröße 11; und tut mir Leid, ich werde nicht in der Lage, um die Datei teilen, wie Es einige sensible Daten. ...und Sie brauchen sich nicht entschuldigten. 🙂 Ich fand diese Frage ähnlich wie meine Anforderung, so dachte der bietet bounty, statt zu Fragen eine neue Frage. Grüße,
- Ich überprüfte weiter-und es ein viel größeres Papierformat genannt E Size was 86,36 cm x 111.76 cm, nach den Messungen, die Seite sollte hoch-statt Querformat. Ich aktualisiere das Vorgehen, um diese alternativen. versuchen Sie, und lassen Sie mich wissen.
- Lassen Sie uns weiter, diese Diskussion im chat.
- Nie wusste REM verwendet werden könnte, für Kommentare in VBA...
InformationsquelleAutor EEM
1

fügen Sie dem code, die Sie zwingen, alles zu drucken Sie auf einem Blatt breit, aber immer noch lassen Sie es drucken über mehrere Blätter groß
```
With Worksheets("Sheet1").PageSetup
    .FitToPagesWide = 1
    .FitToPagesTall = False
End With
```
auch Ihre Margen zu "Eng"
- Danke @neuralgroove für die Antwort. 🙂 Habe versucht, mit Versuch und Irrtum durch Zugabe der oben genannten code. Versucht mit anlegen mit zwei mit Blöcken und auch Zugabe der oben genannten code in der vorherigen mit block (Kombination der Blöcke in einzelne with-block). Auch Ränder festlegen zu 'schmal'. Bekomme ich dieselben Ergebnisse wie die Vorherige. Können Sie mir sagen, Wie ich die integrieren kann, es mit früheren code ?
InformationsquelleAutor neuralgroove

Wählen Sie zunächst den Bereich, den Sie drucken möchten, und legen Sie es als PrintArea. Und dann diesen code ausführen, diese Arbeit für mich mit 79 Spalten-Blatt

Sub saveAsPDF()

    Dim MyPath
    Dim MyFolder


    With Sheet1.PageSetup
        '.CenterHorizontally = True
        .CenterVertically = True
        .Orientation = xlLandscape
        .Zoom = False
        .FitToPagesWide = 1
        .FitToPagesTall = 1
        .BottomMargin = 0
        .TopMargin = 0
        .RightMargin = 0
        .LeftMargin = 0
    End With

    MyPath = ThisWorkbook.Path
    MyFolder = Application.GetSaveAsFilename(MyPath, "PDF Files (*.pdf),*.pdf")

    If MyFolder = False Then Exit Sub
     Sheet1.ExportAsFixedFormat Type:=xlTypePDF, _
                                    Filename:=MyFolder, _
                                    Quality:=xlQualityStandard, _
                                    IncludeDocProperties:=True, _
                                    IgnorePrintAreas:=False, _
                                    OpenAfterPublish:=False

End Sub

Danke u buddy für die Antwort. +1, bin in der Lage zu exportieren bisschen weniger Spalten als die 79 für mich pixel-Größe ist jetzt mehr.

InformationsquelleAutor Estevam Garcia

0

Das problem ist, dass Sie brauchen, um Wählen Sie die UsedRange und verwenden Sie dann Selection.ExportAsFixedFormat
```
Sub GetSaveAsFilename()

Dim fileName As String

fileName = Application.GetSaveAsFilename(InitialFileName:="", _
                                         FileFilter:="PDF Files (*.pdf), *.pdf", _
                                         Title:="Select Path and FileName to save")

If fileName <> "False" Then

  'Selecting the Used Range in the Sheet
  ActiveWorkbook.Worksheets("Sheet1").UsedRange.Select

  'Saving the Selection - Here is where the problem was
  Selection.ExportAsFixedFormat Type:=xlTypePDF, fileName:=fileName, _
                                Quality:=xlQualityStandard, IncludeDocProperties:=False, _
                                IgnorePrintAreas:=False, OpenAfterPublish:=True
End If

End Sub
```
EDIT:

War das problem der PageSetupdenn jede Seite, die Größe hat eine maximale pixel-Grenze, wie Sie waren Richtung in Ihrem Kommentar.

Die Größe der Seite festlegen, Übergröße A0, die sollte mehr als gerecht für Ihre 100x1500 UsedRange. Hier ändern Sie die Seitengröße mit der FitToPages... = 1 zu überprüfen, dass Ihre Range ist innerhalb der Linien drucken.

Den FitToPagesWide und FitToPagesTall ist passt alles auf eine Seite.
```
Sub GetSaveAsFilename()

Dim fileName As String

fileName = Application.GetSaveAsFilename(InitialFileName:="", _
                                         FileFilter:="PDF Files (*.pdf), *.pdf", _
                                         Title:="Select Path and FileName to save")

If fileName <> "False" Then

  'Suspending Communicaiton with Printer to Edit PageSetup via Scripting
  Application.PrintCommunication = False

  'Setting Page Setup
   With ActiveSheet.PageSetup
    .FitToPagesWide = 1
    .FitToPagesTall = 1
    ' Setting Page Size to 92x92 inch Should cater for your data
    .PaperSize = 159
   End With

  'Enabling Communicaiton with Printer
  Application.PrintCommunication = True


  'Selecting the Used Range in the Sheet
  ActiveWorkbook.Worksheets("Sheet1").UsedRange.Select

  'Saving the Selection - Here is where the problem was
  Selection.ExportAsFixedFormat Type:=xlTypePDF, fileName:=fileName, _
                                Quality:=xlQualityStandard, IncludeDocProperties:=True, _
                                IgnorePrintAreas:=True, OpenAfterPublish:=True
End If

End Sub
```
Beachten Sie, dass die Seite Leer angezeigt wird, müssen Sie Zoom in eine Menge, um die Daten anzuzeigen
- Buddy, Danke für die Antwort. Das gibt mir immer noch das gleiche Ergebnis, obwohl. Tut mir Leid, gestern hat jemand downvoted die Antwort.
- haben Sie einen Blick auf das Skript jetzt funktioniert jedes mal bei mir
- Danke für die änderung 🙂 Trotzdem bekomme ich die gleiche Ergebnisse. I guess, What am trying is may not be doable Als, 1) Breite aller Spalten zusammen ist 2750 Pixel. 2) Total no. der Spalten - 100. Is it so? stackoverflow.com/questions/33127693/...
- Vielen Dank für die neue Bearbeiten. Ich war in der Lage zu exportieren, die mehr Spalten als die Vorherige. (gleicher als andere Antwort auf diese Frage, fast 85 Spalten. Noch 15 Spalten nicht passen in der Seite) . +1 für ihn. Auch, paar meiner Spalten sind nicht lesbar. Hoffentlich werden Sie mit Papier-Größe, wie " E " wird dieses problem lösen. stackoverflow.com/questions/33127693/...
- Seite Größe 92x92 ist 233cm x 233cm, die ist größer als E. das, Was Drucker ist als Standarddrucker festgelegt? Der Drucker selbst könnte verhindern, dass Sie, wenn es eine wirklich Druckers. In meinen Tests das Skript arbeitete für eine Spalte Gesamt Breite von mehr als 2700pxl
- Dank Kumpel für die Informationen. 🙂 Ich will nicht in den drucken der exportierten PDF-Datei auf Papier. Ich brauche nur zu sehen, wie eine Kopie. Ist es möglich einzustellen das Papierformat in Microsoft excel Eigenschaften?
- Seitenlayout > Seite Einrichten > Größe. Was ich meine ist, die verfügbaren Größen in der PageSize ist abhängig, welchen Drucker ausgewählt ist. Unabhängig davon, ob Sie gehen, um die Seite zu drucken oder nicht. Ich habe PDFCreator-set als Standard-Drucker zu vermeiden, dieses Problem beim speichern als PDF
- Lassen Sie uns weiterhin diese Diskussion im chat.
InformationsquelleAutor Jean-Pierre Oosthuizen

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.