Erstellen eines popup-Menüs zur Laufzeit

Haben Sie, um tatsächlich zu erstellen, die Instanzen einer Klasse in Delphi, bevor Sie Sie verwenden können. Der folgende code erstellt ein popup-Menü, fügt einige Elemente, die es (einschließlich einer Ereignisprozedur für das klicken Sie), und ordnet es in das Formular. Beachten Sie, dass Sie haben, zu deklarieren (und zu schreiben), die HandlePopupItemClick Veranstaltung selbst wie ich getan habe).

In der interface-Abschnitt (add Menus zu den uses - Klausel):

type
  TForm1 = class(TForm)
    // Double-click the OnCreate in the Object Inspector Events tab. 
    // It will add this item.
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
    // Add the next two lines yourself, then use Ctrl+C to
    // generate the empty HandlePopupItem handler
    FPopup: TPopupMenu;      
    procedure HandlePopupItem(Sender: TObject);
  public
    { Public declarations }
  end;

implementation

// The Object Inspector will generate the basic code for this; add the
// parts it doesn't add for you.
procedure TForm1.FormCreate(Sender: TObject);
var
  Item: TMenuItem;
  i: Integer;
begin
  FPopup := TPopupMenu.Create(Self);
  FPopup.AutoHotkeys := maManual;
  for i := 0 to 5 do
  begin
    Item := TMenuItem.Create(FPopup);
    Item.Caption := 'Item ' + IntToStr(i);
    Item.OnClick := HandlePopupItem;
    FPopup.Items.Add(Item);
  end;
  Self.PopupMenu := FPopup;
end;

// The Ctrl+C I described will generate the basic code for this;
// add the line between begin and end that it doesn't.
procedure TForm1.HandlePopupItem(Sender: TObject);
begin
  ShowMessage(TMenuItem(Sender).Caption);
end;

Nun werde ich überlasse es Ihnen, herauszufinden, wie zu tun den rest (erstellen und zeigen Sie es an einer bestimmten position).

InformationsquelleAutor Ken White