Erstellen Sie benutzerdefinierte MouseEvent.CLICK-Ereignis in AS3 (Parameter an eine Funktion)?

Diese Frage nicht beziehen sich nur auf das MouseEvent.KLICKEN Sie auf Ereignis-Typ, aber alle event-Typen, die bereits in AS3. Ich lese viel über benutzerdefinierte Ereignisse, aber bis jetzt konnte ich nicht herausfinden, wie zu tun, was ich tun möchte. Ich werde versuchen zu erklären, ich hoffe, Sie verstehen:

Hier ist eine illustration meiner situation:

for(var i:Number; i < 10; i++){
    var someVar = i;
     myClips[i].addEventListener(MouseEvent.CLICK, doSomething);
}

function doSomething(e:MouseEvent){ /* */ }

Aber ich möchte in der Lage sein, um pass someVar als parameter an doSomething. Also versuchte ich Folgendes:

for(var i:Number; i < 10; i++){

    var someVar = i;
    myClips[i].addEventListener(MouseEvent.CLICK, function(){
        doSomething(someVar);
    });
}

function doSomething(index){ trace(index); }

Diese Art von Werken aber nicht so, wie ich erwarten. Durch die Funktion Verschlüsse, wenn das MouseEvent.KLICKEN Sie auf Ereignisse tatsächlich feuerte die für Schleife ist schon vorbei und someVar hält den letzten Wert, die Anzahl 9 im Beispiel. Also jeder Klick in jeder Film-clip-call doSomething vorbei 9 als parameter. Und es ist nicht das, was ich will.

Dachte ich, dass das erstellen eines benutzerdefinierten Ereignisses sollte funktionieren, aber dann konnte ich nicht einen Weg finden, um ein benutzerdefiniertes Ereignis ausgelöst, wenn das MouseEvent.CLICK-Ereignis ausgelöst, und übergeben Sie die parameter. Nun weiß ich nicht, ob es die richtige Antwort.

Was soll ich tun und wie?

Für jemand anderes suchen, in dieser habe ich noch eine schnelle code-Beispiel zum übergeben von Parametern an eine Funktion hier: rocketwidget.com/...

InformationsquelleAutor fromvega | 2009-01-08

6

Ohne zu wissen, mehr über Ihre Anwendung, es scheint mehr wie sollten Sie mit dem target-Parameter übergeben, oder erweitern MouseEvent. Der ehemalige wäre mehr im Einklang mit der gängigen Praxis, wenn. So zum Beispiel, wenn Sie ausgesetzt sind eine integer public property auf Ihrem "clip" - Objekt (was auch immer es ist):
```
public class MyClip
{
   public var myPublicProperty:int;

   public function MyClip() { //... }
}

for (var i:int = 0; i < 10; i++)
{
   myClips[i].myPublicProperty = i;
   myClips[i].addEventListener(MouseEvent.CLICK, doSomething);
}
```
... und dann, in Ihrem Ereignis-listener, konnte Sie abrufen, dass Immobilien, die entweder das Ziel oder die Eigenschaft currentTarget des event (wahrscheinlich currentTarget, in deinem Fall):
```
function doSomething(event:MouseEvent):void
{
   trace(event.currentTarget.myPublicProperty.toString());
}
```
Das sollte es tun! Viel Glück.

InformationsquelleAutor Christian Nunciato
7

Sie wirklich brauchen, um erweitern die event-Klasse erstellen Sie Ihre eigene Veranstaltung mit zusätzlichen Parametern. Die Platzierung der Funktionen im addEventListener (anonyme Funktionen) ist ein Rezept für Speicherlecks, die ist nicht gut.
Werfen Sie einen Blick auf die folgenden.
```
import flash.events.Event;

//custom event class to enable the passing of strings along with the actual event
public class TestEvent extends Event
{
    public static const TYPE1 :String = "type1";
    public static const TYPE2 :String = "type2";
    public static const TYPE3 :String = "type3";

    public var parameterText:String;

    public function TestEvent (type:String, searchText:String)
    {
        this.parameterText = searchText;
        super(type);
    }

}
```
wenn Sie ein neues Ereignis erstellen, wie
```
dispatchEvent(new TestEvent(TestEvent.TYPE1, 'thisIsTheParameterText'))" ;
```
können Sie dann hören, dass Veranstaltung wie dieser
```
someComponent.addEventListener(TestEvent.TYPE1, listenerFunction, true , 0, true);
```
und innerhalb der Funktion 'listenerFunction" - Veranstaltung.parameterText wird, enthalten die parameter.

so, in Ihrem myClips Komponente, die Sie würde Feuer aus dem benutzerdefinierten event-und Listener für dieses Ereignis und nicht das Click-Ereignis.
- Warum würde anonyme Funktionen sein, eine wahrscheinliche Ursache von Speicherlecks, genau?
- Sie haben keine Referenz auf die Funktion, die in Verbindung mit der weakReference in die eventListener standardmäßig auf false, wenn Sie nicht vorsichtig führen, um memory-leaks. als schlechte Praxis + jede flashplayer 9.115 oder unten hat einen bug, der verursacht einen Speicherverlust für anon-funcs.
- Das erklärt immer noch nicht, wie ich den Feuer/Versand das benutzerdefinierte Ereignis, wenn ein MouseEvent.CLICK-Ereignis Auftritt. Bin ich etwas fehlt?
- Ihre Frage ist leicht vauge es, Sie bitten, über benutzerdefinierte Ereignisse, das ist, was ich versucht habe zu erklären. mit Ihnen können Sie Parameter hinzufügen, was Sie wollen. Wenn Sie möchten, um das Feuer von benutzerdefinierten Ereignis, wenn der Benutzer klickt auf die Komponente, nur die Verwendung der dispatchEvent-code in der click-handler der Komponente.
InformationsquelleAutor kenneth

    private function myCallbackFunction(e:Event, parameter:String):void
    {
         //voila, here's your parameter
    }

    private function addArguments(method:Function, additionalArguments:Array):Function 
    {
         return function(event:Event):void {method.apply(null, [event].concat(additionalArguments));}
    }

    var parameter:String = "A sentence I want to pass along";
    movieClip.addEventListener(Event.COMPLETE, addArguments(myCallbackFunction, [parameter] ) );

Nutzen Sie die dynamische Funktion Bau in AS3.

dies ist ausgezeichnet. Ich habe gerade implmented es in einem Projekt.
Danke, sehr sehr hilfreich!

InformationsquelleAutor Matt W

2

Können Sie erreichen dies, indem Sie den handler aus der Funktion, die die variable Verschluss, wie diese:
```
for (var i=0; i<5; i++) {
    myClips[i].addEventListener( MouseEvent.CLICK, getHandler(i) );
}

function getHandler(i) {
    return function( e:MouseEvent ) {
        test(i);
    }
}

function test( j ) {
    trace("foo "+j);
}
```
Auch, wie, warum dies erstellt eine neue Schließung, möchten Sie vielleicht zu prüfen, die Erklärung in der akzeptierten Antwort auf eine ähnliche Frage.

InformationsquelleAutor fenomas

Vielen Dank für diese nützliche Tipps, diese Technik besser zu verstehen als Klassen Erklärung.

für mich, ich habe gerade neu angefangen-code-Algorithmus, mit dieser Technik zu lösen, link Beziehung zwischen Timer-array und viewports array, und den status aktualisieren, indem Sie text ändern, in Ihnen Häufig durch die übergabe der ID ' s mit Timer-Ereignisse.

wie diese:

    var view:Object=[];

    for(var i:uint=0;i<Camera.names.length;i++){

    view[i]=getChildByName("Cam"+i);

    //_________ Add Text _________
    var tf:TextField = new TextField();
    tf.autoSize = TextFieldAutoSize.LEFT;
    tf.textColor=0xffffff;
    view[i].tf=view[i].addChild(tf);

    //_________ Add Timer _________
    var t:Timer = new Timer(1000);
    view[i].timer=t;
    view[i].timer.start();
    view[i].timer.addEventListener(TimerEvent.TIMER, addArg(i)); 
}

function addArg(adi:uint):Function {
    return function(event:TimerEvent):void {
        updatecamstatus(adi);
    }
}
function updatecamstatus(vH:uint):void {
   with (view[vH]){
    tf.text="Cam" + vH + "\n";
    tf.appendText("activityLevel: " + videosource.activityLevel + "\n"); 
    tf.appendText("motionLevel: " + videosource.motionLevel + "\n"); 
   }
}

InformationsquelleAutor Tareq Battat

1

Ich sehe, Ihr Ziel ist nicht, tatsächlich zum erstellen einer benutzerdefinierten MouseEvent.KLICKEN Sie auf, sondern übergeben Sie einen parameter an die Funktion. Sie brauchen nicht zu kompliziert erstellen oder erweitern etwas. Es gibt eine einfache und Verschluss-ärger-freie Weise, es zu tun.

Nur Ihre Funktion wie folgt:
```
function doSomething(index:Number):Function {
  return function(e:MouseEvent):void {
    //Use "e" and "index" here. They'll be unique for each addEventListener()
    trace(index);
  }
}
```
Diese Technik kann sich auf jeden AS3-event-Typ, den Sie verwenden können, addEventListener auf.

Und jetzt können Sie es wie folgt:
```
var functionsDoSomething:Object;

for (var i:Number = 0; i < 10; i++) {
  var someVar:Number = i;
  functionsDoSomething[i] = doSomething(someVar);
  myClips[i].addEventListener(MouseEvent.CLICK, functionsDoSomething[i]);
}
```
Den doSomething(someVar) kann verwendet werden, direkt auf addEventListener(), aber es ist besser, halten Sie es in einer Variablen zu, weil Sie in der Lage sein, um es zu entfernen später die gleiche Mode, die Sie Hinzugefügt:
```
for (i = 0; i < 10; i++) {
  myClips[i].removeEventListener(MouseEvent.CLICK, functionsDoSomething[i]);
}
```
Den Häufig verwendeten e.currentTarget.someCustomProperty funktioniert für dynamische Objekte (z.B. MovieClip), aber lassen Sie Sie nach unten auf irgendetwas anderes (z.B. Sprite), Sie zu zwingen, ein ganzes bilden, benutzerdefinierte erweiterte Objekt/Ereignis für jeden Typ.

Diese Lösung befasst sich mit jeden "hörbar" - Objekt und event. Und diese Antwort hat mehr details und Beispiele auf.

InformationsquelleAutor

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.