Brauche VBA-makro zum ausblenden von Zeilen basierend auf dem text, Zelle Werte in 2 verschiedenen Spalten

Unten ist der code, den ich verwenden zum ausblenden aller Zeilen mit dem Wert "Küche: in Spalte 8. Ich muss auch zum ausblenden der Zeile, wenn die Spalte 12 enthält "Keine". Dies ist eine Anweisung "Oder", nicht ein "Und" - Anweisung.
Ich habe recherchiert im forum, aber nicht in der Lage, die Antwort zu finden. Ich möchte auch, um den Prozess zu beschleunigen. Jede Hilfe würde geschätzt werden. 

Sub FOHc()

    BeginRow = 6
    EndRow = 400
    ChkCol = 8


    For RowCnt = BeginRow To EndRow
           If Cells(RowCnt, ChkCol).Value = "Kitchen" Or Cells(RowCnt, ChkCol).Value = Blank Then
           Cells(RowCnt, ChkCol).EntireRow.Hidden = True

            Else
            Cells(RowCnt, ChkCol).EntireRow.Hidden = False

        End If
    Next RowCnt

End Sub

Brauche VBA-makro zum ausblenden von Zeilen basierend auf dem text, Zelle Werte in 2 verschiedenen Spalten

InformationsquelleAutor Kyle M | 2016-01-28
  1. 0

    Können Sie einfach fügen Sie eine weitere Or Zustand

    If Cells(RowCnt, ChkCol).Value = "Kitchen" Or Cells(RowCnt, ChkCol).Value = Blank Or Cells(RowCnt, ChkCol2).Value = "No" Then

    Bei der Beschleunigung des Makros, add Application.ScreenUpdating = False am Anfang und Application.ScreenUpdating = True am Ende. Dies wird verhindern, aktualisieren Sie Ihren Bildschirm, während Sie makro.

    InformationsquelleAutor Egan Wolf
  2. 0

    Hinzufügen einer anderen Logik zu testen, fügen Sie einfach eine weitere Or - Anweisung.

    Zu beschleunigen, sammeln Sie alle Zeilen ausblenden, in einer Reihe, und verstecken Sie in einem Rutsch.

    Auch im Allgemeinen ist es eine gute Idee, um die ordnungsgemäße Verwendung von Qualifiern, die Aussage Cells bezieht sich auf das, was Excel betrachtet werden, das aktive Blatt ist. während ThisWorkbook.Worksheets("Sheet1").Cells bezieht sich immer auf das Blatt "Tabelle1".

    Deklarieren alle Variablen, die möglicherweise verhindern, dass unerwünschte Verhalten und Fehler und in der Regel gute Praxis.

    Hier ist der überarbeitete code.

    Sub FOHc()
    Dim beginRow As Long
    Dim endRow As Long
    Dim chkCol As Long
    Dim rowCnt As Long
    Dim rngResult As Range
    Dim ws As Worksheet

    beginRow = 6
    endRow = 400
    chkCol = 8

    Set ws = ThisWorkbook.Worksheets("Sheet1") 'Change this to the actual name of your sheet.

    With ws
        .Cells.EntireRow.Hidden = False 'Unhides all rows, remove line if that's not desired
        For rowCnt = beginRow To endRow
            If .Cells(rowCnt, chkCol) = "Kitchen" Or .Cells(rowCnt, chkCol) = Empty Or .Cells(rowCnt, 12) = "No" Then
                If rngResult Is Nothing Then
                    Set rngResult = .Cells(rowCnt, 1)
                Else
                    Set rngResult = Union(rngResult, .Cells(rowCnt, 1))
                End If
            End If
        Next rowCnt
    End With

    If Not rngResult Is Nothing Then rngResult.EntireRow.Hidden = True

End Sub
    InformationsquelleAutor SilentRevolution
Schreibe einen Kommentar