Custom legend (oder text) gnuplot

Ich habe eine Datei mit 3 Spalten, die ersten 2 sind die position x y und die 3. eine die ich es für benutze definieren Sie die Farbe, also ich habe so etwas wie dieses:

set palette model RGB defined ( 1 'black', 2 'blue', 3 'green', 4 'red')
unset colorbox

plot "file" u 2:1:3 w points pt 14 ps 2 palette, "file2" u 2:1:3 w points pt 14 ps 2        palette

Nun die Frage: Ist es möglich, eine richtige Legende mit dieser Art von Punkt und FARBE?.
Da die Punkte haben unterschiedliche Farben (nach der pallete) ich will angeben, was bedeutet, dass jede Farbe in der Legende.

Die einzige Lösung, die ich dachte zu schreiben, das irgendwo in der plot-text mit dem Zeichen, der Punkt (in diesem Fall pt 14) und geben Sie die Farbe... aber ist nicht wirklich eine Lösung, rechts?

Also bitte Hilfe!!!

  • In der Regel die colorbox, die du aufhebst, ist dafür gedacht.
  • was meinst du? Ich bin kein Experte auf allen =)
  • Entfernen Sie die unset colorbox Teil aus dem Skript, und Sie haben eine Vereins-Wert <-> - Farbe. Oder haben Sie nur ein paar Farbwerte und jede Farbe hat eine bestimmte Bedeutung?
  • ja ich habe nur 4 Werte und für jede, eine Farbe. Andere Farbe bedeutet, verschiedene Dinge, und ich will haben, dass in der Legende. Aber wenn ich "add title ""etwas" wird es das richtige symbol, aber nicht die Farbe.
InformationsquelleAutor Nikko | 2013-11-27
  1. 6

    Es gibt keine option für diese, Sie müssen mal ein wenig. Hier ist YAGH (Noch ein gnuplot-hack) 😉

    Unter der Annahme, dass deine Werte sind äquidistant verteilt sind, können Sie die '+' speziellen Dateinamen mit der labels Plotten Stil.

    Zeigen nur die benutzerdefinierte Taste verwendet wird, betrachten wir das folgende Beispiel:

    labels="first second third fourth"
set xrange[0:1] # must be set for '+'
set yrange[0:1]
set samples words(labels)   # number of colors to use
key_x = 0.8     # x-value of the points, must be given in units of the x-axis
key_y = 0.8
key_dy = 0.05
set palette model RGB defined ( 1 'black', 2 'blue', 3 'green', 4 'red')
unset colorbox
plot '+' using (key_x):(key_y + $0*key_dy):(word(labels, int($0+1))):0 \
    with labels left offset 1,-0.1 point pt 7 palette t ''

    Diese gibt (mit 4.6.4):

    Custom legend (oder text) gnuplot

    Als set samples nicht auf die Daten der Grundstücke, integrieren Sie diese direkt in Ihre plot-Befehl:

    ...
unset key
plot "file" u 2:1:3 w points pt 14 ps 2 palette, \
     "file2" u 2:1:3 w points pt 14 ps 2 palette, \
     '+' using (key_x):(key_y - $0*key_dy):(word(labels, int($0+1))):0 \
         with labels left offset 1,-0.1 point pt 14 ps 2 palette

    Aber Sie brauchen, um eine korrekte xrange, yrange und die Werte der key_x, key_y und key_dy.

    Dies ist nicht die intuitivste Art, aber es funktioniert 🙂

    • Danke, sehr nützlich. Ich stellte es ein wenig dynamischer in Bezug auf die Skalierung der Achse: key_x = x_range - x_range / 10.0 etc...
    InformationsquelleAutor Christoph
  2. 1

    Habe ich eine alternative Lösung hier gepostet:
    Mit Gnuplot zu Plotten Farben bedingt

    Im wesentlichen zeichnen Sie einmal ohne eine Legende Eintrag, dann machen dummy-Grundstücke (ohne Daten) für jeden Punkt Farbe/label.

    • Ja, kombiniert mit Iterationen und lc palette frac es sollte funktionieren: labels="A B C D"; plot 'file' u 2:1:3 w p pt 14 ps 2 palette, for [i=1:4] '' u (NaN):(NaN) w p pt 14 ps 2 lc palette frac (i/3.0) title word(i).
    InformationsquelleAutor andyras
Schreibe einen Kommentar