Beschaffung von browser und version Coldfusion verwenden

Gibt es etwas, das gebaut in Coldfusion, würde lassen Sie mich wissen, den browser und die Versionsnummer, surfen meine Website? Sind die dort vorhandenen Bibliotheken, die es mir ermöglichen, dies zu tun?

Mein google-fu hat sich nicht gezeigt, viele andere Dinge als einfache if-Anweisungen erkennen, DH.

Habe ich eine Sicherung von der cgi.http_user_agent-variable in Chrome:

Mozilla/5.0 (Windows NT 5.1) AppleWebKit/534.24 (KHTML, like Gecko) Chrome/11.0.696.77 Safari/534.24

Gibt es drei verschiedene Browser wissen! Mache eine if-Anweisung suchen entweder würde true zurückgeben. Es hat zu einer mehr formalen Ansatz?

Du sollst dich nicht browser-sniffing.
Vereinbart. Ich versuche einfach, zu replizieren, eine JS-Komponente, die in Coldfusion. Browser-sniffing ist nur ein winziger Teil von dem, was es tut.
Ist das nicht eigentlich sagen, drei Browsern. Der AppleWebKit Teil sagt nur, dass Sie verwenden einen browser gebaut, der auf der rendering-engine WebKit (Safari Teil ist zu sagen, die gleiche Sache). Ich habe noch nie sicher gewesen, was das Mozilla Teil ist, aber der einzige Teil, sagen Sie einen browser ist Chrome und die version ist es. Bei der überprüfung für Chrome können Sie nur wollen, um zu überprüfen, für AppleWebKit da die meisten webkit-Browser unterstützen die gleichen Sachen.

InformationsquelleAutor TekiusFanatikus | 2011-06-09

coldfusion user-agent

Es ist eine benutzerdefinierte Funktion, die analysiert die Benutzeragent-Zeichenfolge.

browserDetect

<cfscript>
/**
 * Detects 130+ browsers.
 * v2 by Daniel Harvey, adds Flock/Chrome and Safari fix.
 * 
 * @param UserAgent      User agent string to parse. Defaults to cgi.http_user_agent. (Optional)
 * @return Returns a string. 
 * @author John Bartlett ([email protected]) 
 * @version 4, June 28, 2009 
 */
function browserDetect() {

//Default User Agent to the CGI browser string
var UserAgent=CGI.HTTP_USER_AGENT;

//Regex to parse out version numbers
var VerNo="/?v?_? ?v?[\(?]?([A-Z0-9]*\.){0,9}[A-Z0-9\-.]*(?=[^A-Z0-9])";

//List of browser names
var BrowserList="";

//Identified browser info
var BrowserName="";
var BrowserVer="";

//Working variables
var Browser="";
var tmp="";
var tmp2="";
var x=0;


//If a value was passed to the function, use it as the User Agent
if (ArrayLen(Arguments) EQ 1) UserAgent=Arguments[1];

//Allow regex to match on EOL and instring
UserAgent=UserAgent & " ";

//Browser List (Allows regex - see BlackBerry for example)
BrowserList="1X|Amaya|Ubuntu APT-HTTP|AmigaVoyager|Android|Arachne|Amiga-AWeb|Arora|Bison|Bluefish|Browsex|Camino|Check&Get|Chimera|Chrome|Contiki|cURL|Democracy|" &
            "Dillo|DocZilla|edbrowse|ELinks|Emacs-W3|Epiphany|Galeon|Minefield|Firebird|Phoenix|Flock|IceApe|IceWeasel|IceCat|Gnuzilla|" &
            "Google|Google-Sitemaps|HTTPClient|HP Web PrintSmart|IBrowse|iCab|ICE Browser|Kazehakase|KKman|K-Meleon|Konqueror|Links|Lobo|Lynx|Mosaic|SeaMonkey|" &
            "muCommander|NetPositive|Navigator|NetSurf|OmniWeb|Acorn Browse|Oregano|Prism|retawq|Shiira Safari|Shiretoko|Sleipnir|Songbird|Strata|Sylera|" &
            "ThunderBrowse|W3CLineMode|WebCapture|WebTV|w3m|Wget|Xenu_Link_Sleuth|Oregano|xChaos_Arachne|WDG_Validator|W3C_Validator|" &
            "Jigsaw|PLAYSTATION 3|PlayStation Portable|IPD|" &
            "AvantGo|DoCoMo|UP.Browser|Vodafone|J-PHONE|PDXGW|ASTEL|EudoraWeb|Minimo|PLink|NetFront|Xiino|";
            //Mobile strings
            BrowserList=BrowserList & "iPhone|Vodafone|J-PHONE|DDIPocket|EudoraWeb|Minimo|PLink|Plucker|NetFront|PIE|Xiino|" &
            "Opera Mini|IEMobile|portalmmm|OpVer|MobileExplorer|Blazer|MobileExplorer|Opera Mobi|BlackBerry\d*[A-Za-z]?|" &
            "PPC|PalmOS|Smartphone|Netscape|Opera|Safari|Firefox|MSIE|HP iPAQ|LGE|MOT-[A-Z0-9\-]*|Nokia|";

            //No browser version given
            BrowserList=BrowserList & "AlphaServer|Charon|Fetch|Hv3|IIgs|Mothra|Netmath|OffByOne|pango-text|Avant Browser|midori|Smart Bro|Swiftfox";

            //Identify browser and version
Browser=REMatchNoCase("(#BrowserList#)/?#VerNo#",UserAgent);

if (ArrayLen(Browser) GT 0) {

    if (ArrayLen(Browser) GT 1) {

        //If multiple browsers detected, delete the common "spoofed" browsers
        if (Browser[1] EQ "MSIE 6.0" AND Browser[2] EQ "MSIE 7.0") ArrayDeleteAt(Browser,1);
        if (Browser[1] EQ "MSIE 7.0" AND Browser[2] EQ "MSIE 6.0") ArrayDeleteAt(Browser,2);
        tmp2=Browser[ArrayLen(Browser)];

        for (x=ArrayLen(Browser); x GTE 1; x=x-1) {
            tmp=Rematchnocase("[A-Za-z0-9.]*",Browser[x]);
            if (ListFindNoCase("Navigator,Netscape,Opera,Safari,Firefox,MSIE,PalmOS,PPC",tmp[1]) GT 0) ArrayDeleteAt(Browser,x);
        }

        if (ArrayLen(Browser) EQ 0) Browser[1]=tmp2;
    }

    //Seperate out browser name and version number
    tmp=Rematchnocase("[A-Za-z0-9. _\-&]*",Browser[1]);

    Browser=tmp[1];

    if (ArrayLen(tmp) EQ 2) BrowserVer=tmp[2];

    //Handle "Version" in browser string
    tmp=REMatchNoCase("Version/?#VerNo#",UserAgent);

    if (ArrayLen(tmp) EQ 1) {
        tmp=Rematchnocase("[A-Za-z0-9.]*",tmp[1]);
        BrowserVer=tmp[2];
    }

    //Handle multiple BlackBerry browser strings
    if (Left(Browser,10) EQ "BlackBerry") Browser="BlackBerry";

    //Return result
    return Browser & " " & BrowserVer;

}

//Unable to identify browser
return "Unknown";

}
</cfscript>

Es wird, natürlich, beginnen zu Versagen ist, wenn neue Saiten werden nicht Hinzugefügt, wie neue Browser kommen.
Ich gab +1 auf, so wie es das macht, was der OP will, aber es ist nichts, was ich verlassen würde, die, allgemein gesprochen.
Ich habe gerade versucht das über 7 Jahre alte UDF und kehrte er "Chrome 42" für einen Edge-useragent. Gibt es da schon updates seit 2011? Als Folge wechselte ich zu BrowscapCFC & Cache-lookup-Ergebnisse (für die Leistung) als die BrowsCap.org website hält die Datenbank aktualisiert und bietet mehr Informationen (Plattform, crawler, Tisch, Handy, etc.)

InformationsquelleAutor ale

5

Konnte Sie nicht verwenden javascript statt? http://cssuseragent.org/

CSSUA ist genial, fügt der einfachen Klassen zu den tag-und können Sie gezielt Inhalte in CSS - /Javascript-Klassen, wie ua-ie-6 etc.

Danke für den Tipp!
Dies ist die beste Lösung, die ich kam, um

InformationsquelleAutor Jon Joyce
5

Dies ist viel einfacher als die komplizierte Funktion früher gestellt...
```
<CFIF FindNoCase('Chrome','#CGI.HTTP_USER_AGENT#') GREATER THAN 0>
  <CFSET browser = 'Chrome'>
</CFIF>
```
credit: http://www.paulsilver.co.uk/code/coldfusion_detect_browser.php

Das war gut genug für das, was ich zu wissen brauchte.

InformationsquelleAutor Klog
2

Ich erstellt BrowscapCFC powered by http://browscap.org/. Es kann Ihre Bedürfnisse anzupassen

InformationsquelleAutor Henry
1

Es ist nichts gebaut, in ColdFusion, die Ihnen erlauben, dies zu tun. Die Erfassung der user_agent string und analysieren Sie manuell ist über die beste Sie tun können.

Dort sind Drittanbieter-apps wie Browserhawk (http://www.cyscape.com/Default.aspx) , wird dies tun... und zwar habe ich nicht verwendet Browserhawk mich, ich verstehe, dass es macht den job gut.

Googeln dreht auch bis http://www.andrewdixon.co.uk/aebrowser/, aber das ist 6 Jahre alt. Vielleicht noch arbeiten... aber je nachdem, wie kugelsichere Sie benötigen die Lösung zu sein, möchten Sie vielleicht zu prüfen, so etwas wie Browserhawk. Man könnte google für eine Liste von Zeichenfolgen des Benutzer-Agenten und handle es sich... aber angesichts der schieren Anzahl von Browsern (und Versionen) über OS, ich denke, das wäre ein full-time-job an und für sich.

InformationsquelleAutor charliegriefer
0

Die Benutzer-definierte Funktion oben funktioniert großartig, aber ich musste mich fügen Sie den folgenden code, um die version-Nummer, um korrekt zu arbeiten mit dem IE (MSIE):
```
//Handle MSIE Version issue
IF (Left(Browser,4) EQ "MSIE") {
        tmpBrowser = Browser;
    IF (listLen("#tmpBrowser#", " ") EQ 2) {
        Browser = listGetAt("#tmpBrowser#", 1, " ");
        BrowserVer = listGetAt("#tmpBrowser#", 2, " ");
    }
}
```
Mit einem user_agent wie diese:

Mozilla/4.0 (compatible; MSIE 8.0; Windows NT 6.1; Trident/4.0; SLCC2; .NET CLR 2.0.50727; .NET CLR 3.5.30729; .NET CLR 3.0.30729; Media Center PC 6.0; .NET4.0C)

Es wurde wieder eine leere version und einen browser namens "MSIE 8.0"

IE11 macht das ganze noch interessanter. Anscheinend ist es nicht mehr Berichte MSIE.

InformationsquelleAutor Steve Grundy

Hier ist eine neuere build des Browsers, name und version
Getestet auf Opra /IE 8 /IE 9 /IE 10 /IE 11 /Edge /Chrome /Firefox

<cffunction name="GetBrowser" access="public">
    <cfset var l = {}>
    <cfset l.UserInfo = cgi.HTTP_USER_AGENT>
    <cfset l.Browser = {}>

    <cfif FindNoCase ( "Opera", l.UserInfo ) >
        <cfset l.Browser.type = "Opera">
        <cfset l.Browser.Name = "Opera">
    <cfelseif FindNoCase ( "OPR", l.UserInfo )>
        <cfset l.Browser.type = "OPR">
        <cfset l.Browser.Name = "Opera">
    <cfelseif FindNoCase ( "Edge", l.UserInfo )>
        <cfset l.Browser.type = "Edge">
        <cfset l.Browser.Name = "Edge">
    <cfelseif FindNoCase ( "Chrome", l.UserInfo )>
        <cfset l.Browser.type = "Chrome">
        <cfset l.Browser.Name = "Chrome">
    <cfelseif FindNoCase ( "Safari", l.UserInfo )>
        <cfset l.Browser.type = "Safari">
        <cfset l.Browser.Name = "Safari">
    <cfelseif FindNoCase ( "FireFox", l.UserInfo )>
        <cfset l.Browser.type = "FireFox">
        <cfset l.Browser.Name = "FireFox">
    <cfelseif FindNoCase ( "MSIE", l.UserInfo ) >
        <cfset l.Browser.type = "MSIE">
        <cfset l.Browser.Name = "Internet Explorer">
    <cfelseif FindNoCase ( "Trident", l.UserInfo ) >
        <cfset l.Browser.type = "Trident">
        <cfset l.Browser.Name = "Internet Explorer">
    <cfelse>
        <cfset l.Browser.type = "Unknown">
        <cfset l.Browser.Name = "Unknown">
        <cfset l.Browser.Version = "Unknown">
    </cfif>

    <cfif FindNoCase ( "rv:" , l.UserInfo ) NEQ 0>
        <cfset l.Params = REFindNoCase ( "rv:[0-9.]+", l.UserInfo, Find ( "rv:", l.UserInfo ), true )>
        <cfset l.FirstOccurrence = l.Params.POS[1]>
        <cfset l.ParamLength = l.Params.LEN[1]>
        <cfset l.BrowserNameLength = Len ( "rv:" )>
        <cfset l.Browser.Version = Mid ( l.UserInfo, ( l.FirstOccurrence + l.BrowserNameLength ), ( l.ParamLength - l.BrowserNameLength ) )>
     <cfelse>
        <cfset l.Params = REFindNoCase ( #l.Browser.type# & "/?[ 0-9.]+", l.UserInfo, Find ( "#l.Browser.type#", l.UserInfo ), true )>
        <cfset l.FirstOccurrence = l.Params.POS[1]>
        <cfset l.ParamLength = l.Params.LEN[1]>
        <cfset l.BrowserNameLength = Len ( l.Browser.type ) + 1>
        <cfset l.Browser.Version = Mid ( l.UserInfo, ( l.FirstOccurrence + l.BrowserNameLength ), ( l.ParamLength - l.BrowserNameLength ) )>
     </cfif>

     <cfreturn l.Browser>
</cffunction>

<cfdump var="#GetBrowser()#">

InformationsquelleAutor SeriesBlue

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.