Extrahiert numerische Daten aus string in groovy

Ich bin da ein string, der text und numerische Daten:

Beispiele:

"100 Pfund"
"Ich denke, 173 lbs"
"73 lbs."

Ich bin auf der Suche für eine saubere Art und Weise zu extrahieren nur die numerischen Daten aus diesen strings.

Hier ist, was ich bin derzeit dabei Streifen die Antwort:

def stripResponse(String response) {
    if(response) {
        def toRemove = ["lbs.", "lbs", "pounds.", "pounds", " "]
        def toMod = response
        for(remove in toRemove) {
            toMod = toMod?.replaceAll(remove, "")
        }
        return toMod
    }
}
InformationsquelleAutor Joel Miller | 2013-03-22
  1. 24

    Könnten Sie findAll dann konvertieren Sie das Ergebnis in ganzen zahlen:

    def extractInts( String input ) {
  input.findAll( /\d+/ )*.toInteger()
}

assert extractInts( "100 pounds is 23"  ) == [ 100, 23 ]
assert extractInts( "I think 173 lbs"   ) == [ 173 ]
assert extractInts( "73 lbs."           ) == [ 73 ]
assert extractInts( "No numbers here"   ) == []
assert extractInts( "23.5 only ints"    ) == [ 23, 5 ]
assert extractInts( "positive only -13" ) == [ 13 ]

    Wenn Sie brauchen, Dezimalzahlen und negativen zahlen, könnten Sie mit einem komplexeren regex:

    def extractInts( String input ) {
  input.findAll( /-?\d+\.\d*|-?\d*\.\d+|-?\d+/ )*.toDouble()
}

assert extractInts( "100 pounds is 23"   ) == [ 100, 23 ]
assert extractInts( "I think 173 lbs"    ) == [ 173 ]
assert extractInts( "73 lbs."            ) == [ 73 ]
assert extractInts( "No numbers here"    ) == []
assert extractInts( "23.5 handles float" ) == [ 23.5 ]
assert extractInts( "and negatives -13"  ) == [ -13 ]
    • Lösung, dass ich am Ende die Umsetzung basiert auf Beratung vor, ich möchte nur schnappen Sie sich die erste Zahl (wenn dort sind Vielfache I erlöschen der Reaktion). Danke @tim_yates ! def extractNumericData(String response) { if(response) { def numberList = response.findAll( /[0-9]+.[0-9]*|[0-9]*.[0-9]+|[0-9]+/ ) if(numberList.size() == 1) { return numberList.get(0) as BigDecimal } else { return -1 } } }
    • Aus irgendeinem Grund bekomme ich diese: java.lang.UnsupportedOperationException: spread not yet supported in input.findAll(\d+)*.toInteger() . ---- Und heißt es auf Jenkins Ihr gelöst.
    InformationsquelleAutor tim_yates
  2. 2

    Setze dieses hier für Menschen, die brauchen das.

    Anstatt neue Frage, alles, was ich brauchte, war eine Zahl aus einem string.

    Habe ich das mit regex.

    def extractInt( String input ) {
  return input.replaceAll("[^0-9]", "")
}

    Wo der Eingang sein könnte this.may.have.number4.com und zurück 4

    War ich Fehlermeldungen von oben beantworten (wahrscheinlich aufgrund meiner Jenkins-version) - Für einige Grund, warum ich dieses: java.lang.UnsupportedOperationException: spread not yet supported in input.findAll(\d+)*.toInteger() ---- Und es sagt auf Jenkins seine gelöst.

    Hoffe, das hilft.

    • Von Ihnen positiv bewertet werden, denn, obwohl es nicht die Antwort auf die genaue Frage, bietet ein schönes, einfaches sub-Fall
    InformationsquelleAutor hiquetj
  3. 1

    Nach dem hinzufügen der folgenden Methode numbersFilterüber Metaklasse , Sie können es nennen, wie folgt : 

    assert " i am a positive number 14".numbersFilter() == [ 14 ]
assert " we 12 are 20.3propaged 10.7".numbersFilter() == [ 12,20.3,10.7 ]
assert " we 12 a20.3p 10.7 ,but you can select one".numbersFilter(0) == 12
assert " we 12 a 20.3 pr 10.7 ,select one by index".numbersFilter(1) == 20.3

    Fügen Sie diesen code Wie BootStrap

    String.metaClass.numbersFilter={index=-1->
            def tmp=[];
            tmp=delegate.findAll( /-?\d+\.\d*|-?\d*\.\d+|-?\d+/ )*.toDouble()
            if(index<=-1){
                return tmp;
            }else{
                if(tmp.size()>index){
                    return tmp[index];
                }else{
                   return tmp.last();
                }
            }

}
    InformationsquelleAutor Abdennour TOUMI
Schreibe einen Kommentar