Batch-Skript auf server 2008 - Wenn Ping erfolgreich, dann

Das "problem" mit deinem code ist das management der errorlevel um festzustellen, ob die Maschine steht oder nicht online.

Die Fragen sind: wie funktioniert ping Verhalten?, Wann ist errorlevel gesetzt?

Wenn wir arbeiten mit ipv6, die Regeln sind

• errorlevel wird gesetzt, wenn keine Antwort für alle gesendeten Pakete (alle Pakete verloren)

• errorlevel ist nicht festgelegt, wenn es eine Antwort auf die gesendeten Pakete

ipv6 hat ein konsequentes Verhalten und überprüfung der errorlevel ist eine zuverlässige Möglichkeit zu wissen, wenn die Maschine online ist.

In ipv4 sind die Regeln anders

• errorlevel wird gesetzt, wenn dort ist keine Antwort auf mindestens eine der gesendeten Pakete

• errorlevel ist nicht festgelegt, wenn es eine Antwort für alle gesendeten Pakete (keine Päckchen verloren)

Aber das pingen von einem nicht verfügbaren Rechner im gleichen Subnetz nicht einstellen errorlevel, erhalten Sie eine "nicht erreichbar" - Antwort, mit n packets sent, n packed received, 0 packets lost alle Pakete erhalten eine Antwort aus der gleichen Maschine das versenden von Paketen.

Dieses Verhalten in ipv4, wenn die Maschine im gleichen Subnetz-lässt den errorlevel-check fail.

Wie das problem zu lösen in ipv4?

Den Ausgang des ping Befehl kann überprüft werden, ob der string TTL= ist in der Ausgabe vorhanden, der Zielrechner ist online.

ping -n 1 10.0.0.1 | find "TTL=" >nul 
if errorlevel 1 ( 
    echo offline 
) else (
    echo online
)

Für eine "Allgemeine" Lösung (übernommen aus einer früheren Antwort) verwendet werden kann (scheint eine Menge code, aber Sie sind fast alle Kommentare)

@echo off

    setlocal enableextensions disabledelayedexpansion

    if "%~1"=="" goto :eof

    call :isOnline "%~1"
    if not errorlevel 1 ( echo ONLINE ) else ( echo OFFLINE )

    endlocal
    exit /b

:isOnline address pingCount
    setlocal enableextensions disabledelayedexpansion

    :: send only one ping packed unless it is indicated to send more than one
    set /a "pingCount=0", "pingCount+=%~2" >nul 2>nul 
    if %pingCount% lss 1 set "pingCount=1"

    :: a temporary file is needed to capture ping output for later processing
    set "tempFile=%temp%\%~nx0.%random%.tmp"

    :: ping the indicated address getting command output and errorlevel
    ping -w 1000 -n %pingCount% "%~1" > "%tempFile%"  && set "pingError=" || set "pingError=1"

    ::
    :: When pinging, the behaviours of ipv4 and ipv6 are different
    ::
    :: we get errorlevel = 1 when
    ::    ipv4 - when at least one packet is lost. When sending more than one packet
    ::           the easiest way to check for reply is search the string "TTL=" in 
    ::           the output of the command.
    ::    ipv6 - when all packet are lost.
    ::
    :: we get errorlevel = 0 when
    ::    ipv4 - all packets are received. BUT pinging a inactive host on the same  
    ::           subnet result in no packet lost. It is necessary to check for "TTL=" 
    ::           string in the output of the ping command
    ::    ipv6 - at least one packet reaches the host
    ::
    :: We can try to determine if the input address (or host name) will result in 
    :: ipv4 or ipv6 pinging, but it is easier to check the result of the command
    ::
    ::                          +--------------+-------------+
    ::                          | TTL= present |    No TTL   | 
    ::  +-----------------------+--------------+-------------+
    ::  | ipv4    errorlevel 0  |      OK      |    ERROR    |
    ::  |         errorlevel 1  |      OK      |    ERROR    | 
    ::  +-----------------------+--------------+-------------+ 
    ::  | ipv6    errorlevel 0  |              |      OK     |
    ::  |         errorlevel 1  |              |    ERROR    |
    ::  +-----------------------+----------------------------+
    ::
    :: So, if TTL= is present in output, host is online. If TTL= is not present,  
    :: errorlevel is 0 and the address is ipv6 then host is online. In the rest 
    :: of the cases host is offline.
    ::
    :: To determine the ip version, a regular expresion to match a ipv6 address is 
    :: used with findstr. As it will be only tested in the case of no errorlevel, 
    :: the ip address will be present in ping command output.

    set "exitCode=1"
    >nul 2>nul (
        find "TTL=" "%tempFile%" && ( set "exitCode=0" ) || (
            if not defined pingError (
                findstr /r /c:" [a-f0-9:][a-f0-9]*:[a-f0-9:%%]*[a-f0-9]: " "%tempFile%" && set "exitCode=0"
            )
        )
        del /q "%tempFile%"
    )

    :: cleanup and return errorlevel: 0=online , 1=offline 
    endlocal & exit /b %exitCode%

Dank an Euch beide. Ich versuchte beides, aber am Ende das ist was für mich gearbeitet

set machine=userbox
ping -n 1 %machine% | find "TTL=" >nul
IF errorlevel 1 (
echo "Computer Not On" %date% %time% > c:\scripts\%machine%-computeroff.log
) ELSE (
robocopy source destination
shutdown.exe /s /m \\%machine% /c "Mandatory Shutdown in progress. You have 10 minutes" /t 600
echo "shutdown command given" %date% %time% > c:\scripts\shutdown-%machine%.log 

Cheers