AS3: Kann ByteArray wieder seinen Inhalt als string mit zwei bytes pro unicode-Zeichen?

Können Sie interpretieren Ihre ByteArray als nur mit shorts. Diese können Sie Lesen zwei Byte zu einem Zeitpunkt und Holen Sie sich eine einzige Zahl, Wert für Sie beide. Als Nächstes können Sie diese zahlen und interpretieren Sie als Zeichen-codes. Schließlich erstellen Sie eine String aus diesen Zeichen und du bist fertig.

public static function encode(ba:ByteArray):String {
    var origPos:uint = ba.position;
    var result:Array = new Array();

    for (ba.position = 0; ba.position < ba.length - 1; )
        result.push(ba.readShort());

    if (ba.position != ba.length)
        result.push(ba.readByte() << 8);

    ba.position = origPos;
    return String.fromCharCode.apply(null, result);
}

Gibt es einen besonderen Umstand zu beachten. Wenn Sie versuchen, das Lesen eines kurzen aus einem ByteArray wenn es nur ein byte verbleiben, wird eine Ausnahme geworfen. In diesem Fall sollten Sie anrufen readByte mit dem Wert verschoben 8 bit statt. Das ist das gleiche, als wenn die ursprüngliche ByteArray hatte ein zusätzliches 0-byte am Ende. (so dass es sogar in der Länge)

Nun, wie für die Dekodierung dieser String... das Zeichen-code der einzelnen Zeichen, und legen Sie Sie in eine neue ByteArray als shorts. Es wird identisch sein mit dem original, außer wenn das original hatte eine ungerade Anzahl von bytes, in dem Fall decodiert ByteArray wird ein zusätzliches 0-byte am Ende.

public static function decode(str:String):ByteArray {
    var result:ByteArray = new ByteArray();
    for (var i:int = 0; i < str.length; ++i) {
        result.writeShort(str.charCodeAt(i));
    }
    result.position = 0;
    return result;
}

In Aktion:

var ba:ByteArray = new ByteArray();

ba.writeInt(47);
ba.writeUTF("Goodbye, cruel world!");

var str:String = encode(ba);
ba = decode(str);

trace(ba.readInt());
trace(ba.readUTF());

InformationsquelleAutor Gunslinger47