"FileSystemObject".CreateFolder erstellen Verzeichnis und in den Unterverzeichnissen

Ich würde gerne ein Verzeichnis anlegen und ein Unterverzeichnis mit dem folgenden code:

Public fso As Scripting.FileSystemObject
Set fso = New Scripting.FileSystemObject
fso.CreateFolder ("C:\Users\<my_username>\DataEntry\logs")

Ich versuche, erstellen von verschachtelten Verzeichnissen. In diesem Fall, die DataEntry Verzeichnis nicht existieren würde, also im Grunde genommen möchte ich 2 Verzeichnisse DataEntry\logs unter C:\Users\<username>

Wenn ich geben Sie Eingabeaufforderung kann ich das Verzeichnis mit mkdir ohne Probleme. Aber ich kann einfach nicht bekommen VBA zu erstellen, die Ordner und ich bekomme:

Run-time error '76':

Path not found

Ich bin mit Excel 2007/2010 VBA -

  • Versuchen Sie es einfach mit der mkDir Befehl.
  • Ich hab auch schon versucht, aber es funktioniert nicht. Ich glaube, ich kann auf etwas zu sein. Es scheint VBA nicht erstellen von verschachtelten Unterverzeichnissen? Ich aktualisiert meine Frage
  • Tut das erste Verzeichnis erstellt?
  • Das erste Verzeichnis nicht erstellt. Ich habe jetzt mein code geändert für die Verwendung von 2 separaten Verzeichnis Kreationen, eine für die DataEntry und eine für die logs und es scheint zu funktionieren. Es scheint VBA nicht erstellen Sie verschachtelte Verzeichnisse in einem einzigen Satz?
InformationsquelleAutor czchlong | 2015-06-24
  1. 7

    Erstellen müssen jeden Ordner ein zu einer Zeit. Verwenden Sie code wie diesen zu tun:

    Sub tgr()

    Dim strFolderPath As String
    Dim strBuildPath As String
    Dim varFolder As Variant

    strFolderPath = "C:\Users\<my_username>\DataEntry\logs"

    If Right(strFolderPath, 1) = "\" Then strFolderPath = Left(strFolderPath, Len(strFolderPath) - 1)
    For Each varFolder In Split(strFolderPath, "\")
        If Len(strBuildPath) = 0 Then
            strBuildPath = varFolder & "\"
        Else
            strBuildPath = strBuildPath & varFolder & "\"
        End If
        If Len(Dir(strBuildPath, vbDirectory)) = 0 Then MkDir strBuildPath
    Next varFolder

    'The full folder path has been created regardless of nested subdirectories
    'Continue with your code here

End Sub
    • Ich muss sagen, ich bin erstaunt, VBA ist nicht schlau genug, um den übergeordneten Verzeichnissen von selbst...
    InformationsquelleAutor tigeravatar
  2. 5

    tigeravatar Schleife beantworten könnte funktionieren, aber es ist ein bisschen schwer zu Lesen. Statt Mikromanagement der Handhabung von Strings selbst, das FileSystemObject hat Pfad-manipulation-Funktionen zur Verfügung, und die Rekursion ist etwas leichter zu Lesen als eine Schleife.

    Hier ist die Funktion die ich benutze: 

    Function CreateFolderRecursive(path As String) As Boolean
    Dim FSO As New FileSystemObject

    'If the path exists as a file, the function fails.
    If FSO.FileExists(path) Then
        CreateFolderRecursive = False
        Exit Function
    End If

    'If the path already exists as a folder, don't do anything and return success.
    If FSO.FolderExists(path) Then
        CreateFolderRecursive = True
        Exit Function
    End If

    'recursively create the parent folder, then if successful create the top folder.
    If CreateFolderRecursive(FSO.GetParentFolderName(path)) Then
        If FSO.CreateFolder(path) Is Nothing Then
            CreateFolderRecursive = False
        Else
            CreateFolderRecursive = True
        End If
    Else
        CreateFolderRecursive = False
    End If
End Function
    InformationsquelleAutor MarkD
Schreibe einen Kommentar