Extrahieren ID version aus POM in einem Jenkins-pipeline

Habe ich angelegt, eine pipeline und über die eingebetteten groovy-pipeline Skript-definition und kann nicht scheinen, um die version, die ID des Projekts von der POM. Ich habe versucht, die Werke in einem groovy-Konsole, aber auf dem Jenkins build-pipeline Skript:

def project = new XmlSlurper().parse(new File("pom.xml"))
def pomv = project.version.toString()

Gemäß der Dokumentation Jenkins hat eine $POM_VERSION aber der Wert nicht in es nichts, wenn ich es einer Variablen zuweisen und echo aus.

def pomv = "$POM_VERSION"

ODER

def pomv = '$POM_VERSION"
InformationsquelleAutor user301693 | 2016-06-02
  1. 68

    Verwenden readMavenPom wie diese:

    pom = readMavenPom file: 'pom.xml'
pom.version

    Sehen Modell Referenz für die Eigenschaften (wie die obige version).

    Damit dies funktioniert, muss man installieren Pipeline-Dienstprogramm Schritte plugin

    InformationsquelleAutor Krzysztof Krasoń
  2. 9

    In Jenkins 2.138.3 es gibt zwei verschiedene Arten von Rohrleitungen.

    Deklarative und Scripted-pipelines.

    "Deklarative Rohrleitungen ist eine neue Erweiterung der pipeline-DSL (es ist im Grunde ein pipeline-Skript mit nur einem Schritt, ein pipeline-Schritt mit Argumenten (sogenannte Richtlinien) diese Richtlinien sollten Folgen einer bestimmten syntax. Der Punkt dieses neuen formats ist, dass es mehr strenge, und deshalb sollte es einfacher sein für diejenigen, die neu in die Rohrleitungen ermöglichen für die grafische Bearbeitung und vieles mehr.
    scripted-pipelines ist der fallback für erweiterte Anforderungen."

    jenkins pipeline: agent vs-Knoten?

    Hier ist ein Beispiel für eine Deklarative Pipeline: 

    pipeline {

    agent any


    environment {
    //Use Pipeline Utility Steps plugin to read information from pom.xml into env variables
    IMAGE = readMavenPom().getArtifactId()
    VERSION = readMavenPom().getVersion()
    }


    stages {

        stage('Test') {
            steps {
                echo "${VERSION}"
            }

        }

    }

}

    Beispiel von Scripted-Pipeline

    node('master') {

  stage('Test') {
    IMAGE = readMavenPom().getArtifactId()
    VERSION = readMavenPom().getVersion()
    echo "IMAGE: ${IMAGE}"
    echo "VERSION: ${VERSION}"
  }

}

    Hier sind einige gute links:

    Deklarative
    https://github.com/jenkinsci/pipeline-examples/blob/master/declarative-examples/jenkinsfile-examples/mavenDocker.groovy

    Scripted
    https://bulldogjob.com/articles/726-exploring-jenkins-pipelines-a-simple-delivery-flow

    InformationsquelleAutor pitchblack408
  3. 6

    Den Erste Schritte mit Pipeline Seite zeigte sich noch eine andere option. Es funktioniert ohne zusätzliche plugins.

    Eine etwas stabilere version kann gefunden werden in der gemeinsamen Bibliothek ces-bauen-lib (es hat auch einige grundlegende unit-tests):

    def version() {
    def matcher = readFile('pom.xml') =~ '<version>(.+?)</version>'
    matcher ? matcher[0][1] : null
}

    Diese immer mit der ersten <version> tag finden Sie in der pom.xml. Diese sollte die version des maven-Modul oder seine Eltern in den meisten Fällen.

    • Wenn Sie hängen, auf eine parent-POM, dann verwenden Sie matcher[1][1], weil matcher[0][1] entspricht der parent POM version.
    • Diese Antwort funktioniert nicht in jedem meiner POMs, denn es gibt immer mehr als eine <version> - tag.
    • danke für den Hinweis. Ich bearbeitet die post. Diese Arbeit übernimmt jetzt für Sie?
    • Ich glaube nicht, dass es irgendeine Garantie, dass "der erste <version> - tag zu finden pom.xml" ist das Artefakt-version. Wären Sie unter einer großen chance auf der Annahme, dass Menschen setzen die XML-tags in einer bestimmten Reihenfolge, die ist überhaupt nicht erforderlich, durch das format. Wie du sagtest selbst, ist es sehr wahrscheinlich das übergeordnete Artefakt-version statt, die möglicherweise zu völlig falschen Ergebnissen. Das Parsen der XML-scheint der einzig sichere Weg, zu Bearbeiten POM.
    InformationsquelleAutor schnatterer
  4. 3

    Können Sie versuchen readMavenPom Funktion, die verfügbar ist.

    Mehr info ist hier: https://jenkins.io/doc/pipeline/steps/pipeline-utility-steps/#readmavenpom-read-a-maven-project-file

    • Beachten Sie, dass Sie brauchen, um installieren Sie die Rohrleitung Utility-Schritte-plugin um diesen Schritt.
    • Pipeline-Dienstprogramm Schritte plugin sagt, es braucht Pipeline: Groovy plugin 1.11, die ist fast 2 Jahre alt und weit hinter der aktuellen 2.30 (oder so). Das macht mich nervös.
    InformationsquelleAutor Raitis Dembovskis
  5. 0

    Scheint, wie readMavenPom ist die straight-forward beantworten, aber da es erforderlich ist die installation eines zusätzlichen pipeline-plugin, hier ist eine andere, verwendet die native maven-Ansatz statt laden von xml-Daten (basierend auf diese Antwort)

    def mvn_project_version(pom_file) {
    return sh(
        script: """mvn -N -f $pom_file org.apache.maven.plugins:maven-help-plugin:evaluate -Dexpression=project.version |
                   grep -Ev '(^\\s*\\[|Download\\w+:)'""",
        returnStdout: true).trim()
}

    Wegen der Verwendung von grep dieser Befehl funktioniert vielleicht nicht auf einigen Plattformen, die nicht posix-kompatibel, aber man kann immer wird der output in Groovy statt Rohrleitungen durch grep.

    InformationsquelleAutor
  6. 0

    Ich habe gerade die verstärkte @haridsv Lösung ohne Verwendung von grep:

    #!/usr/bin/env
def call(String mvnBin = 'mvn',String pom_file = 'pom.xml') {

return sh(
        script: mvnBin+''' -N -f '''+pom_file+''' org.apache.maven.plugins:maven-help-plugin:evaluate -Dexpression=project.version -q -DforceStdout''',
        returnStdout: true).trim()
}

    Solltest du besser nicht verwenden readMavenPom, da es veraltet ist ( siehe PR https://github.com/jenkinsci/pipeline-utility-steps-plugin/pull/47/commits/eeebaa891a006c083ce10f883b7c1264533bb692 ). Sie können kopieren und fügen Sie diesen in eine Datei wie evaluateMavenPomVersion.groovy 🙂

    InformationsquelleAutor Vincenzo Cerbone
  7. -1

    Ich in der Regel verwenden Sie die Karte, um dies zu tun.

     def pomFile = readFile(pomName)
 def pom = new XmlParser().parseText(pomFile)
 def gavMap = [:]
 gavMap['groupId'] =  pom['groupId'].text().trim()
 gavMap['artifactId'] =  pom['artifactId'].text().trim()
 gavMap['version'] =  pom['version'].text().trim()
    InformationsquelleAutor Mohamed Thoufeeque
  8. -1

    Ich bin gerade erst mit Jenkisfile und ich hatte das gleiche problem wie du. Da XmlSlurper und XmlParser verboten sind Standard-Konfiguration, die ich haben crated unten-Funktion zum extrahieren von maven version:

    String readProjectVersion(String pom) {
    //Take value of the <project> tag
    def matcher = pom.trim() =~ /(?s)<project[^>]*>(.*)<\/project>/
    def pomWithoutProject = matcher[0][1].trim()

    //remove every tag except <version>, since only project version is not encapsulated in the other tag e.g. dependency, parent, plugin
    def nonVersionMatcher = pomWithoutProject =~ /(?s)\s*(?!<version>)<([a-zA-Z][a-zA-Z0-9]*)\b[^>]*>(.*?)<\/\1>\s*/
    def versionTag = nonVersionMatcher.replaceAll("").trim()
    //Take value of the <version> tag
    def versionTagMatcher = versionTag =~ /<version>(.*)<\/version>/
    if (versionTagMatcher.matches()) {
        return versionTagMatcher[0][1]
    }
    //no version tag, version should be inherited from parent version
    def parentVersionMatcher = pomWithoutProject =~ /(?s)\s*<parent>.*<version>(.*)<\/version>.*<\/parent>\s*/
    return parentVersionMatcher[0][1]
}

    Habe ich getestet, diese Lösung gegen die Dateien, in denen Eltern erklärt wurde, die version war die erste Anweisung, die version war die Letzte Anweisung und bei Anwesenheit der version in verschachtelten tags wie dependency, plugin etc.

    InformationsquelleAutor Łukasz D.
Schreibe einen Kommentar