AS3: Einstellung Registrierung Punkt ein DisplayObject mit actionscript?

Wie würden Sie das registrierungskreuz auf ein Sprite oder eine Form, die über actionscript (ich weiß, das ist trivial mit Flash, aber ich muss es tun, rein in actionscript)

InformationsquelleAutor Ronn | 2009-03-16

12

Den Flash-Player-API nicht aufzudecken. Ich glaube, das liegt daran, dass Flash tatsächlich backt in der Registrierung Punkt in der shape-Daten beim erstellen der SWF-Datei. Somit gibt es keinen tatsächlichen registrierungskreuz zu verschieben (anstatt, Sie würde verschieben Sie das Form-Daten... wenn der Flash-Player erlaubt das Bearbeiten von shape-Daten!).

Ich immer dieses Problem lösen, indem Sie einfach die Erziehung meiner sprite/Form auf ein anderes DisplayObject. Also, wenn ich spriteA und wollen seiner bei der Registrierung zeigen (15, 35), ich würde dies tun:
```
var spriteB:Sprite = new Sprite();
spriteB.addChild(spriteA);
spriteA.x = 15;
spriteA.y = 35;
```
Und dann von da an finden spriteB überall, wo ich war, die zuvor unter Bezugnahme auf spriteA.
- Dies ist definitiv die einfachste und einfachste Weg. Nicht das eleganteste, aber. Bu, wenn der Aufwand mit einem extra-container ist nicht ein Problem...
InformationsquelleAutor Troy Gilbert

Mit der transform-matrix ist dies möglich. Hier ist eine gute Umsetzung dieses finden Sie auf diese Website.

public function setRegistrationPoint(s:Sprite, regx:Number, regy:Number, showRegistration:Boolean )
{
    //translate movieclip 
    s.transform.matrix = new Matrix(1, 0, 0, 1, -regx, -regy);

    //registration point.
    if (showRegistration)
    {
        var mark:Sprite = new Sprite();
        mark.graphics.lineStyle(1, 0x000000);
        mark.graphics.moveTo(-5, -5);
        mark.graphics.lineTo(5, 5);
        mark.graphics.moveTo(-5, 5);
        mark.graphics.lineTo(5, -5);
        s.parent.addChild(mark);
    }
}

Können Sie erklären dies genauer, Bitte ?
Link ist tot. Vielleicht erklärt es besser war, eine gute Sache zu tun.

InformationsquelleAutor picardo

~~für Sie bedeutet der index ?~~

Folgenden die Kommentare, die Sie tun können, eine schnelle Implementierung wie folgt Aussehen.
Dies ist nicht genau das, was Sie wollen, da Sie nicht verschiedene Ausrichtungen für jedes Kind.
Ich wollte einfach nicht machen es zu kompliziert, es ist mehr wie 'Arbeits-pseudo-code", um Ihnen eine Idee ...

package  
{
    import flash.display.DisplayObject;
    import flash.display.Sprite;    


    public class SpriteWithRegistration extends Sprite 
    {

        private var _regV:String = "T";
        private var _regH:String = "L";

        private var _width:Number = 0;
        private var _height:Number = 0;


        public function SpriteWithRegistration(width:Number, height:Number, registrationPoint:String = "TL")
        {
            this.width  = height;
            this.height = width;
            this.registrationPoint = registrationPoint;
        }

        public function set registrationPoint(p:String):void
        {
            if(p.length != 2) return;

            var regV:String = p.toUpperCase().substr(0, 1);
            var regH:String = p.toUpperCase().substr(1, 1);

            _regV = (regV == "T" || regV == "C" || regV == "B" ) ? regV : _regV;
            _regH = (regH == "L" || regH == "C" || regH == "R" ) ? regH : _regH;

            alignChildren();
        }

        override public function addChild(child:DisplayObject):DisplayObject
        {
            alignChild(child);
            super.addChild(child);
            return child;
        }

        override public function set width(value:Number):void
        {
            _width = value;
            alignChildren();
        }

        override public function get width():Number
        {
            return _width;
        }

        override public function set height(value:Number):void
        {
            _height = value;
            alignChildren();
        }

        override public function get height():Number
        {
            return _height;
        }

        private function alignChildren():void
        {
            for(var index:int = 0;index < numChildren; index++ )
                alignChild(getChildAt(index));
        }

        private function alignChild(disp:*):void
        {
            switch(_regH)
            {
                case "L":   disp.x = 0;                             break;
                case "C":   disp.x = _width*.5 - disp.width * .5;   break;
                case "R":   disp.x = _width - disp.width;           break;
            }

            switch(_regV)
            {
                case "T":   disp.y = 0;                             break;
                case "C":   disp.y = _height*.5 - disp.height * .5; break;
                case "B":   disp.y = _height - disp.height;         break;
            }
        }
    }
}

Nein, die Registrierung Punkt. standardmäßig ist es oben,Links.
BTW, es gibt keine default-Implementierung für das für sprites und shapes. Was Sinn macht, da es hängt ganz auf, wie Sie Ihr Objekt angepasst werden. Am besten verwenden Sie ein UI-framework oder bauen Sie Ihre eigenen ein. Die Idee angeben, die Größe der Halter und die Ausrichtungen der Kinder.

InformationsquelleAutor Theo.T

Ich hoffe, dies hilft jemand. Das Starling framework hat eine fantastische Methode, genannt "alignPivot()". Ich nahm Ihr Konzept und passte es an die Flash DisplayList. Sie im Grunde sagen Sie ein sprite zu ändern Sie die Registrierung, um Links, rechts, Mitte, oben und unten. Dieser code fügt Ihr sprite in einen container sprite und positioniert sich entsprechend. Es gibt die container-sprite mit dem original-sprite-innen enthalten.

Code gespeichert in einer separaten namens genannt, "Position".

    public static function alignPivot(s:DisplayObject, horizontalAlign: String = "center", verticalAlign: String = "center", showRegistration: Boolean = false, _color: uint = 0x000000): Sprite {

        //create a container sprite to house the sprite you'd like to move
        var _container: Sprite = new Sprite();
        //add your sprite to the continer sprite (the container sprite is what will be returned)
        _container.addChild(s);
        //using getBounds(), find the x,y,width,and height of your sprite within the continer.
        var bounds:Rectangle = _container.getBounds(s);
        //create variables for x and y cooridnates
        var xVal: Number;
        var yVal: Number;

        //I have a separate class called Align which contains public static constants for positiong.
        //Check the values passed above and get the correct x value;
        if (horizontalAlign == Align.LEFT) xVal = -bounds.x;
        else if (horizontalAlign == Align.CENTER) xVal = -bounds.x - bounds.width * .5;
        else if (horizontalAlign == Align.RIGHT) xVal = -bounds.x - bounds.width;
        else throw new ArgumentError("Invalid horizontal alignment: " + horizontalAlign);

        //Check the values passed above and get the correct y value;
        if (verticalAlign == Align.TOP) yVal = -bounds.y;
        else if (verticalAlign == Align.CENTER) yVal = -bounds.y - bounds.height * .5;
        else if (verticalAlign == Align.BOTTOM) yVal = -bounds.y - bounds.height;
        else throw new ArgumentError("Invalid vertical alignment: " + verticalAlign);

        //apply the new x and y cooridnates to your sprite (the one moving within the container we created above)
        s.x = xVal;
        s.y = yVal;

        //optional - this will create a small X at the 0,0 position of the container.
        //This is helpful if you want to see where your registration points are
        if (showRegistration) {
            var mark: Sprite = new Sprite();
            mark.graphics.lineStyle(1, _color);
            mark.graphics.moveTo(-5, -5);
            mark.graphics.lineTo(5, 5);
            mark.graphics.moveTo(-5, 5);
            mark.graphics.lineTo(5, -5);
            _container.addChild(mark);
        }
        //return your contianer sprite
        //This will replace the sprite that you passed in the first parameter.
        //That sprite is inside the container, so you won't notice
        return _container;


    }

Umsetzung:

//Create your sprite
        var _holder: Sprite = new Sprite();
    //Create a shape to put in your sprite
        var my_shape: Shape = new Shape();
        my_shape.graphics.beginFill(0x000000);
        my_shape.graphics.drawRect(0, 0, 200, 100);
        my_shape.graphics.endFill();
    //Add the shape to your sprite
        _holder.addChild(my_shape);
    //Align the holder (must be done AFTER all children have been added)
    //This will put the registration point at the top-center of the sprite. 
    //_holder is replaced by a sprite (container) that contains _holder.
    //The _holder inside the container is positioned appropriately.
    _holder = Position.alignPivot(_holder,Align.CENTER, Align.TOP);
    //Add the new sprite to your stage.
    this.addChild(_holder);

Liste von Konstanten, so dass Sie nicht haben, schreiben Sie sich selbst:

    public static const CENTER:String = "center";
    public static const LEFT:String = "left";
    public static const RIGHT:String = "right";
    public static const TOP:String = "top";
    public static const BOTTOM:String = "bottom";

InformationsquelleAutor Tony

0

Je nachdem, warum Sie es brauchen, es könnte gelöst werden durch die Verwendung von DisplayObject.verwandeln.matrix, das gibt einen Matrix Objekt.

Zum Beispiel, wenn Sie wollte, ändern Sie den Punkt der rotation, dann können Sie mit der Transformation der matrix zu tun.

InformationsquelleAutor Richard Szalay

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.