Extrahieren der eindeutigen Werte aus einer internen Tabelle

Was ist der effizienteste Weg zu extrahieren Sie die eindeutige Werte aus einer Spalte oder mehrere Spalten einer internen Tabelle?

InformationsquelleAutor Lilienthal | 2015-09-30

abap sap

7

Wenn Sie 7.40 SP08 oder oben können Sie einfach verwenden Sie die inline-syntax, zum füllen der Zieltabelle (keine Notwendigkeit für LOOP GROUP BY):
```
DATA: it_unique TYPE STANDARD TABLE OF fieldtype.
it_unique = VALUE #(
  FOR GROUPS value OF <line> IN it_itab
  GROUP BY <line>-field WITHOUT MEMBERS ( value ) ).
```
Dieser funktioniert mit jedem Typ der Zieltabelle.

Für eine ältere Version verwenden:
```
DATA: it_unique TYPE HASHED TABLE OF fieldtype WITH UNIQUE KEY table_line.
LOOP AT it_itab ASSIGNING <line>.
  INSERT <line>-field INTO TABLE lt_unique.
ENDLOOP.
```
Den oben genannten arbeiten mit sortierten Tabellen als gut. Obwohl ich nicht empfehlen die Verwendung von sortierten Tabellen für diesen Zweck, es sei denn, Sie wirklich sicher sind, dass nur ein paar Zeilen in der Ergebnismenge.

Die nicht-null - sy-subrc von INSERT wird einfach ignoriert. Keine Notwendigkeit zu tun, der key lookup-zweimal (einmal für Existenz-check, einmal für das einfügen).

Wenn das Ziel muss sein, eine STANDARD-TABELLE und Sie haben eine , alte ABAP-stack, können Sie alternativ auch
```
DATA: it_unique TYPE STANDARD TABLE OF fieldtype.
LOOP AT it_itab ASSIGNING <line>.
  READ TABLE lt_unique WITH TABLE KEY table_line = <line>-field
    TRANSPORTING NO FIELDS BINARY SEARCH.
  INSERT <line>-field INTO lt_unique INDEX sy-tabix.
ENDLOOP.
```
Diese bietet das gleiche Verhalten wie bei einer sortierten Tabelle, aber mit einer standard-Tabelle.
Ob dies effizienter als SORTIEREN /DELETE ADJACENT DUPLICATES hängt von der Anzahl der doppelten Einträge in itab. Das mehr doppelte Einträge vorhanden sind, desto schneller werden die oben genannten Lösung ist, weil es vermeidet die unnötige fügt in die Zieltabelle. Aber auf der anderen Seite hängt sind schneller als Beilagen.
- Deine erste Lösung funktioniert, aber lt_unique enthält leere Zeilen, wenn meine Tabelle hat leere Zeilen und leere Zeilen in meiner Quell-Tabelle gültig sind. Ich kann nicht löschen Sie Sie von der lt_unique als der Tisch hat keine Struktur. Wie kann ich das beheben?
InformationsquelleAutor Marcel
7

Vor der ABAP 7.40 s SP08 release, die effizienteste Art der Gewinnung von eindeutigen Werte aus einer internen Tabelle oder itab ist die folgende:
```
LOOP AT lt_itab ASSIGNING <ls_itab>.
    APPEND <ls_itab>-value TO lt_values.
ENDLOOP.
SORT lt_values.
DELETE ADJACENT DUPLICATES FROM lt_values.
```
Prüfung des Vorhandenseins eines bestimmten <ls_itab>-value vor dem hinzufügen der internen Tabelle ist ein weiterer Garant für Einzigartigkeit, sondern wahrscheinlich viel mehr rechenintensive beim einfügen in eine standard-Tabelle. Für sortierte oder Hash-Ziel-Tabellen, Verwendung:
```
LOOP AT lt_itab ASSIGNING <ls_itab>.
    READ TABLE lt_sorted_values WITH KEY table_line = <ls_itab>-value BINARY SEARCH.
    IF sy-subrc <> 0.
        APPEND <ls_itab>-value TO lt_sorted_values.
    ENDIF.
ENDLOOP.
```
Beachten Sie, dass mit der ersten Methode, aber das einfügen der Werte in eine dummy-Tabelle, gefolgt von einem APPEND LINES OF lt_dummy INTO lt_sorted_values kann schneller sein, aber die Größe der zwischen-Tabellen weiterverfolgen kann, die.

Als ABAP - 7.40 Support Package 08 jedoch die GROUP BY loops einen besseren Weg bieten, um zu extrahieren eindeutige Werte. Wie der name andeutet, diese Funktion ähnlich zu SQL ist GROUP BY. Zum Beispiel wird der folgende code-Auszug einzigartiges Projekt, das die zahlen aus einer internen Tabelle:
```
LOOP AT lt_project_data ASSIGNING FIELD-SYMBOL(<ls_grp_proj>)
    GROUP BY ( project = <ls_grp_proj>-proj_number ) ASCENDING
    WITHOUT MEMBERS
    ASSIGNING FIELD-SYMBOL(<ls_grp_unique_proj>).
        APPEND <ls_grp_unique_proj>-project TO lt_unique_projects.
ENDLOOP.
```
Die gleiche Logik, erweitert werden kann, abrufen einzigartige Paare, wie der zusammengesetzte Primärschlüssel der EKPO Tabelle EBELN ("Einkaufsbeleg", po_nr) und EBELP ("Artikelnummer des Kauf Dokument", po_item):
```
LOOP AT lt_purchasing_document_items ASSIGNING FIELD-SYMBOL(<ls_grp_po>)
    GROUP BY ( number = <ls_grp_po>-po_nr
               item   = <ls_grp_po>-po_item ) ASCENDING
    WITHOUT MEMBERS
    ASSIGNING FIELD-SYMBOL(<ls_grp_po_item>).
        APPEND VALUE #( ebeln = <ls_grp_po_item>-number
                        ebelp = <ls_grp_po_item>-item ) TO lt_unique_po_items.
ENDLOOP.
```
Nach Horst Keller, einer der SAP-Designer der neuen ABAP release 7.40, die Leistung von GROUP BY-Schleifen wird wahrscheinlich der gleiche sein wie eine manuelle Durchführung dieser Schleifen. Je nachdem, wie (in)effizient wie eine benutzerdefinierte Schleife implementiert ist, kann Sie sogar schneller sein. Beachten Sie, dass diese schneller sein wird als die zwei Methoden, die oben gegeben werden, für Systeme, auf denen die GROUP BY loops sind nicht verfügbar.

Beachten Sie, dass in den meisten Fällen Abfragen an die Datenbank zurück DISTINCT Werte viel schneller und performance-Weise tun, dass die Wehen alle ABAP-code, der verwendet den internen Tabellen aus dem Wasser, besonders on HANA Systemen.

InformationsquelleAutor Lilienthal

Wie über dieses?

lt_unique[] = lt_itab[].
SORT lt_unique[] BY field1 field2 field3...
DELETE ADJACENT DUPLICATES FROM lt_values COMPARING field1 field2 field3...

InformationsquelleAutor Thomas Matecki

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.