die Verwendung von mehreren do-while-Schleife in VBA

Möchte ich Sie Fragen, wie mehrere tun, während Sie oder wenn es einen anderen Weg gibt, wie die Automatisierung dieser Art der Berechnung.
Ich habe Arbeitsblatt mit der Schlusskurse der Aktien namens Geschlossen. Auf einem anderen Blatt Gibt, würde ich gerne berechnen gibt. Ich weiß nicht, wie viele Zeilen und Spalten werden in Geschlossen.
Also schrieb ich das makro für die erste Spalte.

 Sub CalcReturns()
' CalcReturns
Dim row As Integer

Worksheets("Returns").Activate
row = 3
Do While Cells(row, 1) <> ""
Cells(row, 2).Value = Worksheets("Close").Cells(row, 2).Value / _
Worksheets("Close").Cells(row - 1, 2).Value - 1

row = row + 1
Loop
End Sub

Meine Frage ist, wie fügen Sie die zweite Schleife, die das tun, über die Kalkulation, so weit wie Daten in den Spalten der ersten Zeile.
Ich versuchte die Studie die Verwendung von Schleifen, aber ich war in der Lage, tun nur einer, nicht mehrere Danke im vorraus!!!!

InformationsquelleAutor user3703785 | 2014-07-03

Können Sie do-Schleifen Schachteln:

Do while firstCondition
    Do while secondCondition

    Loop
Loop

Ich bin mir nicht sicher, ob dies ist, was Sie zu tun versuchen, aber Sie können eine verschachtelte Schleife, um Ihren code wie folgt:

Sub CalcReturns()
' CalcReturns
Dim row As Integer

Worksheets("Returns").Activate
row = 3
'first loop
Do While Cells(row, 1) <> ""
    col = 2
    'second loop
    Do While Cells(row,col)<>""
        Cells(row, col).Value = Worksheets("Close").Cells(row, col).Value / _
        Worksheets("Close").Cells(row - 1, col).Value - 1
        col = col+1
    Loop
row = row + 1
Loop
End Sub

InformationsquelleAutor MatthewHagemann

Sub CalcReturns()
  ' CalcReturns
  Dim row As Integer

  Worksheets("Returns").Activate
  row = 3
  do until isempty(cells(row,1))
    col = 2
    do until isempty(cells(row,col))
      Cells(row, col).Value = Worksheets("Close").Cells(row, col).Value / _
      Worksheets("Close").Cells(row - 1, col).Value - 1
      col = col+1
    Loop
    row = row + 1
  Loop
End Sub

Vermeiden Sie die Auswahl und Aktivierungen

InformationsquelleAutor r_hudson

Habe ich nicht ganz verstanden, warum Sie benötigen, um die verschachtelten Schleife, aber hier ist ein Beispiel für eine geschachtelte do while-Schleife plus eine alternative Lösung.

Der code funktioniert auf der Annahme, dass Sie Ihre Arbeitsblatt-name "Schließen" mit der täglichen Schlusskurse (für Lager A und Lager B) und dem Datum in der ersten Spalte.

Stock A Stock B
01.12.2018  1000    345
02.12.2018  1002    350
03.12.2018  1001    351
04.12.2018  1003    352
05.12.2018  1005    348
06.12.2018  1006    349
07.12.2018  1005    352

Plus ein zweites Arbeitsblatt mit der Bezeichnung "Return", in dem Sie haben die gleiche Struktur für die Speicherung der täglichen Rückgabe der Daten.

Stock A Stock B
01.12.2018      
02.12.2018  0.20%   1.45%
03.12.2018  -0.10%  0.29%
04.12.2018  0.20%   0.28%
05.12.2018  0.20%   -1.14%
06.12.2018  0.10%   0.29%
07.12.2018  -0.10%  0.86%

Der code berechnet die täglichen Renditen für alle Termine, die für das Lager A und dann weiter mit Lager B (und weitere Aktien, die Sie hinzufügen, um das Blatt).

Hier ist die Lösung mit geschachtelte do while-Schleifen:

Sub CalculateReturns_UsingDoWhile()

    Dim wsC As Worksheet, wsR As Worksheet
    Dim lngRow As Long, lngCol As Long

    Set wsC = Worksheets("Close")
    Set wsR = Worksheets("Return")

    lngCol = 2
    Do While wsC.Cells(2, lngCol) <> vbNullString
        lngRow = 3
        Do While wsC.Cells(lngRow, lngCol).Value <> vbNullString
            wsR.Cells(lngRow, lngCol).Value = wsC.Cells(lngRow, lngCol).Value / wsC.Cells(lngRow - 1, lngCol).Value - 1
            lngRow = lngRow + 1
        Loop

        lngCol = lngCol + 1
    Loop

End Sub

Persönlich mag ich die alternative Ansatz der Verwendung von For-Schleifen, denn es gibt viel weniger Risiko, erstellen Endlosschleifen und ich finde es leichter zu Lesen. Beide code-Schnipsel das gleiche tun und so können Sie wählen, wie pro Ihre Vorliebe. 🙂

Sub CalculateReturns_UsingFor()

    Dim wsC As Worksheet, wsR As Worksheet
    Dim lngRow As Long, lngCol As Long

    Set wsC = Worksheets("Close")
    Set wsR = Worksheets("Return")

    For lngCol = 2 To wsC.Range("B1").End(xlToRight).Column
        For lngRow = 3 To wsC.Range("A2").End(xlDown).Row
            If wsC.Cells(lngRow, lngCol).Value <> vbNullString Then
                wsR.Cells(lngRow, lngCol).Value = wsC.Cells(lngRow, lngCol).Value / wsC.Cells(lngRow - 1, lngCol).Value - 1
            End If
        Next
    Next

End Sub

InformationsquelleAutor tk78

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.