Die Berechtigung Höhe von VBScript

Wir führen Dynamics GP. Aufgrund der Art, es speichert Formulare/Berichte, die ich brauchen, um einige install-scripts, die Kopie ein .LEGEN Sie die Datei in das Programm-Verzeichnis. Dies kann manuell geschehen, aber es ist viel schneller, um nur einen Benutzer führen Sie ein installer-Skript installiert die richtigen Dateien für Sie.

Habe ich mit dem Bau eines VBScript-Installationsprogramm kopiert die erforderlichen Dateien um. Der schwierige Teil ist, dass einige clients mit Windows XP, und einige sind mit Windows 7 (oder sogar 8). UAC ist aktiviert, so dass die Berechtigungen ins Spiel kommen.

Dem Weg dorthin habe ich versucht, es zu tun ist, indem Sie blind versuchen, die Dateien zu kopieren, und wenn eine Erlaubnis Fehler erkannt wird, wird es relauncht das script mit administrator-Berechtigungen. Wo haben wir Probleme in der einige (alle?) Windows 7-Maschinen virtualisiert Datei/registry schreibt, aktiviert, so dass, wenn das Skript versucht, das kopieren von Dateien in C:\Program Files\Microsoft Dynamics\GP2010, es im hintergrund fehl, und kopiert Sie auf den Benutzer AppData\Local\VirtualStore-Verzeichnis. Dies funktioniert nicht mit GP.

Also, was ich tun müssen, haben das Skript kopieren Sie die Dateien auf C:\Program Dateien (nicht den VirtualStore-Verzeichnis), und Berechtigungen zu erhöhen, nur, wenn nötig. Wenn ich es heben auf der ganzen Linie, dadurch wird der Windows XP-Maschinen, die einfach nur pop-up mit einem kryptischen "Ausführen Als" - dialog-box, wenn das script zu starten.

Hier ist, was ich habe, so weit:

Dim WSHShell, FSO, Desktop, DesktopPath
Set FSO = CreateObject("Scripting.FileSystemObject")
Set WSHShell = CreateObject("WScript.Shell")
Desktop = WSHShell.SpecialFolders("Desktop")
DesktopPath = FSO.GetAbsolutePathName(Desktop)

'Set working directory to directory the script is in.
'This ends up being C:\Windows\System32 if the script is
'started from ShellExecute, or a link in an email, thus breaking
'relative paths.
WSHShell.CurrentDirectory = FSO.GetFile(WScript.ScriptFullName).ParentFolder

On Error Resume Next

If FSO.FolderExists("C:\Program Files (x86)") Then
    WScript.Echo "Installing 64-bit."
    FSO.CopyFile "64-bit\*.set", "C:\Program Files (x86)\Microsoft Dynamics\GP2010\", True
    FSO.CopyFile "64-bit\*.lnk", DesktopPath, True
ElseIf FSO.FolderExists("C:\Program Files\Microsoft Dynamics\GP2010\Mekorma MICR") Then
    WScript.Echo "Installing 32-bit (with MICR)."
    FSO.CopyFile "32-bit MICR\*.set", "C:\Program Files\Microsoft Dynamics\GP2010\", True
    FSO.CopyFile "32-bit MICR\*.lnk", DesktopPath, True 
Else
    WScript.Echo "Installing 32-bit."
    FSO.CopyFile "32-bit\*.SET", "C:\Program Files\Microsoft Dynamics\GP2010\", True
    FSO.CopyFile "32-bit\*.lnk", DesktopPath, True
End If

If Err.Number = 70 Then
    CreateObject("Shell.Application").ShellExecute "wscript.exe", """" & WScript.ScriptFullName & """" , "", "runas", 1
    WScript.Quit
ElseIf Err.Number <> 0 Then
    MsgBox "Error " & Err.Number & vbCrLf & Err.Source & vbCrLf & Err.Description
Else
    MsgBox "Installed successfully."
End If

Zusammenfassend: Wie kann ich ein VBScript, Berechtigungen zu erhöhen ohne verursacht XP stall in ein "Ausführen Als" - dialog-box, und ohne dass Windows 7 das kopieren der Dateien in AppData\Local\VirtualStore statt?

InformationsquelleAutor db2 | 2012-11-08

  1. 4

    Verbessert @db2 Antwort:

    • real elevation Prüfung, ohne je nach übergebenen Argumente
    • übergibt alle ursprünglichen Argumente, um die erhöhten Skript
    • verwendet den gleichen host, der das ursprüngliche Drehbuch: wscript.exe, cscript.exe, was

    Code:

    Set OSList = GetObject("winmgmts:").InstancesOf("Win32_OperatingSystem")
For Each OS In OSList
    If InStr(1, OS.Caption, "XP") = 0 And InStr(1, OS.Caption, "Server 2003") = 0 Then
        With CreateObject("WScript.Shell")
            IsElevated = .Run("cmd.exe /c ""whoami /groups|findstr S-1-16-12288""", 0, true) = 0
            If Not IsElevated Then
                Dim AllArgs
                For Each Arg In WScript.Arguments
                    If InStr( Arg, " " ) Then Arg = """" & Arg & """"
                    AllArgs = AllArgs & " " & Arg
                Next
                Command = """" & WScript.ScriptFullName & """" & AllArgs
                With CreateObject("Shell.Application")
                    .ShellExecute WScript.FullName, " //nologo " & Command, "", "runas", 1
                    WScript.Echo WScript.FullName & " //nologo " & Command
                End With
                WScript.Quit
            End If
        End With
    End If
Next

' Place code to run elevated here

    InformationsquelleAutor Miguel Angelo

  2. 2

    Scheint, wie dies ist der einfachste Weg, es zu tun.

    1. Check OS version.
    2. Wenn es nicht XP oder 2003 (ich erwarte nicht, daß dies läuft auf etwas älteren), re-execute mit der Höhe.

    Hier ist der code-block den ich am Anfang des Skripts:

    Dim OSList, OS, UAC
UAC = False
If WScript.Arguments.Count >= 1 Then
    If WScript.Arguments.Item(0) = "elevated" Then UAC = True
End If

If Not(UAC) Then
    Set OSList = GetObject("winmgmts:").InstancesOf("Win32_OperatingSystem")
    For Each OS In OSList
        If InStr(1, OS.Caption, "XP") = 0 And InStr(1, OS.Caption, "Server 2003") = 0 Then
            CreateObject("Shell.Application").ShellExecute "wscript.exe", """" & WScript.ScriptFullName & """ elevated" , "", "runas", 1
            WScript.Quit
        End If
    Next
End If
    Sieht aus, wie Sie sich selbst beantworten, aber ich werde das testen, wenn der aktuelle angemeldete Benutzer hat admin-Rechte, statt der Win-version ist, und erhöhen Sie wenn muss nur.

    InformationsquelleAutor db2

Schreibe einen Kommentar