Excel-VBA - Schreiben mehrere userform checkbox-Werte in eine einzige Zelle

Ich bin versucht, den übergebenen Werte aus einer userform mit 4 Kontrollkästchen, Optionen und schreiben Sie Sie auf eine einzelne Zelle verkettet.

Wenn ich die Option meine userform so:

Ich würde gerne speichern, um eine einzelne Zelle wie diese:

Excel-VBA - Schreiben mehrere userform checkbox-Werte in eine einzige Zelle

Habe ich versucht, dies zu erreichen, mit dem folgenden code (siehe unten), aber es funktioniert nicht ganz richtig mit den Kommas und so, wenn nur der 2., 3., oder 4. Punkt gewählt wird, ohne die erste. Ich bin davon überzeugt, dass es einen besseren Weg, aber ich kann nicht herausfinden, oder finden Sie eine Antwort online.

Private Sub cmdSave_Click()
  Dim colors As String

   If chkRed = True Then
      colors = "Red"
   Else
      colors = colors
   End If

   If chkBlue = True Then
      colors = colors & ", Blue"
   Else
      colors = colors
   End If

   If chkGreen = True Then
      colors = colors & ", Green"
   Else
      colors = colors
   End If

   If chkYellow = True Then
      colors = colors & ", Yellow"
   Else
      colors = colors
   End If

   With colorsSheet
      .Cells(ActiveCell.Row, 1).Value = colors
   End With

   Unload Me

End Sub

InformationsquelleAutor ReidC | 2013-03-11

4

Benennen Sie den frame-Steuerelement zu frameColours dann können Sie Schleife seinen Checkboxen & bauen Sie Ihre string;
```
Dim chk as Control
Dim colors as string, delimiter as string

for Each chk In Me.frameColours.Controls
    if typeOf chk Is msforms.CheckBox then
        if (chk.Value) then
            colors = colors & delimiter & chk.Caption
            delimiter = ","
        end if
    end if
next

With colorsSheet
    .Cells(ActiveCell.Row, 1).Value = colors
End With
```
Alex, das sieht toll aus. Ich danke Ihnen so sehr. Ich werde versuchen es heraus und lassen Sie Sie wissen, wie es geht. Ich habe nicht gelernt, wie zu tun es auf diese Weise vor und wusste, es muss einen besseren Weg gibt.
Hat Super funktioniert. Einzige änderung die ich machen musste war, um ein Leerzeichen hinzuzufügen, um die Trennzeichen zu ändern,",",", "

InformationsquelleAutor Alex K.

Private Sub Submit_Click()

Dim lngIndex As Long, strTemp As String


For lngIndex = 1 To 16

'There are 16 check boxex, hence 1 to 16 is given

If Me.Controls("CheckBox" & lngIndex) Then
    strTemp = strTemp & Me.Controls("TextBox" & lngIndex).Value & vbLf 

'Returns you the output in a new line within the same cell.

End If

Next lngIndex

Sheets("Sheet1").Range("A1").Value = Left$(strTemp, Len(strTemp) - 1)

End Sub

InformationsquelleAutor mac

0

Wenn Sie ausschließen wollen, dass das erste Komma aus Ausgabe wie ", Blau, Grün, Gelb", sind Sie gehen zu müssen, ändern Sie den code, fügt diesen Zeichenfolgen überprüfen, ob colors leer ist. So etwas wie:
```
If chkBlue = true Then
    If colors = "" Then
        colors = "Blue"
    Else
        colors = colors & ", Blue"
    End If
End If
```
Da "Rot" ist die erste Farbe, die Sie hinzufügen, können Sie davon ausgehen, dass colors leer ist:
```
If chkRed = True Then
      colors = "Red"
End If
```
Du nicht' müssen Else ... colors = colors

Ich mag (und von Ihnen positiv bewertet werden) @Alex K. ' s Lösung. Es benötigt weniger code, und nicht die änderungen am code erfordern, wenn Sie das hinzufügen von Farben.
Tim, du hast Recht. Alex hat eine gute Lösung. Ich mag deins auch, weil es behebt mein code so wie es da steht. Froh, Sie zu haben 2 Möglichkeiten, was ich dargelegt um zu tun. Danke.

InformationsquelleAutor Tim

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.