Einstellung der Hintergrundfarbe eines contentbyte itextsharp

Gibt es kein Konzept von "Hintergrundfarbe" in der PDF-Spezifikation, die in Bezug auf text. Alles, was aussieht wie eine Hintergrundfarbe, auch ein Tisch, ist nur text gezeichnet, auf der Oberseite ein Rechteck (oder irgendeine andere Form).

Zeichnen Sie ein Rechteck, rufen Sie einfach die Rectangle Methode auf Ihre PdfContentByte Objekt. Es braucht eine linke untere x -, y -, und eine Breite und eine Höhe. Die Farbe wird bestimmt durch einen vorherigen Anruf an eines der Farbe füllt, wie SetColorFill().

Beim arbeiten mit dem raw canvas wird empfohlen, dass Sie verwenden auch SaveState() und RestoreState(). Da die fill-Befehle sind geteilt zwischen Objekten, aber unterschiedliche Dinge bedeuten diese können helfen, Verwirrung zu vermeiden. SaveState() setzt ein flag, so dass Sie rückgängig machen, alle Grafiken Zustand ändert, wenn Sie anrufen RestoreState().

Den code unten ist eine voll funktionsfähige VB.Net 2010 WinForms-app-targeting iTextSharp 5.1.2.0, die off zeigt die oben genannten. Es erstellt eine Beispiel-Datei auf dem desktop mit einer Textzeile wiederholt sich 7 mal. Jede Zeile schaltet hin und her zwischen zwei Hintergrundfarben. Außerdem zieht es einem Schlaganfall rund um die Textzeile zu simulieren Grenze.

Option Strict On
Option Explicit On

Imports System.IO
Imports iTextSharp.text
Imports iTextSharp.text.pdf

Public Class Form1

    Private Sub Form1_Load(sender As System.Object, e As System.EventArgs) Handles MyBase.Load
        ''//Test file that we'll create
        Dim TestFile = Path.Combine(Environment.GetFolderPath(Environment.SpecialFolder.Desktop), "TestFile.pdf")
        ''//Test String that we'll repeat
        Dim TestString = "It was the best of times..."
        ''//Create an array of our test string
        Dim TestArray = {TestString, TestString, TestString, TestString, TestString, TestString, TestString}

        ''//Create our generic font
        Dim BF_Times = BaseFont.CreateFont(BaseFont.TIMES_BOLD, BaseFont.CP1250, BaseFont.NOT_EMBEDDED)

        ''//Standard PDF setup, change as needed for your stream type
        Using FS As New FileStream(TestFile, FileMode.Create, FileAccess.Write, FileShare.None)
            Using Doc As New Document(PageSize.LETTER)
                Using writer = PdfWriter.GetInstance(Doc, FS)
                    Doc.Open()

                    ''//Grab the raw content object
                    Dim cb = writer.DirectContent
                    ''//Set our starter Y coordinate
                    Dim y = 670
                    ''//Loop through our string collection
                    For I = 0 To (TestArray.Count - 1)
                        ''//Store the current graphics state so that we can unwind it later
                        cb.SaveState()
                        ''//Set the fill color based on eve/odd
                        cb.SetColorFill(If(I Mod 2 = 0, BaseColor.GREEN, BaseColor.BLUE))
                        ''//Optional, set a border
                        cb.SetColorStroke(BaseColor.BLACK)
                        ''//Draw a rectangle. NOTE: I'm subtracting 5 from the y to account for padding
                        cb.Rectangle(0, y - 5, Doc.PageSize.Width, 15)
                        ''//Draw the rectangle with a border. NOTE: Use cb.Fill() to draw without the border
                        cb.FillStroke()
                        ''//Unwind the graphics state
                        cb.RestoreState()

                        ''//Flag to begin text
                        cb.BeginText()
                        ''//Set the font
                        cb.SetFontAndSize(BF_Times, 6)
                        ''//Write some text
                        cb.ShowTextAligned(PdfContentByte.ALIGN_LEFT, TestArray(I), 0, y, 0)
                        ''//Done writing text
                        cb.EndText()

                        ''//Decrease the y accordingly
                        y -= 15
                    Next


                    Doc.Close()
                End Using
            End Using
        End Using

        Me.Close()
    End Sub
End Class