Android Studio: erstellen erstellen.gradle-Datei für die Verwendung auf Jenkins?

Ich landete diese build-Dateien von Grund auf.

Hier einige Richtlinien:

1. Wenn Sie ein Projekt mit mehreren Modulen, erstellen Sie eine Einstellungen.gradle-Datei im Stammverzeichnis Ihres Projekts (auf der gleichen Ebene wie alle Module). Ihre Einstellungen.gradle-Datei sollte wie folgt Aussehen:

   include 'ActionBarSherlock'
   include ':facebook-android-sdk-3.0.1:facebook'
   include 'google-play-services_lib'
   include ':SlidingMenu-master:library'
   include 'Tinder'
   include 'ViewPagerIndicator'
   include 'volley'
   include 'windowed-seek-bar'

2. Innerhalb jedes Modul, erstellen Sie eine build.gradle-Datei. Library-Projekte, Ihre bauen.gradle-Datei sollte wie folgt Aussehen:

   buildscript {
       repositories {
           mavenCentral()
       }
   
       dependencies {
           classpath 'com.android.tools.build:gradle:0.4.2'
       }
   }
   
   apply plugin: 'android-library'
   
   dependencies {
       compile 'com.android.support:support-v4:13.0.0'
   }
   
   android {
       buildToolsVersion "17.0"
       compileSdkVersion 17
   
       sourceSets {
           main {
               manifest.srcFile 'AndroidManifest.xml'
               java.srcDirs = ['src']
               resources.srcDirs = ['src']
               aidl.srcDirs = ['src']
               renderscript.srcDirs = ['src']
               res.srcDirs = ['res']
               assets.srcDirs = ['assets']
           }
   
           instrumentTest.setRoot('tests')
       }
   }

3. Für Ihr Projekt, Ihre bauen.gradle-Datei sollte wie folgt Aussehen:

   buildscript {
       repositories {
           mavenCentral()
       }
   
       dependencies {
           classpath 'com.android.tools.build:gradle:0.4.2'
       }
   }
   
   apply plugin: 'android'
   
   dependencies {
       compile project(':facebook-android-sdk-3.0.1:facebook')
       compile project(':google-play-services_lib')
       compile project(':SlidingMenu-master:library')
       compile project(':ViewPagerIndicator')
       compile project(':volley')
       compile project(':windowed-seek-bar')
       compile files('compile-libs/androidannotations-2.7.1.jar', 'libs/Flurry_3.2.1.jar', 'libs/google-play-services.jar', 'libs/gson-2.2.4.jar', 'libs/picasso-1.1.1.jar')
   }
   
   android {
       buildToolsVersion "17.0"
       compileSdkVersion 17
   
       sourceSets {
           main {
               manifest.srcFile 'AndroidManifest.xml'
               java.srcDirs = ['src']
               resources.srcDirs = ['src']
               aidl.srcDirs = ['src']
               renderscript.srcDirs = ['src']
               res.srcDirs = ['res']
               assets.srcDirs = ['assets']
           }
       }
   }