AS3 DAE Augmented-Reality-PaperVision 3D

Klicken Sie hier um ein video von der notwendigen Importe und arbeiten demo auf meiner Website.

Merke ich, dass Sie die Collada-Klasse, im Gegensatz zu den DAE, Klasse, die beiden wirken ein bisschen anders ist als in dem video dargestellt abobe.

Es ist auch wichtig zu beachten, dass Sie kann sehr gut sein, dies zu tun und richtig, dass es ein problem mit dem Modell oder vielleicht sogar die textur. Wenn die textur nicht geladen wird, sollte man sofort wissen, von der Konsole aus. Versuchen Sie, erstellen eine ColorMaterial und erstellen Sie eine MaterialsList-Objekt die Einstellung "alle" Eigenschaft, um die ColorMaterial Sie erstellt haben. Schließlich übergeben Sie die Liste, um die Instanziierung der Collada-oder DAE-Klassen durch die Instanziierung-oder load-Methode. Stellen Sie außerdem sicher, dass die Kamera nicht gezoomt zu schließen, möglicherweise verlassen der 3D-Objekt dahinter. Schließlich spielen mit der Waage, nicht alle Modelle kommen in der gleichen Größenordnung, und mit Collada-Klasse, im Gegensatz zu DAE, scheint zu Blasen, die das Modell erheblich wie in dem video gezeigt oben genannten link.

Hatte ich viel Zeit zum spielen mit dem FlarToolkit /Papervision3D /Collada-Partnerschaft in letzter Zeit in die Vorbereitungen für die Tony Hawk XI-website.

-Was Sie brauchen

• Eine IDE, benutze ich FlashDevelop3 RC2, aber Flex Builder oder Ihre IDE der Wahl funktioniert.
• Papervision3D 2.0 Whiteshark, (neueste build)
• Flex 3.3 SDK
• Geduld

Zu finden-und die prepping das Modell

• Verwenden Google 3D-Galerie für meine Collada-Dateien.
• Nächsten nehmen ".skp" sketchup-Datei in Google Sketchup.
• Stellen Sie sicher, dass das sketchup-Fenster hat den Fokus und drücken Sie STRG und A gleichzeitig. (Alle wählen)
• Kopf zu Bearbeiten, und gehen Sie zum unteren Rand der drop-down-Liste, wo es wird in der Regel sagen, wie viele Gruppen, die Sie ausgewählt haben.
• Wählen Sie explodieren.
• Wiederholen, bis Sie nicht explodieren können, nicht mehr. (Wenn Sie mit low-poly-Modelle, wie Sie sollen, sollte dies nicht lange dauern.)
• STRG + A wählen Sie alle wieder.
• Goto Datei > Export > 3D-Modell und wählen Sie ".dae" //Wenn Sie nicht selbst in Sketchup .dae-Erweiterung ist nicht verfügbar, Suche die Arbeit 🙂 (im Wesentlichen der .dae ist gewickelt ".skp"
• Sie haben jetzt eine .dae-Datei und einen Ordner mit dem gleichen Namen, mit den Texturen in Bezug auf das Modell im inneren.

- Importieren /analysieren Sie das Modell und die Anzeige

package 
{
    import flash.display.BitmapData;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.media.Camera;
    import flash.media.Video;
    import flash.utils.ByteArray;
    import org.libspark.flartoolkit.core.FLARCode;
    import org.libspark.flartoolkit.core.param.FLARParam;
    import org.libspark.flartoolkit.core.raster.rgb.FLARRgbRaster_BitmapData;
    import org.libspark.flartoolkit.core.transmat.FLARTransMat;
    import org.libspark.flartoolkit.core.transmat.FLARTransMatResult;
    import org.libspark.flartoolkit.detector.FLARSingleMarkerDetector;
    import org.libspark.flartoolkit.pv3d.FLARBaseNode;
    import org.libspark.flartoolkit.pv3d.FLARCamera3D;
    import org.papervision3d.cameras.Camera3D;
    import org.papervision3d.render.LazyRenderEngine;
    import org.papervision3d.scenes.Scene3D;
    import org.papervision3d.view.Viewport3D;
    import org.papervision3d.objects.parsers.Collada;
    import org.papervision3d.objects.parsers.DAE;
/**
 * ...
 * @author Brian Hodge
 */
public class Main extends Sprite 
{
    [Embed(source="../lib/camera_para.dat", mimeType="application/octet-stream")]
    private var CameraParameters:Class;

    [Embed(source="../lib/collada.pat", mimeType="application/octet-stream")]
    private var MarkerPattern:Class;

    private var cameraParameters:FLARParam;
    private var markerPattern:FLARCode;
    private var raster:FLARRgbRaster_BitmapData;
    private var detector:FLARSingleMarkerDetector;

    private var cam:Camera;
    private var vid:Video;
    private var capture:BitmapData;

    private var cam3D:FLARCamera3D;
    private var scene3D:Scene3D;
    private var viewPort:Viewport3D;
    private var mainContainer:FLARBaseNode;
    private var renderer:LazyRenderEngine;

    private var trans:FLARTransMatResult;
    private var prevSet:Boolean = false;
    private var prevZ:Number = 0;

    private var _collada:Collada;
    private var _dae:DAE;

    public function Main():void 
    {
        cameraParameters = new FLARParam();
        cameraParameters.loadARParam(new CameraParameters() as ByteArray);

        markerPattern = new FLARCode(16, 16);
        markerPattern.loadARPatt(new MarkerPattern());

        cam = Camera.getCamera();
        cam.setMode(640, 480, 30);

        vid = new Video();
        vid.width = 640;
        vid.height = 480;
        vid.attachCamera(cam);
        addChild(vid);

        capture = new BitmapData(vid.width, vid.height, false, 0x0);
        capture.draw(vid);

        raster = new FLARRgbRaster_BitmapData(capture);
        detector = new FLARSingleMarkerDetector(cameraParameters, markerPattern, 80);

        cam3D = new FLARCamera3D(cameraParameters);

        scene3D = new Scene3D();

        mainContainer = new FLARBaseNode();
        scene3D.addChild(mainContainer);

        viewPort = new Viewport3D(vid.width, vid.height);
        viewPort.scaleX = viewPort.scaleY = 2;
        addChild(viewPort);

        renderer = new LazyRenderEngine(scene3D, cam3D, viewPort);

        _dae = new DAE();
        _dae.load("assets/dae/apc.dae");
        _dae.rotationZ -= 90;
        mainContainer.addChild(_dae);

        /*
        _collada = new Collada("assets/dae/apc.dae");
        _collada.scale = 0.05;
        _collada.rotationZ -= 90;
        mainContainer.addChild(_collada);
        */

        trans = new FLARTransMatResult();

        this.addEventListener(Event.ENTER_FRAME, mainEnter);
    }
    private function mainEnter(e:Event):void 
    {
        capture.draw(vid);

        if (detector.detectMarkerLite(raster, 80) && detector.getConfidence() > 0.5)
        {
            detector.getTransformMatrix(trans);

            mainContainer.setTransformMatrix(trans);
            mainContainer.visible = true;
            renderer.render();
        }
        else
        {
            mainContainer.visible = false;
            renderer.render();
        }
    }
}

}

Hoffentlich all dies hilft Ihnen, ich schlage vor, Sie nur zu halten, mit ihm zu spielen und halten Sie vertraut sich mit ihm.

InformationsquelleAutor Brian Hodge

Ich fand einige gute Informationen, die tatsächlich bei diese Website. Ich verwendet den code zum import von Modellen, die in meinen AR-Sachen. Es beschreibt eine sehr einfache Methode für den Import von collada-Modellen. Ich habe gerade die Probe FlarToolkit Beispiel (die simpleCube Beispiel) und fügte den code in diesem Artikel, und das war genug, um mich gehen.

Hier der code:

package {
    import org.papervision3d.lights.PointLight3D;
    import org.papervision3d.materials.WireframeMaterial;
    import org.papervision3d.materials.shadematerials.FlatShadeMaterial;
    import org.papervision3d.materials.utils.MaterialsList;
    import org.papervision3d.materials.*;
    import org.papervision3d.materials.utils.*;
    import org.papervision3d.materials.shadematerials.*;
    import org.papervision3d.objects.primitives.Cube;
    import org.papervision3d.objects.primitives.Cylinder;
    import org.papervision3d.objects.DisplayObject3D;
    import org.papervision3d.objects.parsers.Collada;
    import flash.events.*;

    public class SimpleCube extends PV3DARApp {

        public var FAlogo:DisplayObject3D;
        public var light                        :PointLight3D;

        public function SimpleCube() {
            this.init('Data/camera_para.dat', 'Data/flarlogo.pat');
        }

        protected override function onInit():void {
            super.onInit();
            this.addEventListener( Event.ENTER_FRAME, EROnEnterFrame );

            //let there be light
            this.light = new PointLight3D;
            this.light.x = 0;
            this.light.y = 1000;
            this.light.z = -1000;

            //cow model
            FAlogo = new Collada("http://papervision2.com/wp-content/downloads/dae/cow.dae");
            FAlogo.rotationZ = -90;
            FAlogo.rotationY = -90;
            FAlogo.x = -100;
            FAlogo.z = 100;
            FAlogo.scale = 0.1;

            //re-orient the logo model before adding it to the scene

            this._baseNode.addChild(this.FAlogo);
        }

        private function EROnEnterFrame( event :Event ):void
        {
            //spins the cow yay!
            FAlogo.yaw(3);
        }
    }
}

InformationsquelleAutor shady