Display immer den vollen Bildschirm in excel mit vba

Fügen Sie diesen in das workbook-Modul. Es wird maximieren Sie das Fenster, wenn es geändert ruft:

Private Sub Workbook_WindowResize(ByVal Wn As Window)
    ActiveWindow.WindowState = xlMaximized
End Sub

InformationsquelleAutor Dominic Sherry

Workbook_Activate bringt full-screen Modus, während andere zurück zu bringen normalen Modus.

Private Sub Workbook_Activate()
    On Error Resume Next
    With Application
        .DisplayFullScreen = True
        .CommandBars("Worksheet Menu Bar").Enabled = False
    End With

End Sub

Private Sub Workbook_Deactivate()
    On Error Resume Next
    With Application
        .DisplayFullScreen = False
        .CommandBars("Worksheet Menu Bar").Enabled = True
    End With

End Sub

BEARBEITEN

Sie sollten nicht 'ändern' die Art und Weise funktioniert Windows auf der system-Ebene. Allerdings, wenn Sie wirklich müssen; fügen Sie den folgenden, um ein neues Modul und rufen Sie die SetStyle-Verfahren.

, Code angeboten wird UNGETESTET'wie es ist' - die API ist eine Möglichkeit zum ändern von Windows auf der system-Ebene und kann gefährlich sein (plötzliche Abstürze, Daten-Datei Korruption,...), wenn Sie nicht wissen, was Sie tun.

VB:

Option Explicit 

 'Related Windows API functions
Private Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" (ByVal hWnd As Long, ByVal nIndex As Long) As Long 
Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hWnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long 
Private Declare Function GetSystemMenu Lib "user32" (ByVal hWnd As Long, ByVal bRevert As Long) As Long 
Private Declare Function DeleteMenu Lib "user32" (ByVal hMenu As Long, ByVal nPosition As Long, ByVal wFlags As Long) As Long 
Private Declare Function DrawMenuBar Lib "user32" (ByVal hWnd As Long) As Long 
Private Declare Function SetFocus Lib "user32" (ByVal hWnd As Long) As Long 
Private Declare Function LockWindowUpdate Lib "user32" (ByVal hWndLock As Long) As Long 

 'Window style constants
Private Const GWL_STYLE As Long = (-16) '//The offset of a window's style
Private Const GWL_EXSTYLE As Long = (-20) '//The offset of a window's extended style
Private Const WS_CAPTION As Long = &HC00000 '//Title bar bit
Private Const WS_SYSMENU As Long = &H80000 '//System menu bit
Private Const WS_THICKFRAME As Long = &H40000 '//Sizable frame bit
Private Const WS_MINIMIZEBOX As Long = &H20000 '//Minimize box bit
Private Const WS_MAXIMIZEBOX As Long = &H10000 '//Maximize box bit
Private Const WS_EX_TOOLWINDOW As Long = &H80 '//Tool Window: small titlebar bit

 'Constant to identify the Close menu item
Private Const SC_CLOSE As Long = &HF060 


Public Sub SetStyle() 

    Dim lStyle As Long, hMenu As Long 

     'Get the basic window style
    lStyle = GetWindowLong(Application.hWnd, GWL_STYLE) 

    If lStyle = 0 Then 
        MsgBox "Unable to determine application window handle...", vbExclamation, "Error" 
        Exit Sub 
    End If 

     '//Build up the basic window style flags for the form
     '//Uncomment the features you want...
     '//Set it True to enable, FALSE to disable
     '//The first 2 are obvious, ThickFrame controls if the Window is sizable or not.

     '//SetBit lStyle, WS_CAPTION, True
     '//SetBit lStyle, WS_SYSMENU, False
     '//SetBit lStyle, WS_THICKFRAME, False
    SetBit lStyle, WS_MINIMIZEBOX, False 
    SetBit lStyle, WS_MAXIMIZEBOX, False 

     'Set the basic window styles
    SetWindowLong Application.hWnd, GWL_STYLE, lStyle 

     'Get the extended window style
    lStyle = GetWindowLong(Application.hWnd, GWL_EXSTYLE) 


     '//Handle the close button differently
     '//If Close button is wanted
     '//hMenu = GetSystemMenu(Application.hWnd, 1)

     '//Not wanted - delete it from the control menu
    hMenu = GetSystemMenu(Application.hWnd, 0) 
    DeleteMenu hMenu, SC_CLOSE, 0& 


     'Update the window with the changes
    DrawMenuBar Application.hWnd 
    SetFocus Application.hWnd 

End Sub 


 '//Set or clear a bit from a style flag
Private Sub SetBit(ByRef lStyle As Long, ByVal lBit As Long, ByVal bOn As Boolean) 

    If bOn Then 
        lStyle = lStyle Or lBit 
    Else 
        lStyle = lStyle And Not lBit 
    End If 

End Sub 

InformationsquelleAutor skkakkar