Errorlevel in einer For-Schleife (Batch-Fenster)

Habe ich das folgende windows-batch-code:

for %%i in (iidbms iigcc iigcd dmfacp dmfrcp rmcmd qwerty) do (
  tasklist | findstr /i %%i
  echo %errorlevel%
  if %errorlevel% == 0 (echo %%i ok process found %errorlevel%)
  if %errorlevel% == 1 (echo %%i no process found %errorlevel%)
)

Aber es funktioniert nicht so wie ich erwarten.

Alle Namen Prozesse iidbms, iigcc, iigcd, dmfacp, dmfrcp, rmcmd sind real, und Sie werden finden, statt qwerty ist erfunden und sollte nicht finden, so sollte print " kein Prozess gefunden 1", aber es funktioniert nicht, druckt er immer 0.

Aber was ich gemerkt habe ist, dass wenn ich das tasklist | findstr /i qwerty von der dos-Eingabeaufforderung, kurz nach es ist, dass die %errorlevel% = 1.

Welche Art von Antwort könnte sein, oder besser ist?

InformationsquelleAutor der Frage aemme | 2010-10-15

  1. 22

    IF ERRORLEVEL gibt TRUE zurück, wenn der return-code war gleich oder höher als die angegebenen errorlevel. In deinem Beispiel, da 0 ist niedriger als 1, ist die erste errorlevel-Anweisung immer true sein, wenn der tatsächliche Fehlercode ist 0 oder höher. Was Sie wollen, ist zu testen errorlevel 1 ersten.

    E. g.:

    for %%i in (iidbms iigcc iigcd dmfacp dmfrcp rmcmd qwerty) do (
    tasklist | findstr /i %%i
    if errorlevel 0 if not errorlevel 1 echo process
    if errorlevel 1 if not errorlevel 2 echo process not found
)

    Weiteres Problem ist, wenn Sie wollen, echo der aktuelle errorlevel innerhalb der for-Schleife. Da Variablen, die aufgelöst werden, vor dem start der Schleife, echo %errorlevel% wird immer echo 0. Wenn Sie wollen auf der echo-Wert bei der Ausführung Zeit, müssen Sie zum ändern der snippet-wie so:

    setlocal enabledelayedexpansion
for %%i in (iidbms iigcc iigcd dmfacp dmfrcp rmcmd qwerty) do (
    tasklist | findstr /i %%i
    if errorlevel 0 if not errorlevel 1 echo %%i ok process found !errorlevel!
    if errorlevel 1 if not errorlevel 2 echo %%i no process found !errorlevel!
)

    InformationsquelleAutor der Antwort JRL

  2. 24

    Hinzufügen 

    setlocal EnableDelayedExpansion

    den Anfang deines Skriptes, dann verwenden Sie
    !errorlevel! statt %errorlevel%

    Verzögerte Erweiterung verursacht Variablen erweitert werden, bei der Ausführung
    Zeit, anstatt zur Analysezeit

    ~ http://ss64.com/nt/delayedexpansion.html

    Die Antwort auf eine andere Frage, die wies mich in die richtige Richtung: https://stackoverflow.com/a/6658935/10245

    InformationsquelleAutor der Antwort Tim Abell

  3. 0

    Können Sie vbscript verwenden,

    NumArgs = WScript.Arguments.Count
strComputer="."
Set objWMIService = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colProcessList = objWMIService.ExecQuery("Select * from Win32_Process")
For Each objProcess in colProcessList
    For i=0 To NumArgs-1
        If InStr( objProcess.Name ,WScript.Arguments(i)  ) > 0 Then
            WScript.Echo "found:" & WScript.Arguments(i)
        End If 
    Next 
Next

    Verwendung:

    C:\test>cscript //nologo test.vbs explorer spool svchost
found:svchost
found:svchost
found:svchost
found:svchost
found:svchost
found:explorer
found:svchost
found:spool

    InformationsquelleAutor der Antwort ghostdog74

Schreibe einen Kommentar