Fehler beim Überprüfen auf NULL in VBScript

Ich habe Folgendes VBScript in einer Klassischen ASP-Seite:

function getMagicLink(fromWhere, provider)
    dim url 
    url = "magic.asp?fromwhere=" & fromWhere
    If Not provider is Nothing Then ' Error occurs here
        url = url & "&provider=" & provider 
    End if
    getMagicLink = "<a target='_blank' href='" & url & "'>" & number & "</a>"
end function

Dass ich immer ein "Objekt Erforderlich" Fehlermeldung messager auf die Zeile, die sagt If Not provider Is Nothing Then.

Entweder den Wert NULL oder ist nicht NULL, also warum bin ich immer diese Fehlermeldung?

Edit: Wenn ich Sie aufrufen, das Objekt, ich pass auf entweder NULL, oder ich gehe in einen string.

InformationsquelleAutor der Frage Daniel Allen Langdon | 2013-01-24

  1. 32

    Aus dem code, es sieht aus wie provider ist eine Variante oder eine andere variable und kein Objekt.

    Is Nothing ist für Objekte, die nur, noch später werden Sie sagen, es ist ein Wert, der entweder NULL oder NICHT NULL, das behandelt werden würde, indem IsNull.

    Versuchen Sie es mit:

    If Not IsNull(provider) Then 
    url = url & "&provider=" & provider 
End if

    Alternativ, wenn das nicht funktioniert, versuchen Sie:

    If provider <> "" Then 
    url = url & "&provider=" & provider 
End if

    InformationsquelleAutor der Antwort LittleBobbyTables

  2. 19

    Sehe ich viel Verwirrung in den Kommentaren. NullIsNull() und vbNull sind hauptsächlich für die Handhabung von Datenbanken und in der Regel nicht in VBScript. Wenn es nicht ausdrücklich in der Dokumentation des aufrufenden Objekt/Daten, verwenden Sie es nicht.

    Um zu testen, ob eine variable nicht initialisiert ist, verwenden Sie IsEmpty(). Um zu testen, ob eine variable nicht initialisiert ist, oder enthält ""test auf "" oder Empty. Um zu testen, ob eine variable ein Objekt ist, verwenden Sie IsObject und zu sehen, wenn dieses Objekt keine Referenz test auf Is Nothing.

    In Ihrem Fall, Sie wollen zunächst testen, ob die variable ist ein Objekt, und dann sehen, ob die variable Nothingdenn wenn es nicht ein Objekt, bekommt man das "Objekt Erforderlich" Fehlermeldung, wenn Sie test auf Nothing.

    snippet-mix and match in deinem code:

    If IsObject(provider) Then
    If Not provider Is Nothing Then
        ' Code to handle a NOT empty object /valid reference
    Else
        ' Code to handle an empty object /null reference
    End If
Else
    If IsEmpty(provider) Then
        ' Code to handle a not initialized variable or a variable explicitly set to empty
    ElseIf provider = "" Then
        ' Code to handle an empty variable (but initialized and set to "")
    Else
        ' Code to handle handle a filled variable
    End If
End If

    InformationsquelleAutor der Antwort AutomatedChaos

  3. 0

    Werde ich fügen Sie einfach ein Leerzeichen ("") an das Ende der variable und machen Sie den Vergleich. Sowas wie unten sollte funktionieren, auch wenn die variable null ist. Sie können auch schneiden Sie die Variablen nur für den Fall von Räumen.

    If provider & "" <> "" Then 
    url = url & "&provider=" & provider 
End if

    InformationsquelleAutor der Antwort ian0411

Schreibe einen Kommentar