Exportieren von Daten aus PowerPivot

Um eine PowerPivot-Tabelle in Excel:

1. Erstellen Sie eine pivot-Tabelle, basierend auf PowerPivot-Daten.
2. Stellen Sie sicher, dass die pivot-Tabelle, die Sie erstellt hat, etwas in den Bereich Werte, aber nichts in Filter-, Spalten - oder Zeilen-Bereiche.
3. Gehen Sie zu Daten > Verbindungen.
4. Wählen Sie Ihr Daten-Modell und klicken Sie auf Eigenschaften.
5. In der Registerkarte Auslastung, OLAP Drill Durch die Maximale Anzahl von Datensätzen abrufen, so hoch, wie Sie benötigen (maximal 9999999 records).
6. Doppelklicken Sie auf den Maßnahmen-Bereich in der pivot-Tabelle zu bohren-durch.

InformationsquelleAutor Timo R.

Reines Excel /VBA-Lösung ist weiter unten. Dies ist adaptiert von der code hier zu verwenden "FileSystemObject" und Schreibe 1k Zeilen zu einer Zeit, zu der Datei. Sie benötigen, um Microsoft ActiveX Data Objects Library und Microsoft Scripting Runtime verweisen.

Option Explicit

Public FSO As New FileSystemObject

Public Sub ExportToCsv()

    Dim wbTarget As Workbook
    Dim ws As Worksheet
    Dim rs As Object
    Dim sQuery As String

    'Suppress alerts and screen updates
    With Application
        .ScreenUpdating = False
        .DisplayAlerts = False
    End With

    'Bind to active workbook
    Set wbTarget = ActiveWorkbook

    Err.Clear

    On Error GoTo ErrHandler

    'Make sure the model is loaded
    wbTarget.Model.Initialize

    'Send query to the model
    sQuery = "EVALUATE <Query>"
    Set rs = CreateObject("ADODB.Recordset")
    rs.Open sQuery, wbTarget.Model.DataModelConnection.ModelConnection.ADOConnection
    Dim CSVData As String
    Call WriteRecordsetToCSV(rs, "<ExportPath>", True)

    rs.Close
    Set rs = Nothing

ExitPoint:
    With Application
        .ScreenUpdating = True
        .DisplayAlerts = True
    End With
    Set rs = Nothing
    Exit Sub

ErrHandler:
    MsgBox "An error occured - " & Err.Description, vbOKOnly
    Resume ExitPoint
End Sub



Public Sub WriteRecordsetToCSV(rsData As ADODB.Recordset, _
        FileName As String, _
        Optional ShowColumnNames As Boolean = True, _
        Optional NULLStr As String = "")
    'Function returns a string to be saved as .CSV file
    'Option: save column titles

    Dim TxtStr As TextStream
    Dim K As Long, CSVData As String

    'Open file
    Set TxtStr = FSO.CreateTextFile(FileName, True, True)

    If ShowColumnNames Then
        For K = 0 To rsData.Fields.Count - 1
            CSVData = CSVData & ",""" & rsData.Fields(K).Name & """"
        Next K

        CSVData = Mid(CSVData, 2) & vbNewLine
        TxtStr.Write CSVData
    End If

    Do While rsData.EOF = False
        CSVData = """" & rsData.GetString(adClipString, 1000, """,""", """" & vbNewLine & """", NULLStr)
        CSVData = Left(CSVData, Len(CSVData) - Iif(rsData.EOF, 3, 2))
        TxtStr.Write CSVData
    Loop

    TxtStr.Close

End Sub

InformationsquelleAutor Matt Wenham