CMD verschachtelten Anführungszeichen im argument

Wie dbenham sagte, es scheint unmöglich zu entkommen, ein Raum in einem parameter ohne Anführungszeichen ein.

Aber es könnte möglich sein, wenn Sie wissen, wie die Empfänger - Funktion erhält den Parameter.

Dann könnte man tranfer der parameter über ein entflohener verzögerte variable, die variable erweitert werden, die nicht in den Ruf, es wird erweitert, nur in der Funktion.

Und es ist notwendig, dass die Parameter, die zugewiesen werden in der Funktion zur Variablen, aber dies könnte der Fall sein in einem guten und lesbaren code.

setlocal EnableDelayedExpansion 
set path_with_space="c:\test\filenamewith space.txt"
@CALL :FUNCTION blaat1, "blaat2 ^!path_with_space^!"
GOTO :EOF

:FUNCTION
@echo off
echo arg 1: %~1
echo arg 2: %~2
echo arg 3: %~3
GOTO :EOF 

Ausgabe:

arg 1: blaat1
arg 2: blaat2 "c:\test\filenamewith space.txt"
arg 3:

EDIT: Soltution mit batch-Injektion

Dies funktioniert auch, wenn die verzögerte Erweiterung sollte immer deaktiviert.

Aber dann müssen Sie jetzt, wie die Parameter erweitert werden, die in der Funktion.

@echo off
set path_with_space="c:\test\filenamewith space.txt"
CALL :FUNCTION 1 2 ""^^"&call:inject:""
exit/b

:inject
set arg1=blaat1
set arg2=blaat2 %path_with_space%
set arg3=none
exit /b

:FUNCTION
@echo off
set "arg1=%~1"
set "arg2=%~2"
set "arg3=%~3"
echo arg 1: %arg1%
echo arg 2: %arg2%
echo arg 3: %arg3%
GOTO :EOF

Ich glaube, es ist nicht möglich.

Ist es nicht möglich zu entkommen, ein Raum, so dass es ist nicht so auszulegen, als parameter-Trennzeichen. Der einzige Weg, um ein Leerzeichen in einem parameter ist, müssen Sie ihn in Anführungszeichen. Sie benötigen etwas Platz, um zitiert werden, und einige nicht, so ist es unmöglich.

WENN SIE NICHT MÖCHTEN, ZU VERWENDEN, VERZÖGERTE EXPANSION (Sie brauchen, um die edit FUNKTION zu acomplish diese!):

Ich schlage vor, Sie entfernen Sie Anführungszeichen vor der übergabe der Argumente an FUNKTION (Hinweis: %path_with_space:"=%" vs %path_with_space%" im ursprünglichen Beispiel), dann können Sie setzen Sie Sie wieder ein, ersetzen Sie Ihren Weg mit zitiert verion (%%_arg_2:%path_with_space:"=%=%path_with_space%%%):

@SET path_with_space="c:\test\filenamewith space.txt"
@CALL :FUNCTION blaat1, "blaat2 %path_with_space:"=%"
@GOTO :EOF

:FUNCTION
@echo off
echo arg 1: %~1
set _arg_2=%~2
call echo arg 2: %%_arg_2:%path_with_space:"=%=%path_with_space%%%
echo arg 3: %~3
GOTO :EOF

Ausgabe:

arg 1: blaat1
arg 2: blaat2 "c:\test\filenamewith space.txt"
arg 3:

Wenn auch andere Argumente enthalten Pfade, die von Anführungszeichen eingeschlossen sind, können Sie dem gleichen Muster Folgen für alle von Ihnen