Erste AD-Details basierend auf Benutzername

Ich habe einen code zum abrufen der Informationen eines Benutzers aus dem AD-wie E-Mail-Adresse, Telefonnummer etc, etc. Die codes, die ich momentan verwende, ist:

Set objSysInfo = CreateObject("ADSystemInfo")
strUser = objSysInfo.UserName
msgbox(strUser)
Set objUser = GetObject("LDAP://" & strUser)

Es wird der aktuell angemeldete Benutzer die details. Aber was ich jetzt noch tun müssen, ist zu analysieren, in der Benutzername und das abrufen der details, die Grundlage.

Habe ich versucht zu ändern objSysinfo.Benutzername, um den Benutzernamen und das es leer zurückgegeben.

Set objSysInfo = CreateObject("ADSystemInfo")
strUser = "SomeUserName"
msgbox(strUser)
Set objUser = GetObject("LDAP://" & strUser)

Wie soll ich über das abrufen der Informationen aus der ANZEIGE für einen Benutzer-Namen zur Verfügung gestellt?

InformationsquelleAutor Bloopie Bloops | 2014-01-14

  1. 14

    LDAP-URIs erfordern einen definierten Namen. Account-Namen nicht funktionieren. Wenn Sie möchten, um Benutzer-Objekte basierend auf den Namen des Kontos Sie müssen ein "normaler" LDAP-Abfrage:

    username = "SomeUserName"

Set rootDSE = GetObject("LDAP://RootDSE")
base  = "<LDAP://" & rootDSE.Get("defaultNamingContext") & ">"
'filter on user objects with the given account name
fltr  = "(&(objectClass=user)(objectCategory=Person)" & _
        "(sAMAccountName=" & username & "))"
'add other attributes according to your requirements
attr  = "distinguishedName,sAMAccountName"
scope = "subtree"

Set conn = CreateObject("ADODB.Connection")
conn.Provider = "ADsDSOObject"
conn.Open "Active Directory Provider"

Set cmd = CreateObject("ADODB.Command")
Set cmd.ActiveConnection = conn
cmd.CommandText = base & ";" & fltr & ";" & attr & ";" & scope

Set rs = cmd.Execute
Do Until rs.EOF
  WScript.Echo rs.Fields("distinguishedName").Value
  rs.MoveNext
Loop
rs.Close

conn.Close

    Da ich verärgert aus, die zu schreiben alle, die boilerplate-code immer und immer wieder, wickelte ich es in eine Klasse (ADQuery) vor einiger Zeit.

    es funktioniert sehr gut! Vielen, vielen Dank! Ist das also eine Abfrage, die aus der AD-Datenbank?
    Richtig.
    Vor kurzem fand ich ein coder mit einer Github-Website, die hatte ein make-Befehl, für den Bau von Excel-Dateien, die enthaltenen VBA. Es war beeindruckend. Mein Arbeitsplatz-Sicherheit wird nicht lassen Sie mich speichern Sie Ihre .vba-Datei auf meiner Festplatte oder umbenennen. Gibt es eine chance, Sie können Ihre Bibliothek auf Github oder ähnliches?
    Ich werde darüber nachdenken.

    InformationsquelleAutor Ansgar Wiechers

  2. 0

    Einfach nur einen zusätzlichen Kommentar zu Ansgar RootDSE ist großartig, wenn Sie nur über eine Domäne verfügen. Sie können ändern, seinen code zu zeigen, wo sonst:

        base  = "<LDAP://" & rootDSE.Get("defaultNamingContext") & ">"

    etwas wie:

        base  = "<LDAP://" & "DC=corp,DC=foo,DC=com" & ">"

    wenn Ihre Domäne Active Directory-Domäne ist corp.foo.com

    InformationsquelleAutor Michael Berg

Schreibe einen Kommentar