einrichten eines timer in flash as3

Du willst also einen timer, ticks alle 15 Sekunden für 60 Sekunden. Das heißt, es wird auf tick 4 mal (60 /15). Nennen wir es speedTimer;
Sie haben zu instanziieren, es etwas wie das:

speedTimer = new Timer(60 * 1000, 4);

Dann müssen Sie zwei verschiedene Ereignis-Listener. Eine, die aufgerufen wird, jedes mal, wenn der timer "tickt", und eine, die aufgerufen wird, wenn es anhält.

speedTimer.addEventListener(TimerEvent.TIMER, onSpeedTimer);
speedTimer.addEventListener(TimerEvent.TIMER_COMPLETE, onSpeedTimerComplete);

In der ersten event-handler-Sie erhöhen den Wert des speed. Dass es möglich ist, werden Sie brauchen, um es zu ändern aus einer Konstanten eine variable.

In der zweiten handler, setzen Sie Ihre code, um zu gehen zu einer anderen Seite.

Gibt es einige Punkte, die sollten erwähnt werden:

Wenn Sie eine variable deklarieren, sollten Sie einen Bereich angeben (z.B. privat, öffentlich, etc.) auf die gleiche Weise tun, die für Ihre Funktionen:

private var catcher:Catcher;

Wenn Sie deklarieren eine Funktion, sollten Sie angeben einen Wert zurück, mit Ausnahme der Konstruktor Ihrer Klasse. Wenn die Funktion nichts zurückgibt, die Sie verwenden können, void:

public function setNextObject():void {
    [...]
}

Benennung ist wichtig, vor allem, um zu verstehen, Ihrem code, wenn Sie es später Lesen würde. Wenn Sie eine Timer ist es besser, nennen Sie es so etwas wie myTimer eher als nextObject.

Dies ist das gleiche für function-Namen: setNextObject() erstellt eine neue Timer und startet es, so würde ich es nennen startTimer().

Beim erstellen eines neuen Timers wie diese:

new Timer(1000 + Math.random() * 1000, 1);

Geben Sie eine Anzahl von Wiederholungen der 1. Das bedeutet, dass Ihre timer Stoppt nach der Verzögerung erfüllt ist. Weil Sie es wollen, laufen Sie über und über wieder, sollten Sie stattdessen geben Sie einem repeatCount von 0 (unendlich).
Halten die functionnality, dass Ihre timer-tick auf zufällige Intervall, werden Sie dann brauchen, um einen neuen delai Wert in der Ereignisprozedur

myTimer.delay = 1000 + Math.random() * 1000;

goodObjects und nadObjects werden niemals geändert, so sollten Sie extrahieren Sie Sie in der Konstanten:

private const GOOD_OBJECTS:Array = ["Circle1","Circle2"];
private const BAD_OBJECTS:Array  = ["Square1","Square2"];

Mit all diesen änderungen sollte es jetzt einfacher sein, zu verstehen, was dein code tut. Hier ist der aktualisierte code:

package
{
    import flash.display.*;
    import flash.events.*;
    import flash.text.*;
    import flash.utils.Timer;
    import flash.utils.getDefinitionByName;

    public class CatchingGame extends MovieClip
    {
        private const GOOD_OBJECTS:Array = ["Circle1","Circle2"];
        private const BAD_OBJECTS:Array = ["Square1","Square2"];

        private var catcher:Catcher;
        private var myTimer:Timer;
        private var speedTimer:Timer;
        private var objects:Array = new Array();
        private var score:int = 0;
        private var speed:Number;

        public function CatchingGame()
        {
            speed = 7.0;
            catcher = new Catcher();
            catcher.y = 350;
            addChild(catcher);
            startTimer();
            startSpeedTimer();
            addEventListener(Event.ENTER_FRAME, onEnterFrame);
        }

        public function startTimer():void
        {
            myTimer = new Timer(1000 + Math.random() * 1000, 0);
            myTimer.addEventListener(TimerEvent.TIMER, onTimer);
            myTimer.start();
        }

        public function startSpeedTimer():void
        {
            speedTimer = new Timer(60 * 1000, 4);
            speedTimer.addEventListener(TimerEvent.TIMER, onSpeedTimer);
            speedTimer.addEventListener(TimerEvent.TIMER_COMPLETE, onSpeedTimerComplete);
            speedTimer.start();
        }

        public function onTimer(e:Event):void
        {
            myTimer.delay = 1000 + Math.random() * 1000;
            if (Math.random() < .5)
            {
                var r:int = Math.floor(Math.random() * GOOD_OBJECTS.length);
                var classRef:Class = getDefinitionByName(GOOD_OBJECTS[r]) as Class;
                var newObject:MovieClip = new classRef(); 
                newObject.typestr = "good";
            }
            else
            {
                r = Math.floor(Math.random() * BAD_OBJECTS.length);
                classRef = getDefinitionByName(BAD_OBJECTS[r]) as Class;
                newObject = new classRef(); 
                newObject.typestr = "bad";
            }
            newObject.x = Math.random() * 500;
            addChild(newObject);
            objects.push(newObject);
            startTimer();
        }

        private function onSpeedTimer(e:Event):void
        {
            speed++;
        }

        private function onSpeedTimerComplete(e:Event):void
        {
            //Go to some page...
        }

        public function onEnterFrame(e:Event):void
        {
            moveObjects2();
        }

        public function moveObjects2():void {
            for(var i:int = objects.length - 1; i >= 0; i--)
            {
                objects[i].y += speed;
                if (objects[i].y > 400)
                {
                    removeChild(objects[i]);
                    objects.splice(i, 1);
                }
                if (objects[i].hitTestObject(catcher))
                {
                    if (objects[i].typestr == "good")
                    {
                        score += 5;
                    }
                    else
                    {
                        score -= 1;
                    }
                    if (score < 0)
                    {
                        score = 0;
                    }
                    scoreDisplay.text = "Score: "+score;
                    removeChild(objects[i]);
                    objects.splice(i,1);
                }
            }
            catcher.x = mouseX;
        }
    }
}

Wenn es noch einen Teil, der Sie nicht verstehen, fühlen Sie bitte sich frei, zu erwähnen Sie im Kommentar

InformationsquelleAutor duTr