Drag & Drop Batch-Datei für mehrere Dateien?

Ja, natürlich ist das möglich. Beim ziehen von mehreren Dateien auf eine batch-Datei bekommen Sie eine Liste der übersprungenen Dateien, die als eine durch Leerzeichen-getrennte Liste. Sie können dies überprüfen, mit dem einfach folgende batch:

@echo %*
@pause

Nun haben Sie zwei Möglichkeiten:

1. PngCrush kann bereits in der Lage mehrere Dateinamen auf der Kommandozeile. In diesem Fall alles, was Sie würde tun müssen, wäre die pass %* zu PngCrush, anstatt nur %1 (wie Sie wahrscheinlich jetzt tun):

   @pngcrush %*
   

   %* enthält alle Argumente, um die batch-Datei, so ist dies ein bequemer Weg, um pass alle Argumente zu einem anderen Programm. Vorsichtig mit Dateien mit Namen wie PngCrush Optionen, wenn. UNIX-geeks werden wissen,, problem 🙂

   Nach der Lektüre Ihrer post beschreibt Ihre Technik, aber das funktioniert nicht richtig, wie Sie schreiben, die komprimierte Datei, um new.png. Eine schlechte Idee, wenn Sie Umgang mit mehreren Dateien auf einmal, da kann es nur eine new.png :-). Aber ich habe gerade ausprobiert, dass PngCrush verarbeitet mehrere Dateien nur gut, wenn Sie also nicht dagegen eine in-place-update von den Dateien, dann setzen

   @pngcrush -reduce -brute %*
   

   in Ihrem batch-wird die Arbeit zu tun (nach Ihrer original-Artikel).

2. PngCrush nicht in der Lage mehrere Dateien oder Sie schreiben wollen, jedes Bild in einer neuen Datei nach der Kompression. In diesem Fall bleiben Sie mit Ihrem "one file at a time" - routine, aber Sie Schleife über die input-Argumente. In diesem Fall ist es am einfachsten, nur eine kleine Schleife und shift die Argumente jedes mal, wenn Sie Prozess ein:

   @echo off
   if [%1]==[] goto :eof
   :loop
   pngcrush -reduce -brute %1 "%~dpn1_new%~x1"
   shift
   if not [%1]==[] goto loop
   

   Was wir hier tun, ist einfach: Zunächst überspringen wir die gesamte Partie, wenn es ausgeführt wird, ohne Argumente, dann definieren wir ein label zum springen: loop. Im inneren haben wir Sie einfach laufen PngCrush auf das erste argument, was die komprimierte Datei einen neuen Namen. Möchten Sie vielleicht zu Lesen, auf den Weg Dissektion syntax, die ich hier in help call. Im Grunde, was ich hier mache ist der name der Datei genau wie vorher; ich habe nur stick "_new" am Ende des Dateinamens (vor der Erweiterung). %~dpn1 erweitert, um Laufwerk, der Pfad und der Dateiname (ohne Erweiterung), während %~x1 erweitert, um die Erweiterung, einschließlich der dot.

   ETA: Eep, ich habe gerade gelesen Ihre gewünschte Ausgabe mit neuen.png, neu(1).png, etc. In diesem Fall benötigen wir keine Lust Weg Dissektionen, aber wir haben andere Probleme zu kümmern.

   Der einfachste Weg wäre wahrscheinlich nur starten ein Zähler auf 0, bevor wir den Prozess der ersten Datei und die Schrittweite jedes mal, wenn wir den Prozess noch eins:

   @echo off
   if [%1]==[] goto :eof
   set n=0
   :loop
   if %n%==0 (
       pngcrush -reduce -brute %1 new.png
   ) else (
       pngcrush -reduce -brute %1 new^(%n%^).png
   )
   shift
   set /a n+=1
   if not [%1]==[] goto loop
   

   %n% ist unser counter hier, und wir behandeln den Fall, wo n ist 0 das Ergebnis schreiben zu new.png statt new(0).png.

   Dieser Ansatz hat Probleme, obwohl. Wenn es bereits Dateien mit dem Namen new.png oder new(x).png dann wirst du wohl Klamotten. Nicht schön. Also müssen wir etwas anders machen und prüfen, ob wir tatsächlich die Datei-Namen:

   rem check for new.png
   if exist new.png (set n=1) else (set n=0 & goto loop)
   rem check for numbered new(x).png
   :checkloop
   if not exist new^(%n%^).png goto loop
   set /a n+=1
   goto checkloop
   

   Den rest des Programms bleibt die gleiche, auch die normale Schleife. Aber jetzt starten wir in die ersten freien Dateinamen und vermeiden Sie das überschreiben von Dateien, die bereits vorhanden sind.

Fühlen Sie sich frei, um anzupassen, wie gebraucht.

InformationsquelleAutor der Antwort Joey

FOR %%A IN (%*) DO (
    REM Now your batch file handles %%A instead of %1
    REM No need to use SHIFT anymore.
    ECHO %%A
)

Und zu differenzieren zwischen abgelegten Dateien und Ordner, die Sie verwenden können:

FOR %%I IN (%*) DO (
    ECHO.%%~aI | FIND "d" >NUL
    IF ERRORLEVEL 1 (
        REM Processing Dropped Files
        CALL :_jobF "%%~fI"
    ) ELSE (
        REM Processing Dropped Folders
        CALL :_jobD "%%~fI"
    )
)

InformationsquelleAutor der Antwort Amr Ali