Excel-VBA - variable für die Schleife

Ich kann nicht scheinen, um meine zweite for-Schleife rechts. Ich bin auf der Suche nach der Zelle mit dem Wert 'Persoonlijke prijslijst'. Sobald ich diese Zelle muss ich gehen, zwei-und delete-8 nach unten. Wenn ich Debuggen, es sagt temp = 0, so dass ich vermute, es ist in meinem zweiten for-Schleife.

Dim i As Integer
For i = 1 To 800
    Range("C" & i).Select
    If Range("C" & i).Value = "Persoonlijke prijslijst" Then
        Dim temp As Integer
        For temp = i - 2 To temp + 8
            Range("C" & temp).EntireRow.Delete Shift:=xlToLeft
        Next temp
    End If
Next i

Meinst du, gehen Sie zwei Zeilen, und löschen Sie dann 8 Zeilen nach unten von dort?
Ja, das ist richtig
Es ist, weil Sie beim löschen von Zeilen innerhalb dieser zweiten for-Schleife. Jedes mal, wenn eine Zeile gelöscht, die temp-variable würde auch aktualisiert werden müssen. Aber es ist besser, es zu tun Kyle ist Weg.
Es ist der Gedanke, der zählt 🙂
Wie kommt man falsche Gedanken 😉

InformationsquelleAutor CustomX | 2012-03-14

Ist es das, was Sie versuchen?

Option Explicit

Sub Sample()
    Dim ws As Worksheet
    Dim StrSearch As String
    Dim i As Long

    '~~> Change this to the relevant sheet name        
    Set ws = Sheets("Sheet1")

    StrSearch = "Persoonlijke prijslijst"

    With ws
        For i = 800 To 1 Step -1
            If .Range("C" & i).Value = StrSearch Then
                .Rows(i - 2 & ":" & i + 5).Delete
            End If
        Next i
    End With
End Sub

+1 🙂 guter Vorschlag Sid
Es geht nicht um Punkte. Ich habe nie Sorge 😉 Also Sie kann Umgekehrt die Abstimmung, die Sie gab. Es über etwas nach rechts 😉
Neee, die Sie noch verdient. Deins wahrscheinlich auch wirklich funktioniert!
Wieder bist du angenommen 😉
Kann ich bestätigen, es funktioniert 😉

InformationsquelleAutor Siddharth Rout

5

Einen anderen Weg ohne looping 800 mal:
```
 Sub testing()

Dim rng As Range
Dim fAddress As String
Dim rngRows As Range

With Sheet1.Range("C1:C800")
    Set rng = .Find("Persoonlijke prijslijst")
    If Not rng Is Nothing Then
        fAddress = rng.Address
        Do
        If rngRows Is Nothing Then
            Set rngRows = rows(rng.Row - 2 & ":" & rng.Row + 5)
        Else
            Set rngRows = Union(rngRows, rows(rng.Row - 2 & ":" & rng.Row + 5))
        End If
           Set rng = .FindNext(rng)
        Loop While Not rng Is Nothing And rng.Address <> fAddress
    End If
End With

rngRows.EntireRow.Delete

End Sub
```
- Kyle, hast du den code testen, bevor du postest? 😉
- Macht diese Arbeit für mehrere Selektionen? Also, wenn Persoonlijke prijslijst ist in meinem Dokument 4 mal?
- Ich habe bereits über .Finden und .FindNext in diesem link. "siddharthrout.wordpress.com/2011/07/14/...", Für eine kleine Anzahl von Zeilen, können Sie mit Schleifen. Allerdings, wenn Sie verwenden .Find Sie müssen sehr vorsichtig sein, als wenn Sie, löschen Sie den Bereich dann Set rng = .FindNext(rng) Zeile geben Sie den Fehler 😉 Lasst mich wissen, wenn Sie möchten, eine .Find - code als auch 🙂
- also mit .finden und .findnext ist weniger CPU-intensiv? Ich habe nicht verwendet diese Funktion in der Vergangenheit, so bin ich sehr daran interessiert. Wenn Sie Zeit haben und nichts dagegen haben, würde ich sagen ja .version finden 🙂
- ganz richtig, ich hatte ihn noch nicht getestet. Ich habe aktualisiert mein original code :S Danke Sid
- Zu finden ist schnell, aber es erfordert auch weniger Schleifen, sollten Sie versuchen zu vermeiden und die Schleife in VBA, da es langsam ist. Aufruf des Arbeitsblatts (die Dinge), dann ist auch langsam so getan werden sollte, so wenig wie möglich oder all in one gehen, wenn Sie können
- in diesem Fall kann ich nicht vor Ort das Problem, es funktioniert wie ich es erwarten würden? Also ich fürchte, du wirst zu haben, um mir zu sagen, was mir fehlt 😉
- Scheint, wie ich immer noch hatte sich der alte code, die gab mir falsche Ergebnisse. Ja nun funktioniert 🙂 wurde Der Schwerpunkt auf die Einstellung rngRows +1 für die Bereitstellung einen code, der funktioniert:)
- Sie haben nicht zu deaktivieren Kyles Antwort. Sie können nun wählen Sie seine Antwort, denn er hat geändert, der code und es funktioniert 🙂
- Dank Sid, hatte mich hinterfragen, meine geistige Gesundheit und für ein bisschen da 😉
- Ich bin der größte fan von .FINDEN und .FINDNEXT (wie Sie sehen können, es in meinem blog (siddharthrout.wordpress.com/2011/07/14/...), aber Es ist nicht machbar, für solche kleinen Zeilen. Sie am Ende mehr code schreiben 🙂
- Entschuldigung für die Fehler, ich wollte zu akzeptieren Sids Antwort, weil seine arbeitete zunächst 🙂 ich dachte, ich hätte akzeptiert sein, aber aufgrund der stackoverflow-Absturz für mich, ging etwas schief.
- Ich dachte es war nur mir. SO stürzt sich auf mich.
InformationsquelleAutor SWa

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.