Ausführen von Befehlen in eine batch-Datei, die innerhalb einer anderen batch-Datei

Meine erste interpretation der Frage führte mich zu glauben, dass Sampath wollte eine batch-Skript, das zwei Sätze von Befehlen. Aufruf wäre es der 1. Satz von Befehlen in das übergeordnete Fenster, ein zweites Fenster öffnen würde, der würde laufen das gleiche script mit thd 2. Satz von Befehlen.

"%~f0" geben Sie den vollständigen Pfad der aktuell ausgeführten batch-Skript. Ein einfaches Kommandozeilen-argument dient als Schalter, um zu bestimmen, welcher code ausgeführt werden.

@echo off
if "%~1"==":PART2" goto %~1

::use this line if 2nd window is to remain open upon completion
::start "%~f0" :PART2

::use this line if 2nd window is to close upon completion
start cmd /c "%~f0" :PART2

echo Test parent output
pause
exit /b

:PART2
echo Test child output
pause
exit /b

Andriy M schlägt Sampath will in der Lage sein, um dynamisch das senden von Befehlen an das 2. Fenster. Diese kann getan werden, mit 2 scripts, die ich nennen werde Meister.bat-und-slave -.bat.

Den slave.bat einfach liest Befehle von der Standardeingabe und führt Sie aus. Die master.BVT startet den slave mit Eingang umgeleitet, um eine Kommando-Datei und fügt Befehle an das command-file.

Hier ist ein Beispiel des Meisters.Fledermaus, die zeigt, dymamically senden Befehle an den slave. Beachten Sie, dass die master aufgefordert, einen Befehl, aber der slave-Fenster den Fokus haben. Stellen Sie sicher, klicken Sie auf die master-so können Sie den Befehl Ihrer Wahl.

@echo off

:: create an empty command file
type nul >cmds.txt

:: start the slave with input redirected to the command file
start slave.bat ^<cmds.txt

:: issue some commands by appending them to the command file
>>cmds.txt echo echo command 1
>>cmds.txt echo echo command 2
>>cmds.txt echo echo(
>>cmds.txt echo rem /?

:: ask for a command to send to the slave
set /p "cmd=Enter a command to be sent to the slave: "

:: send the command
>>cmds.txt echo %cmd%

::pause so we can see the results in the slave window
for /l %%n in (1 1 1000000) do rem

::tell the slave to exit
>>cmds.txt echo exit

Und hier ist der Sklave.bat

@echo off
:top
set "cmd="
set /p "cmd="
%cmd%
goto :top

Es klingt fast wie was Sie wollen, ist eine Datei, die enthält Befehle, die Sie ausführen möchten, und verwenden Sie eine batch-Skript und rufen auf diese Befehle, wenn Sie wollen?

Habe ich umgesetzt, indem eine batch-Datei enthält alle Befehle (code-snippets), die ich nützlich finde, und dann mit meinem anderen batch-scripts aufrufen, die "master" - Datei für meine snippets.

Zum Beispiel in meinem MASTER_BAT.BAT - Datei, ein Beispiel für ein snippet zu erstellen, Daten in anderes format für die Verwendung so Aussehen:

GOTO:%~1

:GET_CURRENT_DATE
:: Created: 1/19/2012
:: Creates variables for the date format in different forms.
:: No additional arguments required
SET DISABLED=0
IF [%DISABLED%] == [1] GOTO:EOF
:: Created: 11/30/11
:: Creates date formats.
Set mdy=%date:~4,2%-%date:~7,2%-%date:~12,4%
Set mdY=%date:~4,2%-%date:~7,2%-%date:~10,4%
Set Dmdy=%date:~0,4%%date:~4,2%-%date:~7,2%-%date:~12,4%
Set DmdY=%date:~0,4%%date:~4,2%-%date:~7,2%-%date:~10,4%
Set ymd=%date:~12,4%-%date:~4,2%-%date:~7,2%
Set ymd=%date:~10,4%-%date:~4,2%-%date:~7,2%

GOTO:EOF

Und in meinem CHILD_BAT.BAT, ich will das snippet zu erstellen, der Datum-Formate... können sagen, ich will es so machen, dass ich anrufen kann das Datum durch das aktuelle Datum im mm/TT/JJ-format:

CALL MASTER_BAT.BAT "GET_CURRENT_DATE"
ECHO %mdy%
PAUSE

Ihre Ausgabe für CHILD_BAT.BAT wäre:

1-23-12
Press any key to continue...

Außerdem werden alle Variablen erstellt, die in Ihrem CHILD_BAT.BAT vor der CALL Befehl übergeben werden, um die MASTER_BAT.BAT Skript als gut. Jedoch, die for-Schleife interation, enthält eine CALL wird nicht passieren die for-Schleife temporäre variable.

Hoffe, das ist hilfreich.

EDIT: Hinweis, dass mein snippet ist verwendbar für das US-Datumsformat.