Finden Sie einen Wert, return die Zelle darunter (oder bis zu 4 unten), wo der erste Wert beginnt mit 1

Ich habe eine word-Datei in Excel importieren. Die Datei ist in der Spalte A, bis zu 400-500 Zeilen lang. Zur Veranschaulichung ein Beispiel:

Type application
0 shortcut
1 Client installation (standalone)
0 Client installation with data on the network (fileshare needed)
0 Client/server (server needed)
0 Webbased without dependancies
0 Webbased with dependancies
Importancy
0 Company critical
1 Important
0 Supportive

Und vielen anderen Bereichen von Interesse. Nun habe ich eine Formel, die sucht für einen bestimmten text-Wert, zum Beispiel "Produkt-manager" und gibt der Wert darunter (der name). Zur Veranschaulichung:

=INDEX(A:A;MATCH("Product manager";A:A;0)+2;1)

Hier, das +2 gibt den Namen der Produkt-manager.

Das problem ich brauche EURE Hilfe!

Das problem ist wie folgt. In dem großen code-block oben sehen Sie ein bit-Wert, mit 1 entsprechend mit der check-box angeklickt in der word-Datei. Jetzt möchte ich die Suche auf Typ Anwendung und wieder nur der Wert entsprechend der 1, also in diesem Fall 1-Client-installation (standalone -).

Die oben genannte Lösung mit INDEX und MATCH funktioniert nicht, weil es gibt nur eine bestimmte Zeile unten die Suchanfrage (also Zeile +1, Zeile +5). Ich will um den Wert zu finden Typ Anwendung, serach, die in den 6 Zeilen unten und auch wieder nur 1 Wert, es zu finden.

InformationsquelleAutor JuliusSecret | 2015-07-24

1

Folgenden am Beispiel von meine mehr illustre Kollegen, habe ich den Versuch gestartet, zur Verwendung von INDEX für diese Art von Frage, so die Antwort wäre so etwas wie dieses:-
```
=INDEX(INDEX(B$1:B$10,MATCH(D2,B$1:B$10,0)):B$10,MATCH(1,INDEX(A$1:A$10,MATCH(D2,B$1:B$10,0)):A$10,0))
```
also er findet den string (z.B. charlie) in Spalte B, und sucht den rest des Bereichs in Spalte A eine '1'.

Wenn alle Werte in einer Spalte, wie in der Frage, die Formel wird
```
=INDEX(INDEX(A$1:A$10,MATCH(D2,A$1:A$10,0)):A$10,
MATCH("1*",INDEX(A$1:A$10,MATCH(D2,A$1:A$10,0)):A$10,0))
```
Setzen, um eine Begrenzung der Bandbreite und Fehlerbehandlung sollte so etwas wie dieses:-
```
=IFERROR(
INDEX(INDEX(A:A,MATCH(D2,A:A,0)):
INDEX(A:A,MATCH(D2,A:A,0)+4),
MATCH("1*",INDEX(A:A,MATCH(D2,A:A,0)):
INDEX(A:A,MATCH(D2,A:A,0)+4),0)),
"No entry")
```
Wenn Sie wollte Suche mehr als eine Spalte in der gleichen Weise, könnten Sie die gleiche Art von Formel, aber es wäre nicht praktikabel, ohne Verwendung von hilfsspalten. So kopieren Sie es über (sagen wir) zwei Spalten, und zeigen Sie dann das erste match.

Legen Sie nach dem start der Suche in E2:-
```
=MATCH(D2,A$1:A$20,0)+1
```
Ende der Suche in F2 konnte man einfach E2+4, aber Sie können die Suche auch bis zu den nächsten 'Nummer' mit:-
```
=MATCH(1,INDEX((INDEX(A$1:A$20,E2):A$20>"2")+(INDEX(A$1:A$20,E2):A$20=""),),0)+E2-2
```
Die Suche nach einer Zelle, beginnend mit "1" in G2:-
```
=IFERROR(MATCH("1*",INDEX(A$1:A$20,$E2):INDEX(A$1:A$20,$F2),0),"")
```
und ziehen Sie über in H2 und I2.

Holen Sie sich die erste der drei matches in J2:-
```
=MIN(G2:I2)
```
Finden und welche Spalten es gilt in K2:-
```
=IF(J2=0,"",MATCH(J2,G2:I2,0))
```
Endlich die passende Zelle mit der Zeile und Spalte, in J2 und K2:-
```
=IF(K2="","No entry",INDEX(INDEX(A$1:A$20,E2):C$20,J2,K2))
```
- Ich danke Ihnen so sehr für Ihre Eingabe, und harte Arbeit für einen völlig fremden! Ich wirklich Graben diese Website. Eine Letzte Frage und dann bin ich raus. Was ist, wenn ich setzen will, wird der Suchbereich, zum Beispiel +4 Zeilen, wenn es eine bestimmte Taste? Mein Szenario enthält das zweite Bild. Einige Tasten haben vielleicht keine 1, in diesem Fall möchte ich wieder einen bestimmten Wert (zum Beispiel, "kein Eintrag"). Im moment ist es sucht, bis er findet eine Zeile, gibt eine 1 zurück, während ich nur wollen, um die Suche in den nächsten 3 von 4 oder 5 Zeilen.
- Hinzugefügt haben, auf meine Antwort. Wäre schön, wenn Sie könnten, Suche bis zu den nächsten 'wichtigsten', aber nicht wissen, wie dies zu tun 🙂
- Vielen Dank Tom Sharpe für Ihre Hilfe so weit. Ich habe noch eine Frage ich kann einfach nicht herausfinden, und ich hoffe wirklich, Sie können etwas Licht auf dieses problem. Die Sache ist die: ich will die Suche in einem bestimmten BEREICH von Zellen und Spalten. Zum Beispiel, ich Suche auf den Begriff "Anwendung". Sobald es gefunden wird, möchte ich die Suche AUS, die Zelle (z.B. A30) bis zu 5 Zeilen nach unten und 2 Spalten weiter rechts (also von der A30 bis C35) für den ERSTEN Wert zurückgibt, ein. Ich möchte, dass die ersten 1 zurückgegeben werden, mit den entsprechenden text Folgen (mit der 1 als Platzhalter).... Ich hoffe Ihr könnt mir helfen!
- Das wäre wirklich hart. Da MATCH kann nur mit einer Spalte, würden Sie wahrscheinlich brauchen einen anderen Ansatz, bei dem eine array-Formel oder VBA. Wieder zu Euch zurück kommen, wenn ich an nichts denken.
- Eigentlich ist es OK, es zu tun, aber müssen einige hilfsspalten, weil zu viel zu tun mit einer Formel. Hinzufügen, um meine Antwort.
InformationsquelleAutor Tom Sharpe
0

Sagen, wir haben Daten wie:

und wir wollen:
1. finden Puck
2. geben den ersten Wert beginnend mit "1" unter Puck
Mit Match() mit einer wildcard können, suchen Sie die Zeile mit Puck. So in C5 geben wir:
```
=MATCH("*Puck",A1:A9999,0)
```
dann verwenden wir Match() wieder zu finden, die Zeile, die beginnt mit "1". So in C6 wir geben::
```
=INDEX(A1:A9999,MATCH("1*",INDIRECT("A" & C5 & ":A9999"),0)+C5-1)
```
Natürlich das 2-Zell-Ansatz immer in einer Zelle kombiniert.
- Vielen Dank Gary für Ihre Eingabe, ist es sehr geschätzt! Ich die Lösung wählen, die zur Verfügung gestellt von Tom Sharpe, aber ich habe immer noch ein ungelöstes Lösung. Es ist geschrieben unter seine Lösung, haben Sie vielleicht eine Idee haben, wie Sie dies tun?
- Ich weiß es nicht.....Sorry.....
InformationsquelleAutor Gary's Student

Schreibe einen Kommentar

Du musst angemeldet sein, um einen Kommentar abzugeben.