Export einzelner Dokumente aus E-mail-merge

Wie würde ich es schaffen, Individuen-Dateien aus E-mail-merge statt eine große Datei, dass der Ausgang durch die Seriendruck-Funktion in Microsoft Office?

Hoffte ich, in der Lage sein, speichern Sie jeden Buchstaben als der erstellt wurde, als name eines der Seriendruckfelder, aber ich habe nicht in der Lage zu finden, eine intuitive Art und Weise so weit...

InformationsquelleAutor MT_ | 2014-11-05
  1. 2

    als von meiner Erfahrung, es ist keine option zum speichern einzelner Dateien, Sie können stattdessen verwenden von Makros zur spucken Sie die Dateien und speichern Sie Sie individuell mit speziellen Namen, den Sie möchten. Ich habe versucht, das gleiche, und es gelang mit, was Sie wollen. Hoffe den code unten hilft Ihnen ebenso erreichen Sie Ziel.

    Sub BreakOnSection()
   'Used to set criteria for moving through the document by section.
   Application.Browser.Target = wdBrowseSection

   'A mailmerge document ends with a section break next page.
   'Subtracting one from the section count stop error message.
   For i = 1 To ((ActiveDocument.Sections.Count) - 1)

      'Select and copy the section text to the clipboard
      ActiveDocument.Bookmarks("\Section").Range.Copy

      'Create a new document to paste text from clipboard.
      Documents.Add
      'To save your document with the original formatting'
      Selection.PasteAndFormat (wdFormatOriginalFormatting)

      'Removes the break that is copied at the end of the section, if any.
      Selection.MoveUp Unit:=wdLine, Count:=1, Extend:=wdExtend
      Selection.Delete Unit:=wdCharacter, Count:=1

      ChangeFileOpenDirectory "C:\"
      DocNum = DocNum + 1
      ActiveDocument.SaveAs FileName:="test_" & DocNum & ".doc"
      ActiveDocument.Close
      'Move the selection to the next section in the document
      Application.Browser.Next
   Next i
   ActiveDocument.Close savechanges:=wdDoNotSaveChanges
End Sub

    Bitte revert mich für alle Erklärungen.

    • Ich habe versucht, dieses Skript, wenn ich das erste Auseinandersetzung mit diesem Thema, aber ich habe immer ein Laufzeitfehler, wie "6078 - nicht finden konnte reichen." Es kann zu tun haben mit der Art und Weise der Universität hat, die Dinge (ich hatte zu tun, einige Tricks, um Sie zu bekommen, mir zu erlauben, verwenden Sie Makros in den ersten Platz). Ich bin versucht, dies für unsere office-admin, so bin ich versucht, um es so einfach wie möglich, was nicht möglich sein kann.
    • Wo machen Sie an das Ende jedes Dokuments. In anderen Worten, wo Sie sagen, das Makro zu stoppen und auch wenn ich Sie als PDF speichern, ist es nicht öffnen. Dank
    • Lebensretter, vielen Dank]
    InformationsquelleAutor Arunkumar Nehru
  2. 3

    Kürzlich habe ich über die ähnliche situation, wo ich speichern möchten, einzelne Dateien im pdf-format anstatt zu speichern eine große Datei erstellt, die von E-Mail-merge-Funktion. Ich habe aufgeschrieben, diese kleine Funktion zum speichern einzelner Dateien im pdf-format.

    Sub SaveAsPDF()
Dim CouncilName  As String   
    With ActiveDocument.MailMerge
        .Destination = wdSendToNewDocument
        .SuppressBlankLines = True
        For SectionCount = 1 To .DataSource.RecordCount
            With .DataSource
                'FirstRecord and LastRecords defines how many data records needs to be merge in one document.
                'createing pdf file for each data record so in this case they are both pointing to ActiveRecord.
                .FirstRecord = ActiveDocument.MailMerge.DataSource.ActiveRecord
                .LastRecord = ActiveDocument.MailMerge.DataSource.ActiveRecord

                'get the council name from data source 
                CouncilName = .DataFields("Council").Value  

                'move to next datasource record.
                If .ActiveRecord <> .RecordCount Then
                    .ActiveRecord = wdNextRecord
                End If
            End With

            'Get path and file name 
            PDFPathAndName = ActiveDocument.Path & Application.PathSeparator & "FINAL - " & CouncilName & ".pdf"

            ' Merge the document
            .Execute Pause:=False

            ' Save resulting document.
            Set PDFFile = ActiveDocument
            PDFFile.ExportAsFixedFormat PDFPathAndName, wdExportFormatPDF
            PDFFile.Close 0
        Next
    End With
End Sub
    • Ich werde versuchen, diese, würde es aber auch bewahren, Sicherheits-features, d.h. editierbare Felder in das Dokument?
    InformationsquelleAutor Parth Parmar
  3. 0

    Versuchen, diese - es war für mich - Exportiert einzelnen word-und pdf -

    http://www.gmayor.com/individual_merge_letters.htm

    • Ein link zu einer möglichen Lösung ist immer willkommen, aber bitte fügen Sie den Kontext um den link so dass Ihre Kolleginnen und Nutzer haben eine Vorstellung davon, was es ist und warum es da ist. Immer zitieren die meisten relevanten Teil eine wichtige Verbindung, im Falle der Ziel-Website nicht erreichbar ist oder dauerhaft offline ist. Berücksichtigen Sie, dass kaum mehr als ein link auf eine externe Seite ist ein möglicher Grund, Warum und wie Sie einige Antworten gelöscht?.
    InformationsquelleAutor Yogeshwar Patel
  4. 0

    Ich geändert Parth Antwort, da es für mich nicht funktioniert.

    Sub SaveAsFileName()
Dim FileName  As String
With ActiveDocument.MailMerge
    .Destination = wdSendToNewDocument
    .SuppressBlankLines = True

    For SectionCount = 1 To .DataSource.RecordCount
        With .DataSource
            ActiveDocument.MailMerge.DataSource.ActiveRecord = SectionCount
            ActiveDocument.MailMerge.DataSource.FirstRecord = SectionCount
            ActiveDocument.MailMerge.DataSource.LastRecord = SectionCount

            ' replace Filename with the column heading that you want to use - can't have certain symbols in the name
            FileName = .DataFields("Filename").Value
        End With

        'Get path and file name
        FullPathAndName = ActiveDocument.Path & Application.PathSeparator & FileName & ".docx"

        ' Merge the document
        .Execute Pause:=False

        ' Save resulting document.
        ActiveDocument.SaveAs (FullPathAndName)
        ActiveDocument.Close False
    Next
End With
End Sub
    InformationsquelleAutor John
Schreibe einen Kommentar