berechnen Sie den Monat das Jahr und die Wochennummer in excel

In Excel 2007 habe ich ein Jahr Zahl und Nummer der Woche und ich will arbeiten, die Monat-Nummer.

Der Haken ist, dass in meinem Fall der Beginn jeder Woche ist ein Montag, also einige Wochen überschneiden sich durch die Jahre.

Beispiele:

Year: 2012
Week 1 started: Monday 2nd January
Sunday 1st January was in week 52 of 2011

Angesichts der unten:

Year: 2011
Week: 10

Wie kann ich trainieren, dass Woche 10 startete am 7. März und somit in der Woche 10 war im Monat Anzahl 3.

Vielen Dank für jede Hilfe auf diesem.

InformationsquelleAutor Pricey | 2012-06-01
  1. 4

    Empfehle ich die folgende Vorgehensweise

    • Bestimmung der (ISO) Woche des 1. Januar (siehe auf dieser Seite) [in Zelle C4]

      =INT((B4-DATE(YEAR(B4-WEEKDAY(B4-1)+4),1,3)+WEEKDAY(DATE(YEAR(B4-WEEKDAY(B4-1)+4),1,3))+5)/7) (vorausgesetzt, B4 =DATE([Year],1,1))

    • Berechnung der Tag, an dem Woche 1 startet [in Zelle D4]

      =IF(C4=1,B4-WEEKDAY(B4,3),B4+7-WEEKDAY(B4,3))

    • Bestimmen, der Montag in der Woche in Frage, und der entsprechende Monat

      =MONTH(D4+7*([Week]-1))

    • Super Antwort, danke, nahm sich ein Stück zu erarbeiten, die D4 war die Woche 1 des Jahres bei der Ausarbeitung der Monat der Berechnung. Macht den job für mich, ich habe bemerkt, dass es ein problem mit den Schaltjahren wie 2012, Woche 18 beginnt April 30th, aber die obigen Formeln gibt Woche 5 sein, wenn es in Woche 4. Fortunely ich nicht zu genau mit diesem, also nochmals vielen Dank.
    • Interessant, es scheint zu funktionieren für mich. Für das Jahr 2012, Woche 18 C4 ergibt 52 (1. Januar Woche 52, 2011). D4 ist Montag, der 2. Jan 2012 und (D4+7*(18-1) sollte zum 30 April. Vielleicht habe ich einen Fehler gemacht, da ein übersetzen musste die Formeln. Ich werde den Beitrag aktualisieren, wenn Sie lassen Sie mich wissen, wo der Fehler liegt.
    • Ah ich weiß was mein problem ist. Es ist ein Verweis auf die Zelle B1 in der Formel, die funktioniert aus Woche 1. Ich habe keinen Wert für die jeweilige Zelle, ich nehme an, seine B4 also habe ich es angepasst und es funktioniert jetzt.
    • Vielen Dank, es behoben! Stellte sich heraus, es war ein weiterer Fehler in der Formel (+WOCHENTAG statt -an WOCHENTAGEN).
    • Guter Punkt, ja, ich hatte nicht versucht, den Zustand.
    InformationsquelleAutor Paul B.
  2. 24

    Können Sie tatsächlich tun dies, ein wenig mehr einfach. Wenn Jahr ist in A2, z.B. 2012, und die Nummer der Woche ist in B2 Sie können das Startdatum der Woche mit dieser Formel

    =DATE(A2,1,-2)-WEEKDAY(DATE(A2,1,3))+B2*7

    formats wie der date -

    ......klar kann man wickeln, dass in einem MONAT-Funktion, um den Monat, d.h.

    =MONTH(DATE(A2,1,-2)-WEEKDAY(DATE(A2,1,3))+B2*7)

    format der Ergebnis-Zelle als Allgemeine

    Erklärung

    Oben findet das Datum der letzten Montag des Vorjahres und fügt dann die Anzahl der Wochen * 7 geben Sie das Startdatum der jeweiligen Woche.

    Den ersten Tag des Jahres für ISO Wochen immer nur montags in der Zeit 29. Dez bis 4. Jan, so finden Sie, dass das Datum finden wir den Montag unmittelbar vor dem 5. Jan.

    Zu finden, der Montag unmittelbar vor jedem Datum, das Sie verwenden können, diese Allgemeine Formel

    =date-WEEKDAY(date-2)

    also, wenn Datum 5. Jan des Jahres gezeigt, in A2 das ist das gleiche wie

    =DATE(A2,1,5)-WEEKDAY(DATE(A2,1,3))

    .....aber der erste Montag in diesem Jahr, wenn ich also möchte, dem letzten Montag im vorigen Jahr kann ich subtrahieren 7 - eine Möglichkeit, dies zu erreichen, subtrahieren Sie 7 von der 5 bis -2 somit:

    =DATE(A2,1,-2)-WEEKDAY(DATE(A2,1,3))

    • Danke, dieses Zeug verwirrt mich, was ist eigentlich Los, -2 aus den ersten Monat des Jahres dann abzüglich der Wochentag num zum 3. Tag des Januar für das Jahr... dann fügen Sie die Wochen * Tage in der Woche. Deine Antwort sieht gut aus und viel sauberer +1. Dank
    • Vielen Dank - habe ich eine Erklärung......
    • Dauert einige Ihren Kopf Runde der Logik, sondern eine saubere und einfache Formel, die Super Antwort
    InformationsquelleAutor barry houdini
  3. 0

    Die ISO-Woche immer enthalten, 4. Januar, also seinen Wochentag, beginnend mit Montag (offensichtlich ein "Jahr" ist die Zelle mit dem Jahr):

    WEEKDAY(DATE(year;1;4))

    Dies ist die Anzahl der Tage, die wir brauchen, um zurück zu gehen, die ab diesem Datum zu finden, ein Montag (plus eins)

    DATE(year;1;4)-WEEKDAY(DATE(year;1;4))+1

    So, jetzt brauchen wir nur zu zählen...

    DATE(year;1;4)-WEEKDAY(DATE(year;1;4))+1+weeknumber*7
    InformationsquelleAutor Envite
Schreibe einen Kommentar