Batch-Datei und DEL errorlevel 0 Problem

Dem Stapel zu entfernen, Dateien und Verzeichnisse von bestimmten Orten und Ausgang Erfolg oder stdout/stderr-Nachrichten, um eine neue .txt-Datei. Ich habe die meisten das Skript und führt es genau so, wie es sollte, außer, wenn das löschen erfolgreich ist, bewegt sich vorwärts zur nächsten Zeile, vielmehr als echo einer "erfolgreich" Meldung auf dem Protokoll.

echo Basic Deletion Batch Script > results.txt
@echo off
call :filelog >> results.txt 2>&1
notepad results.txt
exit /b

:filelog

call :delete new.txt
call :delete newer.txt
call :delete newest.txt
call :remove c:\NoSuchDirectory

GOTO :EOF

:delete
echo deleting %1
del /f /q c:\Users\newuser\Desktop\%1 
if errorlevel 0 echo succesful

GOTO :EOF

:remove
echo deleting directory %1
rmdir /q /s %1

GOTO :EOF

Aus irgendeinem Grund kann ich nicht finden, die syntax für die if-del erfolgreich echo 'erfolgreich'. In dem obigen Beispiel, wenn ich die Zeile entfernen

if errorlevel 0 echo successful

Alles funktioniert gut, aber keine Erfolgsmeldung. Mit dieser Zeile Links in Echos Erfolg für jede Zeile.

InformationsquelleAutor John Scott | 2014-04-09

7

del und ErrorLevel?

Den del Befehl nicht die ErrorLevel solange die angegebenen Parameter gültig sind, wird es sogar resetet die ErrorLevel zu 0 in solchen Fällen (zumindest für Windows 7).

del ändert die ErrorLevel nur im Fall, dass eine ungültige Option angegeben wird (del /X setzt ErrorLevel zu 1), werden keine Argumente angegeben, werden alle (del setzt ErrorLevel zu 1 auch), oder einen falschen Datei-Pfad angegeben ist (del : setzt ErrorLevel zu 123), zumindest für Windows 7.

Möglich Zu Arbeiten, Um

Ein möglicher work-around ist das erfassen der STDERR Ausgabe von del, weil im Falle der Löschung von Fehlern, die damit verbundenen Meldungen (Could Not Find [...], Access is denied., The process cannot access the file because it is being used by another process.) sind geschrieben. Eine solche Aussehen könnte:
```
for /F "tokens=*" %%# in ('del /F /Q "\path\to\the\file_s.txt" 2^>^&1 1^> nul') do (2> nul set =)
```
Verwenden Sie den code in der Eingabeaufforderung direkt, anstatt in eine batch-Datei schreiben %# statt %%#.

Wenn Sie nicht wollen, zu löschen, nur-lese-Dateien, entfernen Sie /F von der del Befehlszeile;

wenn Sie möchten, dass die Ansagen (im Falle von Platzhaltern ? - und/oder * vorhanden sind, in den Pfad der Datei), entfernen /Q.

Erklärung von Code

Dieser führt den Befehl aus Zeile del /F /Q "\path\to\the\file_s.txt". Durch den Teil 2>&1 1> nul, die Ausgabe des Befehls an STDOUT entlassen werden, und seine STDERR Ausgabe umgeleitet werden, so dass for /F erhält.

Wenn der Löschvorgang erfolgreich war, del erzeugt keine STDERR Ausgang, daher der for /F Schleife nicht Durchlaufen, da gibt es nichts zu analysieren. Beachten Sie, dass ErrorLevel wird nicht zurückgesetzt in dem Fall, sein Wert bleibt unverändert.

Wenn for /F erhält jeder STDERR Ausgabe vom del Befehlszeile-der Befehl in der Schleife ausgeführt wird, die set =; dies ist eine ungültige syntax, daher set legt die ErrorLevel zu 1. Die 2> nul Teil vermeidet die Nachricht The syntax of the command is incorrect. angezeigt werden.

Um die ErrorLevel explizit Sie können auch cmd /C exit /B 1. Vielleicht diese Zeile besser lesbar. Für sicher, es ist mehr flexibel, denn Sie können jede (vorzeichenbehaftete 32-bit) Zahl, einschließlich 0 um es zu deaktivieren (das weglassen der Nummer löscht Sie auch). Vielleicht ist es ein bisschen schlimmer in Bezug auf Leistung, obwohl.

Anwendungsbeispiel

Folgende batch-Datei zeigt, wie Sie die oben beschriebene Problemumgehung angewendet werden könnte:
```
:DELETE
echo Deleting "%~1"...
rem this line resets ErrorLevel initially:
cmd /C exit /B
rem this line constitutes the work-around:
for /F "tokens=*" %%# in ('del /F /Q "C:\Users\newuser\Desktop\%~1" 2^>^&1 1^> nul') do (2> nul set =)
rem this is the corrected ErrorLevel query:
if not ErrorLevel 1 echo Deleted "%~1" succesfully.
goto :EOF
```
Voreinstellung ErrorLevel

Neben den oben genannten Befehl cmd /C exit /B können Sie auch > nul ver zum zurücksetzen der ErrorLevel. Dies kann kombiniert werden mit der for /F Schleife arbeiten-etwa wie diese:
```
> nul ver & for /F "tokens=*" %%# in ('del /F /Q "\path\to\the\file_s.txt" 2^>^&1 1^> nul') do (2> nul set =)
```
Alternative Methode Ohne for /F

Anstatt for /F zu erfassen, die STDERR Ausgabe von del, die find - Befehl kann auch benutzt werden, wie find /V "" gibt eine ErrorLevel von 1 wenn ein leerer string kommt und in 1 ansonsten:
```
del "\path\to\the\file_s.ext" 2>&1 1> nul | find /V "" 1> nul 2>&1
```
Jedoch, dies würde die Rückkehr eine ErrorLevel von 1 im Fall, dass die Löschung erfolgreich war und die 0 wenn nicht. Umkehren, das Verhalten, eine if/else Klausel könnte angefügt werden, wie diese:
```
del "\path\to\the\file_s.ext" 2>&1 1> nul | find /V "" 1> nul 2>&1 & if ErrorLevel 1 (1> nul ver) else (2> nul set =)
```
InformationsquelleAutor aschipfl
1

Wenn Sie die Verwendung dieser syntax, statt diese
```
if errorlevel 0 echo successful
```
können Sie diese - weil errorlevel 0 ist immer wahr.
```
if not errorlevel 1 echo successful
```
InformationsquelleAutor foxidrive
1

Verwenden Sie einfach rm aus UnxUtils (oder gow oder cygwin). Es setzt den errorlevel korrekt, im Falle einer nicht vorhandenen Datei, oder alle Fehler löschen der Datei.
- Bestätigen Sie, rm setzt errorlevel auf eine nicht vorhandene Datei, während del nicht.
InformationsquelleAutor clueless
0

Soviel ich mich erinnern kann die korrekte syntax ist:
```
if %errorlevel% == 0 echo succesful
```
Dass die Prozent-Zeichen sind ein Hinweis auf check environment-Variablen.
- Das habe ich versucht, es noch echos erfolgreich für jede Zeile.
- Diese Arbeit sollte zum Debuggen könntest du echo der Dateiname und seine errorlevel.
- Scheint, dass die DEL-Kommando ist immer erfolgreich, in seiner eigenen Art und Weise. Es löscht die Dateien oder verursacht einen Ausgang, beide sind als Erfolg (errorlevel 0). Ich denke, eine andere Möglichkeit, dies zu tun. Wenn jemand eine Idee hat bin ich offen. Dank
- Sie verwenden konnte, wenn nicht vorhanden mit dem Namen
- Ich dachte, die arbeiten rund um.... original post editiert. Dank
InformationsquelleAutor rekire

_{Dies wurde Hinzugefügt als edit von dem ursprünglichen Fragesteller, ich baute es zu einem community-wiki zu beantworten, denn es sollte eine Antwort sein, nicht Bearbeiten.}

Fand ich heraus, wie es zu tun... eine Art und Weise sowieso.

echo Startup > results.txt
@echo off
call :filelog >> results.txt 2>&1
notepad results.txt
exit /b

:filelog

call :delete new.txt
call :delete newer.txt
call :delete newest.txt
call :remove c:\NoSuchDirectory

GOTO :EOF

:delete
echo deleting %1
dir c:\users\newuser\Desktop\%1  >NUL 2>&1
SET existed=%ERRORLEVEL%
del /f /q c:\Users\newuser\Desktop\%1 
dir c:\users\newuser\Desktop\%1 2>NUL >NUL
if %existed% == 0 (if %ERRORLEVEL% == 1  echo "successful" )

GOTO :EOF

:remove
echo deleting directory %1
rmdir /q /s %1

GOTO :EOF

InformationsquelleAutor

IF ERRORLEVEL 0 [cmd] wird ausgeführt, jedes mal, weil WENN ERRORLEVEL # prüft, ob der Wert von ERRORLEVEL größer als oder gleich #. Deshalb, jeder Fehler-code wird die Ausführung von [cmd].

Eine gute Referenz für diese ist: http://www.robvanderwoude.com/errorlevel.php

>IF /?
Performs conditional processing in batch programs.

IF [NOT] ERRORLEVEL number command
IF [NOT] string1==string2 command
IF [NOT] EXIST filename command

  NOT               Specifies that Windows should carry out
                    the command only if the condition is false.

  ERRORLEVEL number Specifies a true condition if the last program run
                    returned an exit code equal to or greater than the number
                    specified.

Ich würde empfehlen, ändern Sie Ihren code so etwas wie die folgenden:

:delete
echo deleting %1
del /f /q c:\Users\newuser\Desktop\%1 
if errorlevel 1 (
    rem This block executes if ERRORLEVEL is a non-zero
    echo failed
) else (
    echo succesful
)

GOTO :EOF

Wenn Sie etwas brauchen, dass Prozesse mehr als einen ERRORLEVEL, Sie könnte so etwas tun:

:delete
echo deleting %1
del /f /q c:\Users\newuser\Desktop\%1 
if errorlevel 3 echo Cannot find path& GOTO :delete_errorcheck_done
if errorlevel 2 echo Cannot find file& GOTO :delete_errorcheck_done
if errorlevel 1 echo Unknown error& GOTO :delete_errorcheck_done
echo succesful
:delete_errorcheck_done

GOTO :EOF

ODER

:delete
echo deleting %1
del /f /q c:\Users\newuser\Desktop\%1 
goto :delete_error%ERRORLEVEL% || goto :delete_errorOTHER

:delete_errorOTHER
echo Unknown error: %ERRORLEVEL%
GOTO :delete_errorcheck_done
:delete_error3
echo Cannot find path
GOTO :delete_errorcheck_done
:delete_error2
echo Cannot find file
GOTO :delete_errorcheck_done
:delete_error0
echo succesful
:delete_errorcheck_done

GOTO :EOF

InformationsquelleAutor Hossy

0

Die Antwort von aschipfl ist Super (danke, hat mir sehr geholfen!) mit dem code unter Voreinstellung ErrorLevel bekommen Sie eine schöne standard-Funktion:

Achten Sie auf %~1 statt %1 im del - Anweisung, oder Sie erhalten Fehler, wenn Sie eine zitiert mit dem Namen.
```
::######################################################################
::call :DELETE "file.txt"
::call :DELETE "file.txt" "error message"
:DELETE
  >nul ver && for /F "tokens=*" %%# in ('del /F /Q "%~1" 2^>^&1 1^> nul') do (2>nul set =) || (
    if NOT .%2==. echo %~2
  )
goto :EOF
```
BTW 1: Sie können eine nette Fehlermeldung als zweiten parameter

BTW 2: Mit :: statt REM für Kommentare macht den code auch leichter lesbar.

InformationsquelleAutor CONSULitAS

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.

Batch-Datei und DEL errorlevel 0 Problem

`del` und `ErrorLevel`?

Möglich Zu Arbeiten, Um

Erklärung von Code

Anwendungsbeispiel

Voreinstellung `ErrorLevel`

Alternative Methode Ohne `for /F`

del und ErrorLevel?