Batch-Datei so rufen Sie eine andere batch-Datei auf eine angegebene Sprungmarke (label) oder anrufen und sofort springen eine bestimmte Bezeichnung?

Könnte passieren das Etikett, das Sie wollen, zu gehen, um als parameter

Beispiel-Skripte, die

Ersten.bat

@echo off
set label=GOHERE
call Second.bat %label%
pause >nul

Sekunde.bat

@echo off
goto %1
echo This line should be skipped
:GOHERE
echo Jumped here

Gibt es mehrere Methoden oder tricks, die es erlaubt, dies zu tun. In dieser Lösung wird der trick besteht in der ändern Sie den Kontext des Laufenden Programms, um die zweite Batch-Datei. Nach dieser änderung, alle Etiketten in der zweiten Batch-Datei wird lokalen labels des Laufenden Programms, so dass Sie direkt aufgerufen, über die üblichen call :label - Befehl, der kann sich auch auf die Argumente in eine ganz übliche Weise. Der Kontext des Laufenden Programms wiederhergestellt werden muss, bevor das Programm beendet wird.

Den Weg, um den Kontext zu ändern, bestehen nur umbenennen die zweite Batch-Datei mit dem gleichen Namen der erste (und benennen Sie die erste, der jedem anderen Namen) also wenn die Batch-Datei Prozessor sieht für ein label, es ist wirklich durchsuchen Sie die Inhalte der zweiten Datei! Die Dateien müssen umbenannt werden, wieder Ihren ursprünglichen Namen, bevor das Programm beendet wird. Der Schlüssel Punkt das macht diese Methode funktioniert ist, dass beide Sätze von rename-Befehle (und alle code zwischen Ihnen), müssen in Klammern; auf diese Weise, den code zuerst analysiert und dann ausgeführt aus dem Speicher, also das umbenennen der Dateien auf der Festplatte nicht beeinflussen. Natürlich, dieser Punkt bedeutet, dass der Zugriff auf die Werte aller Variablen in den code getan werden muss, über die Verspätung !Erweiterung! (oder mit der call %%variable%% trick).

Ersten.bat

@echo off

rem Change the running context to the second/library batch file:
(
ren first.bat temporary.bat
ren second.bat first.bat

rem From this point on, you may call any label in second.bat like if it was a local label

call :label2
echo Returned from :label2
call :label1
echo Returned from :label1

rem Recover the running context to the original batch file
ren first.bat second.bat
ren temporary.bat first.bat
)

echo This is first.bat ending...
pause > nul

Sekunde.bat

@echo off

:label1
echo I am label1 subroutine at second.bat
goto :EOF

:label2
echo This is the second subroutine at second.bat
goto :EOF

AUSGABE

This is the second subroutine at second.bat
Returned from :label2
I am label1 subroutine at second.bat
Returned from :label1
This is first.bat ending...

Sollten Sie beachten, dass diese Methode ermöglicht entwickeln, die Unterprogramme in der ersten Datei in der üblichen Weise (ohne Kontext ändern) und dann bewegen Sie einfach den ausgefüllten Unterprogrammen, die zweite/Bibliothek-Datei, weil die Art und Weise, Sie zu nennen ist genau das gleiche in beiden Fällen. Diese Methode erfordert keine änderungen, die in der zweiten/Bibliothek-Datei oder in der Art, wie Unterprogramme aufgerufen werden; es muss nur stecken Sie die zwei kleinen Blöcke umbenennen Befehle in der ersten Datei.

BEARBEITEN: die Wiederherstellung von Dateien, wenn ein run-time Fehler passieren

Wie angegeben in einem Kommentar, wenn Sie eine Laufzeit-Fehler auftreten, nachdem die Dateien wurden umbenannt, die Dateien werden nicht umbenannt, zurück an Ihre ursprünglichen Namen; es ist jedoch sehr leicht zu erkennen, dieser situation durch die Anwesenheit des zweiten.bat-Datei und die Dateien wiederherzustellen, wenn eine solche Datei nicht existiert. Dieser test kann getan werden, in einer supervisor-Abschnitt, führen Sie den original-code in einer separaten cmd.exe Kontext, so wird dieser Abschnitt immer komplett richtig, auch wenn der ursprüngliche code wurde abgebrochen durch einen Fehler.

Ersten.bat

@echo off

if "%~1" equ "Original" goto Original

rem This supervisor section run the original code in a separate cmd.exe context
rem and restore the files if an error happened in the original code
(
cmd /C "%~F0" Original
if not exist second.bat (
   echo Error detected!  Restoring files
   ren first.bat second.bat & ren temporary.bat first.bat
)
goto :EOF
)


:Original

( ren first.bat temporary.bat & ren second.bat first.bat

call :label1
echo Returned from :label1
call :label2
echo Returned from :label2

ren first.bat second.bat & ren temporary.bat first.bat )

echo This is first.bat ending...

Sekunde.bat

@echo off

:label1
echo I am label1 subroutine at second.bat
exit /B

:label2
set "var="
if %var% equ X echo This line cause a run-time error!
exit /B

AUSGABE

I am label1 subroutine at second.bat
Returned from :label1
No se esperaba X en este momento.
Error detected!  Restoring files

Wie gesagt in dem Kommentar, den ich an meine Antwort, ich erhielt das Kopfgeld, da @NicoBerrogorry nahm sich die Zeit zu entwickeln, eine hervorragende Lösung und bieten ein komplettes schreiben.

Dennoch, es war ein syntax Fehler, dass er übersehen, wahrscheinlich, weil er nicht die CMD - Dateien, während ich fast völlig aufgegeben BAT - Dateien. Die folgenden CALLAT Skript beinhaltet eine Korrektur und vier Erweiterungen.

1. Es Griffe vollständig angegebenen Befehle, d.h. Befehle, die angeben, den Namen der Datei mit Verlängerung.
2. Korrigiert er die Aufsicht in der ursprünglichen, die es verursacht, zu ignorieren CMD - Dateien.
3. Wenn die Ziel-Datei kann einfach nicht gefunden werden, erscheint eine Fehlermeldung.
4. Die für Schleife fügt der Datei eine Zeile zu einem Zeitpunkt ersetzt wird, mit einem dezidiert old-school - KOPIEREN - Befehl, fügt den target-Skript-Datei, die zwei-Linien-Präambel das macht die ganze Arbeit. In Fall, dass Sie vergessen haben oder nicht wissen, über Sie, die > NUL: am Ende der copy-Befehl löscht die "1 Datei kopiert" - Meldung.
5. Während das original die Erfüllung Ihrer mission, dauerte es nicht reinigen bis nach sich; diese version tut dies, indem Sie die temporäre Skript-Datei und das temporäre Verzeichnis, in dem es erstellt wird.

HTML:

@ECHO OFF
SETLOCAL EnableDelayedExpansion

rem Create a folder in the temporary files directory.
IF NOT EXIST "%TEMP%\CALLAT\" MKDIR "%TEMP%\CALLAT\"

rem Chose a name for the modified script.
SET MODIFIED_SCRIPT="%TEMP%\CALLAT\modified_%1.bat"

rem Convert the called script name to the corresponding .bat
rem or .cmd full path to the called script.

rem Then load the script. - 2017/05/08 - DAG - The second if exist test duplicated the first. Instead, it must evaluate for the .CMD extension.

SET "COMMAND_FILE=%~dp0%1"
IF EXIST "%COMMAND_FILE%.bat" (
    SET "COMMAND_FILE=%COMMAND_FILE%.bat"
) ELSE IF EXIST "%COMMAND_FILE%.cmd" (
    SET "COMMAND_FILE=%COMMAND_FILE%.cmd"
) else if exist "%COMMAND_FILE%" (
	echo INFO: Using "%COMMAND_FILE%"
) else (
	echo ERROR: Cannot find script file %COMMAND_FILE%.bat
	echo                             or %COMMAND_FILE%.cmd
)

rem Add some lines to go directly to the desired label.
ECHO @ECHO OFF> %MODIFIED_SCRIPT%
ECHO GOTO %2>> %MODIFIED_SCRIPT%

rem Append the called script.
copy %MODIFIED_SCRIPT%+%COMMAND_FILE% %MODIFIED_SCRIPT% > NUL:

rem Call the modified script.
CALL %MODIFIED_SCRIPT%

rem Pack out your trash. When a script ends, you get an ENDLOCAL for free.
del %MODIFIED_SCRIPT%
rd "%TEMP%\CALLAT\"

Schließlich, diese version von CALLAT entfällt eine redundante ECHO OFF und die abschließende ENDLOCAL, die ich vor langer Zeit entdeckt, ist unnötig, weil aus dem Skript impliziert ENDLOCAL.

Da fast alle meiner Produktion scripts bewohnen ein einzelnes Verzeichnis, das zugänglich ist über den Verzeichnis-PFAD-Liste, die Anforderung, dass beide Skripte bewohnen das gleiche Verzeichnis ist nicht eine erhebliche Behinderung. Außerdem, mit ein wenig mehr Arbeit, es könnte fast sicher sein, entspannt. Das überlasse ich Ihnen als übung für den interessierten Leser, aber ich gebe dir einen Anhaltspunkt; es könnte bedeuten, aufrufen ein internes Unterprogramm, das Parsen der name der input-Datei durch den Einsatz der beschriebenen Technik [im Command-Line-Parameter].Eins

Oben gezeigten Skript ist zu finden Ihren Weg in die Produktion.