Delphi: öffnen Sie ein zip-Archiv aus einem stream -> extrahieren einer stream -

Zip-Datei der Komponente, die in XE2 dies tun wird.

Es eine überladene Open Methode, erhält eine TStream als input-Parameter.

Zu extrahieren einzelner Dateien Sie können den Aufruf einer überladenen Read - Methode und übergeben Sie den Namen der Datei, die Sie extrahieren möchten. Die extrahierte Datei zurückgegeben wird, wie eine neue Instanz von TStream. Sie können, verwenden Sie CopyFrom auf diese Instanz zu übertragen, die extrahierte Datei in Ihrem stream.

var
  ZipFile: TZipFile;
  DownloadedStream, DecompressionStream, MyStream: TStream;
  LocalHeader: TZipHeader;
...
ZipFile := TZipFile.Create;
try
  ZipFile.Open(DownloadedStream, zmRead);
  ZipFile.Read('myzippedfile', DecompressionStream, LocalHeader);
  try
    MyStream.CopyFrom(DecompressionStream, DecompressionStream.Size);
  finally
    DecompressionStream.Free;
  end;
finally
  ZipFile.Free;
end;

Beachten Sie, dass habe ich nicht getestet, diese code habe ich nur geschrieben, es basiert auf der source code für TZipFile und der Dokumentation enthaltenen Quell-code. Gibt es vielleicht ein paar Falten, aber wenn der code sich so verhält, wie beworben, es erfüllt Ihre Anforderungen perfekt.

OK, jetzt habe ich es getestet, weil ich neugierig war. Hier ist das Programm, das zeigt, dass es funktioniert, wie beworben:

program ZipTest;

{$APPTYPE CONSOLE}

uses
  System.SysUtils,
  System.Classes,
  System.Zip;

procedure ExtractToFile(
  const ZipFileName: string;
  const ZippedFileIndex: Integer;
  const ExtractedFileName: string
);
var
  ZipFile: TZipFile;
  DownloadedStream, DecompressionStream, OutputStream: TStream;
  LocalHeader: TZipHeader;
begin
  DownloadedStream := TFileStream.Create(ZipFileName, fmOpenRead);
  try
    ZipFile := TZipFile.Create;
    try
      ZipFile.Open(DownloadedStream, zmRead);
      ZipFile.Read(ZippedFileIndex, DecompressionStream, LocalHeader);
      try
        OutputStream := TFileStream.Create(ExtractedFileName, fmCreate);
        try
          OutputStream.CopyFrom(DecompressionStream, DecompressionStream.Size);
        finally
          OutputStream.Free;
        end;
      finally
        DecompressionStream.Free;
      end;
    finally
      ZipFile.Free;
    end;
  finally
    DownloadedStream.Free;
  end;
end;

begin
  try
    ExtractToFile('C:\desktop\test.zip', 0, 'C:\desktop\out.txt');
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.

Beachten Sie, dass ich extrahiert, die durch den index eher als Dateiname da, das war bequemer für mich. Und ich verwendete Datei-streams eher als Speicher-streams, die ich mir vorstellen das Sie verwenden würde. Da jedoch die TZipFile Methoden der Arbeit mit TStream ich bin mir sicher, dass der code funktioniert mit streams jeglicher form.

Dies ist die neueste in einer Reihe von Fragen über ZIP-Dateien. Ich weiß, dass Sie mit XE2 und ich Frage mich, warum Sie scheinen nur ungern mit dem eingebauten ZIP-Klasse, die XE2 stellt. Ich habe nicht gesehen, nichts, um anzuzeigen, dass es nicht Ihre Anforderungen erfüllen. In der Tat ist es genau diese Fähigkeit, arbeiten direkt mit den streams, die macht mir das Gefühl, es hat genügend Allgemeingültigkeit für jede Anwendung.