Aufzählen der Liste der Netzwerk-Computer und freigegebene Ordner in einer Baumansicht?

Ich weiß, es gibt viele Möglichkeiten aufzählen von Computern und Geräten im Netzwerk, aber wie kann ich zeigen nur Computer für die Windows Dateifreigabe? Ich muss einen Baum-Ansicht von Netzwerk-Computern und freigegebenen Ordnern. Ich weiß, dass ich verwenden könnte, die bestehende shell-Steuerelemente für diese, aber ich würde lieber halten Sie es in meinem eigenen Baum-Ansicht. Es wird nur eine Liste der betroffenen Computer auf dem Netzwerk die freigegebenen Ordner. Vorbei an den Computern und deren freigegebenen Ordner, ich kann die einzelnen directory-listing Teil selbst. Ich muss nur wissen, wie man die Liste computer und deren freigegebene Ordner Listen.

InformationsquelleAutor Jerry Dodge | 2012-07-22
  1. 2

    WNetOpenEnum geben Sie alle Computer im Netzwerk

    Der Funktion WNetOpenEnum beginnt eine Aufzählung von Netzwerk-Ressourcen
    oder bestehende verbindungen. Sie können weiterhin die Aufzählung durch den Aufruf
    die WNetEnumResource Funktion.

    NetShareEnum werden Sie alle Freigaben auf einem Rechner.

    Ruft Informationen über jede freigegebene Ressource auf einem server.

    Können Sie die Kombination der beiden heraus zu filtern, was Sie nicht wollen

    • Zusätzlicher Auszug aus Msdn NetSharesEnum Eintrag: You can also use the WNetEnumResource function to retrieve resource information. However, WNetEnumResource does not enumerate hidden shares or users connected to a share: wenn die Aufzählung verborgene Ressourcen sind Teil der OP-Anforderungen NetShareEnum ist nicht eine option, oder?
    InformationsquelleAutor parapura rajkumar
  2. 3

    Bitte beachten Sie die folgenden Ressourcen, wenn Sie daran interessiert sind, Beispiel Delphi-code mit WNetOpenEnum/WNetOpenEnum Windows-API:

    Dass eine gute Beherrschung der NETRESOURCE Struktur ist auch muss.

    Ich personnaly empfehlen die folgenden Auflistungen von http://www.developpez.net's Forum:

    Liste #1:

    unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, Unit2;

type
  TForm1 = class(TForm)
    ListBox1: TListBox;
    procedure FormCreate(Sender: TObject);
  private
    procedure EnumNetworkProc(const aNetResource :TNetResource; const aLevel :word; var aContinue :boolean);
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

{ TForm1 }

procedure TForm1.EnumNetworkProc(const aNetResource :TNetResource; const aLevel :word; var aContinue :boolean);
begin
  if aNetResource.dwDisplayType in [RESOURCEDISPLAYTYPE_DOMAIN, RESOURCEDISPLAYTYPE_SERVER] then
    ListBox1.Items.Add(StringOfChar(' ', aLevel*4) +aNetResource.lpRemoteName);
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  EnumNetwork(EnumNetworkProc, RESOURCE_GLOBALNET, RESOURCETYPE_DISK);
end;

end.

    Listing #2:

    unit Unit2;

interface

uses Windows;

type
  TEnumNetworkProc = procedure(const aNetResource :TNetResource; const aLevel :word; var aContinue :boolean) of object;

procedure EnumNetwork(const aEnumNetworkProc :TEnumNetworkProc; const aScope :dword = RESOURCE_GLOBALNET; const aType :dword = RESOURCETYPE_ANY);

implementation

//Procédure récursive
procedure DoEnumNetwork(const aContainer :Pointer;
                        const aEnumNetworkProc :TEnumNetworkProc;
                        const aScope :dword;
                        const aType  :dword;
                        const aLevel :byte);
type
  PNetResourceArray = ^TNetResourceArray;
  TNetResourceArray = array [0..0] of TNetResource;
var
  NetHandle    :THandle;
  NetResources :PNetResourceArray;
  NetResult    :dword;
  Size, Count, i :Cardinal;
  Continue     :boolean;
begin
  Continue := TRUE;

  NetResult := WNetOpenEnum(aScope, aType, 0, aContainer, NetHandle);

  if NetResult = NO_ERROR then
  try
    //Taille de base
    Size := 50 *SizeOf(TNetResource);
    GetMem(NetResources, Size);

    try
      while Continue do
      begin
        Count := $FFFFFFFF;
        NetResult := WNetEnumResource(NetHandle, Count, NetResources, Size);

        //Taille insuffisante ?
        if NetResult = ERROR_MORE_DATA
        then ReallocMem(NetResources, Size)
        else Break;
      end;

      //Enumère
      if NetResult = NO_ERROR then
        for i := 0 to Count - 1 do
        begin
          //Callback
          if Assigned(aEnumNetworkProc) then
          begin
            aEnumNetworkProc(NetResources^[i], aLevel, Continue);
            if not Continue then Break;
          end;

          //Appel récursif
          if (NetResources^[i].dwUsage and RESOURCEUSAGE_CONTAINER) > 0 then 
            DoEnumNetwork(@NetResources^[i], aEnumNetworkProc, aScope, aType, aLevel +1);
        end;
    finally
      FreeMem(NetResources, Size);
    end;
  finally
    WNetCloseEnum(NetHandle);
  end;
end;

procedure EnumNetwork(const aEnumNetworkProc: TEnumNetworkProc; const aScope, aType: dword);
begin
  DoEnumNetwork(nil, aEnumNetworkProc, aScope, aType, 0);
end;

end.

    Quelle: Liste des machines sur un réseau local (tout le réseau de Win) - Original-Beitrag (in Französisch) von Lucas Panny.

    InformationsquelleAutor menjaraz
Schreibe einen Kommentar