E4X Hinzufügen von CDATA-Inhalt

Im Prinzip brauche ich zum definieren eines node-Namen und den CDATA-Inhalten mithilfe von Variablen.

var nodeName:String = "tag";
var nodeValue:String = "<non-escaped-content>";

Naiv dachte ich, das würde funktionieren :

var xml:XML = <doc><{nodeName}><![CDATA[{nodeValue}]]></{nodeName}>

Ausgänge :

<doc><tag><![CDATA[{nodeValue}]]></tag></doc>

In einer früheren version des Skripts entworfen für FP9 ich umging das problem, indem Sie :

new XMLNode( XMLNodeType.XMLNodeType.CDATA_NODE, nodeValue ); //...

aber das scheint nicht zu funktionieren in FP10, und ich habe das Gefühl, die Methode ist irgendwie sowieso abgeschrieben.

Jemand eine elegante Lösung dafür ?

Antwort aktualisiert ... greetz

InformationsquelleAutor Theo.T | 2009-08-06

7

wie wäre es damit:
```
var xml:XML = <doc><{nodeName}>{nodeValue}</{nodeName}></doc>
trace(xml.toXMLString());
```
Ausgänge:
```
<doc>
  <tag>&lt;non-escaped-content&gt;</tag>
</doc>
```
ich gebe zu, das ist nicht CDATA, aber ich sehe kein problem ... Analyse erfordert ein wenig mehr Zeit, aber OTOH, richtige escaping viel robuster als CDATA ...

die version mit XMLNode verwendet die flash.xml - Paket, das ist für die Abwärtskompatibilität mit AS2 ... gar nicht bemerkt hatte, war es Weg unter FP10 ... aber, Sie könnte diese
```
var x:XML = new XML("<![CDATA[" + nodeValue + "]]>");
```
als Ersatz, und verwenden Sie dann appendChild als würden Sie mit flash.xml ...

alternativ könnte man es e4x-Stil, wenn Sie wickeln Sie es in eine Funktion
```
function cdata(data:String):XML {
    return = new XML("<![CDATA[" + data + "]]>");
}
```
dann
```
var xml:XML = <doc><{nodeName}>{cdata(nodeValue)}</{nodeName}></doc>
```
aber ich persönlich denke, dass Zeichenfolgen, die sowohl text-basiert und relativ kurz ist, sollten escaped werden, sondern dann, eingewickelt in CDATA ...

update:
ich nicht bekommen, Ihren Standpunkt hier

"<" ist ganz anders, als eine "<"

das ist, was die ganze Sache über ... 😀 ... "<" würde interpretiert werden, die während der Analyse, in der Erwägung, dass "<" ist nur zurückverwandelt zu "<", so dass nach dem Parsen der XML-haben Sie genau die gleiche Zeichenfolge wie zuvor ...

dies ist mein code:
```
package {
    import flash.display.MovieClip;
    public class Main extends MovieClip {       
        public function Main():void {
            var nodeName:String = "tag";
            var nodeValue:String = "<non-escaped-content>";
            var xml:XML = <doc><{nodeName}>{cdata(nodeValue)}</{nodeName}></doc>;
            trace(cdata("test").toXMLString());
            trace(xml.toXMLString());
        }
        private function cdata(data:String):XML {
            return new XML("<![CDATA[" + data + "]]>");
        }
    }
}
```
funktioniert perfekt für mich, auf flash player 10, der Kompilierung mit flex sdk 4 ... don ' T habe eine flash-IDE zur hand, aber wenn es um Reine ActionScript-Ergebnisse sind fast jeden Fall die gleichen, so sollte es funktionieren (Sie können verwenden Sie diese als Ihre Dokument-Klasse, wenn Sie wollen, oder einfach instanziieren) ...

btw. die erste Spur zeigt, dass das zweite Beispiel funktioniert, ist auch klar, da new XML(<String>) verwendet die native XML parser zu erstellen, die eine XML aus dem gegebenen string ...

hier ist, was die oben generiert:
```
<![CDATA[test]]>
<doc>
  <tag><![CDATA[<non-escaped-content>]]></tag>
</doc>
```
funktioniert ganz gut für mich ... 🙂

greetz

back2dos
- Hey, vielen Dank. Der Grund, warum ich will CDATA ist, dass die Methode verwendet um log-strings, einschließlich XML, in denen ein "<" ist etwas ganz anderes als ein "<" natürlich ... Leider ist die zweite Lösung wird zu konvertieren die tags der CDATA-in "<[CDATA[ ]]>" ignorieren die ganze Bedeutung des CDATA - () : (Hast du eigentlich die 3. Lösung arbeiten ? Dies funktionierte in FP9, sondern gibt mir einen runtime error in FP10 ?
- Ich bin nicht immer der cdata-helper-Funktion zum kompilieren von Flex-SDK-3.X nichts.
- welche Fehler sind Sie immer?
- Ich bin immer in der mxml-compiler-Fehlermeldung: "Parse error in '\");\n\t\t}\n\n\n\t\....return new XML("<![CDATA[" + data + "]]>");" ich habe eine kompilierbare Umsetzung des cdata-Funktion unten.
InformationsquelleAutor back2dos
7

Den oben genannten cdata-Funktion muss wie folgt Aussehen, sehen, dass die Letzte ">" ist das entkommen im code. Ansonsten gibt es Fehler bei der Kompilierung.
```
private function cdata(data:String):XML
{
    return new XML("<![CDATA[" + data + "]]\>");                
}
```
- diese Methode funktioniert gut für alle, aber was ist, wenn meine Daten ']]> " ich bin immer der Fehler "Das markup im Dokument nach dem Stammelement muss sein gut-gebildet." während der Konvertierung in xml. gibt es irgendeine andere Möglichkeit, es zu beheben ?
InformationsquelleAutor taudep

Dank, cdata-Funktion ist sehr nützlich. Ich schrieb nur neue.

function newNode(nodeName:String,nodeValue:String):XML{
    return new XML(<{nodeName}>{cdata(nodeValue)}</{nodeName}>);
}

InformationsquelleAutor emrahsifoglu

private function cdata(data:String, nodeName:String):XML{
    return new XML( "<"+nodeName+"><![CDATA[" + data + "]]\></"+nodeName+">");
}

funktionieren 🙂

InformationsquelleAutor eldervaz

Hier ist eine andere Lösung

public static function getCDATANode(data:String, tagName:String):void
{
        var node:XML  = new XML(  "<" + tagName + "/>" );
        var cdata:XML = new XML("<![CDATA[" + data + " ]]>");
        node.appendChild(cdata);

        trace("getCDATANode: ", node.toXMLString() );
}

InformationsquelleAutor Tahir Alvi

Hier ist meine Lösung ohne Verwendung von Funktionen:

var nodeName:String = "tag";
var nodeValue:String = "<non-escaped-content>";
var xml:XML = <doc><{nodeName}>{new XML("<![CDATA[" + nodeValue + "]]>")}</{nodeName}></doc>;

Wenn Sie ersetzen müssen, die vorhandenen Knoten Inhalte und halten Knoten-Attributen die Sie verwenden können:

var newNodeValue:String = "<non-escaped-content>";
var xml:XML = <doc><tag attribute="true">This is node content</tag></doc>;

xml.tag[0].setChildren(new XMLList());
xml.tag[0].appendChild(new XML("<![CDATA[" + newNodeValue + "]]>"));

InformationsquelleAutor Malacinjo

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.