Extrahieren string aus einer text-Datei mit Trennzeichen 2

Ich versuche zu extrahieren eines string aus einer text-Datei mit 2 Trennzeichen. Eine zum starten und eine zum stoppen.

Beispiel:

Hi my name is$John and I'm happy/today

Was ich tun müssen, ist, um eine Funktion aufzurufen, die würde den string zwischen $ und /. Ich habe schon überall gesucht aber ich kann nicht scheinen, etwas nützliches zu finden, und ich bin neu in der Programmierung.

InformationsquelleAutor Gab | 2011-02-09
  1. 12

    Können Sie es mit Pos und Copy:

    function ExtractText(const Str: string; const Delim1, Delim2: char): string;
var
  pos1, pos2: integer;
begin
  result := '';
  pos1 := Pos(Delim1, Str);
  pos2 := Pos(Delim2, Str);
  if (pos1 > 0) and (pos2 > pos1) then
    result := Copy(Str, pos1 + 1, pos2 - pos1 - 1);
end;
    • PosEx, um die Suche für Delim2 ab nachdem die Lage des Delim1.
    • Ja, das würde die Leistung steigern.
    • Vielen Dank genau das was ich gebraucht habe!!
    • Andreas: nicht nur die performance. Es ergeben sich auch ein Ergebnis, wenn es ist eine schließende Trennzeichen vor der Eröffnung Trennzeichen, das der code nicht.
    • Ja, das ist richtig.
    InformationsquelleAutor Andreas Rejbrand
  2. 12

    Den oben genannten Funktionen wird nicht funktionieren, wenn das 2. der text erscheint auch vor dem 1. Muster...

    Sollten Sie verwenden PosEx() statt Pos():

    Können Sie es mit Pos und Copy:

    function ExtractText(const Str: string; const Delim1, Delim2: string): string;
var
  pos1, pos2: integer;
begin
  result := '';
  pos1 := Pos(Delim1, Str);
  if pos1 > 0 then begin
    pos2 := PosEx(Delim2, Str, pos1+1);
    if pos2 > 0 then
      result := Copy(Str, pos1 + 1, pos2 - pos1 - 1);
  end;
end;
    InformationsquelleAutor Arnaud Bouchez
  3. 10

    Ich würde es tun, so etwas wie dieses:

    function ExtractDelimitedString(const s: string): string;
var
  p1, p2: Integer;
begin
  p1 := Pos('$', s);
  p2 := Pos('/', s);
  if (p1<>0) and (p2<>0) and (p2>p1) then begin
    Result := Copy(s, p1+1, p2-p1-1);
  end else begin
    Result := '';//delimiters not found, or in the wrong order; raise error perhaps
  end;
end;
    • Genau in derselben Sekunde. Das ist ziemlich cool.
    • cool ja
    InformationsquelleAutor David Heffernan
  4. 7

    Get em all

    function ExtractText(const Str: string; const Delim1, Delim2: string): TStringList;
var
  c,pos1, pos2: integer;
begin
  result:=TStringList.Create;
  c:=1;
  pos1:=1;

  while pos1>0 do
  begin
    pos1 := PosEx(Delim1, Str,c);
    if pos1 > 0 then begin
      pos2 := PosEx(Delim2, Str, pos1+1);
    if pos2 > 0 then
      result.Add(Copy(Str, pos1 + length(delim1), pos2 - (length(delim1) + pos1)));
      c:=pos1+1;
     end;

  end;
end;
    • Nette Idee, um mehrere vorkommen, aber es ist nicht ein gutes design zu erstellen, das Objekt innerhalb der Funktion den aufrufenden code verwalten müssen, die die Befreiung der Objekt zimmerreserviereung, ohne das Sie es erstellt hat. Die stringlist erstellt werden soll (und verwaltet) durch den aufrufenden code, und per Referenz übergeben.
    • Ich bin neu in der Programmierung. Nur-sharing-Idee. Vielleicht, das jemand es beheben kann.
    InformationsquelleAutor poetra
  5. 4

    Gab, können Sie eine Funktion schreiben, die dies tun, mit einem TFileStream Klasse, und die Copy und Pos Funktionen.

    siehe dieses Beispiel : 

    uses
  Classes,
  SysUtils;

function ExtractString(Const FileName: TFileName;Const IDel,FDel : AnsiString) : AnsiString;
Var
 FileStream : TFileStream;
 i,f        : Integer;
begin
  FileStream:= TFileStream.Create(FileName, fmOpenRead or fmShareDenyWrite); //oopen the file
  try
    try
      SetLength(Result, FileStream.Size); //set the size of the string
      FileStream.Read(Pointer(Result)^, FileStream.Size);//read the content into a string
      i:=Pos(IDel,Result);//search the initial delimiter
      f:=Pos(FDel,Result);//search the final delimiter
      Result:=Copy(Result,i+1,f-i-1); //extract the value between the delimiters
    except
      Result := '';
      raise;
    end;
  finally
    FileStream.Free;
  end;
end;

    werden und nutzen auf diese Weise

    ExtractString('your_file_name','$','/');
    • Anstelle von SetLength+Lesen, Sie können auch einen TMemoryStream, dann LoadFromFile() then SetString(Result,PAnsiChar(MemoryStream.Speicher),MemoryStream.Größe);
    InformationsquelleAutor RRUZ
  6. 3

    In den neueren Delphi können Sie es so machen.. (yay)

    program Project40; {$APPTYPE CONSOLE}

uses RegularExpressions;

const
  str = 'Is$John and I''m happy/today';

function GetStr(const aStr: string): string;
begin
  Result := TRegEx.Match(aStr, '\$.*/').Value;
  Result := Copy(Result, 2, Length(Result) - 2);
end;

begin
  Writeln(GetStr(str));
  ReadLn;
end.
    • Nicht die beste Verwendung für Reguläre Ausdrücke, aber +1 für denken außerhalb der box.
    InformationsquelleAutor Wouter van Nifterick
  7. 2

    Vorausgesetzt, beide Trennzeichen sind Zeichen, die wie pro Ihre post:

    function ExtractDelimitedValueFromFile(const aFilename: String;
                                       const aOpenDelim: Char;
                                       const aCloseDelim: Char;
                                       var aValue: String): Boolean;
var
  i: Integer;
  strm: TStringStream;
  delimStart: Integer;
  delimEnd: Integer;
begin
  result      := FALSE;
  aValue      := '';
  delimStart  := -1;
  delimEnd    := -1;

  strm := TStringStream.Create;
  try
    strm.LoadFromFile(aFileName);

    for i := 1 to strm.Size do
    begin
      if (delimStart = -1) and (strm.DataString[i] = aOpenDelim) then
        delimStart := i
      else if (delimStart <> -1) and (strm.DataString[i] = aCloseDelim) then
        delimEnd := i;

      result := (delimStart <> -1) and (delimEnd <> -1);
      if result then
      begin
        aValue := Copy(strm.DataString, delimStart + 1, delimEnd - delimStart - 1);
        BREAK;
      end;
    end;

  finally
    strm.Free;
  end;
end;

    Verwendung:

      var
    str: String;
  begin
    if ExtractDelimitedValueFromFile('path\filename.ext', '$', '/', str) then
      // work with str
    else
      // delimited value not found in file
  end;
    InformationsquelleAutor Deltics
Schreibe einen Kommentar