Ausgabe die Tiefe des aktuellen Knotens in der Hierarchie

Unter Verwendung von XSLT/XPATH 1.0, ich möchte HTML-Code erstellen, wo die class Attribut eines span element zeigt die Tiefe in der ursprünglichen XML-Hierarchie.

Beispielsweise mit diesem XML-fragment:

<text>
    <div type="Book" n="3">
        <div type="Chapter" n="6">
            <div type="Verse" n="12">
            </div>
        </div>
    </div>
</text>

Möchte ich diese HTML:

<span class="level1">Book 3</span>
<span class="level2">Chapter 6</span>
<span class="level3">Verse 12</span>

Wie tief diese div Elemente gehen könnte, ist nicht a priori bekannt. Die divs konnte sein Buch -> Kapitel. Sie konnte sein Volumen -> Buch -> Kapitel -> Absatz -> Line.

Kann ich nicht verlassen sich auf die Werte von @Typ. Einige oder alle Null-Werte.

InformationsquelleAutor JPM | 2012-02-04
  1. 17

    Dieser hat eine sehr einfache und kurze Lösung-keine Rekursion, keine Parameter, keine xsl:element keine xsl:attribute:

    <xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="div">
  <span class="level{count(ancestor::*)}">
   <xsl:value-of select="concat(@type, ' ', @n)"/>
  </span>
  <xsl:apply-templates/>
 </xsl:template>
</xsl:stylesheet>

    wenn diese transformation wird angewendet auf das XML-Dokument:

    <text>
    <div type="Book" n="3">
        <div type="Chapter" n="6">
            <div type="Verse" n="12"></div></div></div>
</text>

    die wollten, das richtige Ergebnis produziert wird:

    <span class="level1">Book 3</span>
<span class="level2">Chapter 6</span>
<span class="level3">Verse 12</span>

    Erklärung: Korrekte Verwendung von Vorlagen, AVT und die count() Funktion.

    InformationsquelleAutor Dimitre Novatchev
  2. 5

    Ohne oder mit Rekursion - aber Dimitre Antwort ist besser als meine eine

    <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes"/>

<xsl:template match="/text">
    <html>
        <body>
            <xsl:apply-templates/>
        </body>
    </html>
</xsl:template>

<xsl:template match="//div">
    <xsl:variable name="depth" select="count(ancestor::*)"/>
    <xsl:if test="$depth > 0">
        <xsl:element name="span">
            <xsl:attribute name="class">
                <xsl:value-of select="concat('level',$depth)"/>
            </xsl:attribute>
            <xsl:value-of select="concat(@type, ' ' , @n)"/>
        </xsl:element>
    </xsl:if>
    <xsl:apply-templates/>
</xsl:template>

</xsl:stylesheet>
    InformationsquelleAutor Kevan
  3. 0

    Da in der Regel mit XSL Rekursion.

    <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="html" indent="yes"/>

  <xsl:template match="/text">
    <html>
      <xsl:apply-templates>
        <xsl:with-param name="level" select="1"/>
      </xsl:apply-templates>
    </html>
  </xsl:template>


  <xsl:template match="div">
    <xsl:param name="level"/>

    <span class="{concat('level',$level)}"><xsl:value-of select="@type"/> <xsl:value-of select="@n"/></span>

    <xsl:apply-templates>
      <xsl:with-param name="level" select="$level+1"/>
    </xsl:apply-templates>
  </xsl:template>


</xsl:stylesheet>
    InformationsquelleAutor GSerg
Schreibe einen Kommentar