Firemonkey Grid Control - Styling eine Zelle basierend auf einem Wert (über die OnGetValue function call)

Ich bin auf der Suche für empfohlenen Lösung, um Stil ein TGrid-Zelle, die gezeichnet wird durch die OnGetValue nennen (das heißt, zu malen die Zellen in der Ansicht). Für den hintergrund, eine exzellente Antwort von Mike, der zeigte, wie einfach tAlign Eigenschaft, wenn die Zelle angelegt wird; aber meine nächste Herausforderung ist die Färbung der Inhalt der Zelle.

Früheren posting/Antwort

Ziel ist die Veränderung der Zelle Attribute (Schriftart, Stil, Farbe, etc...) von dem Wert bin ich etwa wieder, wie die Zelle "Wert". In dem unten aufgeführten Beispiel; es wäre die Anwendung eines Stils auf den OnGetValue "Wert" zurückgegeben wird. Es kann gut sein, dass wir zu tun haben, das über eine FM-Stylesheet, oder können wir direkt zur TText Attribute? Im Idealfall, beide Szenarien wären toll - aber in diesem Stadium nehme ich entweder Lösung... (;->

unit Unit1;

interface

uses
  System.SysUtils, System.Types, System.UITypes, System.Classes, System.Variants,
  FMX.Types, FMX.Controls, FMX.Forms, FMX.Dialogs, FMX.Objects, FMX.Grid,
  FMX.Layouts, FMX.Edit;

type
  TForm1 = class(TForm)
    Grid1: TGrid;
    Button1: TButton;
    StyleBook1: TStyleBook;
    procedure Grid1GetValue(Sender: TObject; const Col, Row: Integer;
      var Value: Variant);
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

  TStringColNum = class(TStringColumn)
  private
    function CreateCellControl: TStyledControl; override;
  published
  end;

var
  Form1: TForm1;

implementation

{$R *.fmx}

function TStringColNum.CreateCellControl: TStyledControl;
begin
  Result:=TTextCell.Create(Self);
  TTextCell(Result).TextAlign := TTextAlign.taTrailing;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  Grid1.AddObject(TStringColumn.Create(Self));
  Grid1.AddObject(TStringColNum.Create(Self)); // Right Aligned column?

  Grid1.RowCount:=5000;
  Grid1.ShowScrollBars:=True;
end;

procedure TForm1.Grid1GetValue(Sender: TObject; const Col, Row: Integer;
  var Value: Variant);
begin
  if Col=0 then
    Value:='Row '+IntToStr(Row);

  if Col=1 then
    Value := 'Row '+IntToStr(Row);

// Apply style based on value ?

end;

end.

Vielen Dank im Voraus,
Ian.

  • Können Sie definieren ', basierend auf einem Wert'? Meinst du, sagen Sie, wenn der Wert negativ ist dann ist die Schrift rot sein usw?
  • Hallo Mike - ja, spot-on. Ich habe zwei Szenarien, aber beide sind nach dem gleichen Prinzip. Ein Szenario ist der negative Wert wird ROT dargestellt, und das andere Szenario ist zu "Fett" ein Element in der Liste (die ich wählen werden - durch off-grid-statt details; wichtige Kunden etc...). Vielen Dank im Voraus. Ian.
InformationsquelleAutor Ian | 2012-02-13
  1. 5

    Erstens eine Entschuldigung. In meiner Antwort auf Ihre Letzte Frage, CreateCellControl sollte genannt haben geerbt zu erstellen, die die Zelle. Ich habe ergänzten meine Antwort.

    Als für diese Frage, die ich hochgeladen habe, meine blog-posting auf FireMonkey-Zellen - http://monkeystyler.com/blog/entry/firemonkey-grid-basics-custom-cells-and-columns - es deckt den Stoff von der vorherigen Antwort und umfasst auch das erstellen von benutzerdefinierten Zelle steuert. Sie müssen Lesen, bevor Ihr gehen. Ich werde warten.

    ...

    Nun zurück? Gut.

    Folgenden auf das Beispiel in dem blog-post.

    Außer, dass ich schon aktualisiert, die TFinancialCell Erben direkt von TTextCell (das ist natürlich ein TEdit), das macht weit mehr Sinn und ist wesentlich einfacher zu stylen ist.

    So, update der TFinancialCell:

    type TFinancialCell = class(TTextCell)
  private
    FIsNegative: Boolean;
    FIsImportant: Boolean;
  protected
    procedure SetData(const Value: Variant); override;
    procedure ApplyStyle;override;
    procedure ApplyStyling;
  public
    constructor Create(AOwner: TComponent); override;
  published
    property IsNegative: Boolean read FIsNegative;
    property IsImportant: Boolean read FIsImportant;
  end;

    Code für die oben:

    procedure TFinancialCell.ApplyStyle;
var T: TFMXObject;
begin
  inherited;
  ApplyStyling;
end;

procedure TFinancialCell.ApplyStyling;
begin
  if IsNegative then
    FontFill.Color := claRed
  else
    FontFill.Color := claBlack;
  Font.Style := [TFontStyle.fsItalic];
  if IsImportant then
    Font.Style := [TFontStyle.fsBold]
  else
    Font.Style := [];
  if Assigned(Font.OnChanged) then
    Font.OnChanged(Font);
  Repaint;
end;

constructor TFinancialCell.Create(AOwner: TComponent);
begin
  inherited;
  TextAlign := TTextAlign.taTrailing;
end;

procedure TFinancialCell.SetData(const Value: Variant);
var F: Single;
  O: TFMXObject;
  S: String;
begin
  S := Value;
  FIsImportant := S[1] = '#';
  if IsImportant then
    S := Copy(Value,2,MaxInt)
  else
    S := Value;

  F := StrToFloat(S);
  inherited SetData(Format('%m', [F]));
  FIsNegative := F < 0;
  ApplyStyling;
end;

    Und schließlich, aktualisieren Sie die GetValue-event-handler:

    procedure TForm1.Grid1GetValue(Sender: TObject; const Col, Row: Integer;
  var Value: Variant);
var Cell: TStyledControl;
begin
  if Col = 0 then
    Value := Row
  else if Col = 1 then
  begin
    Value := FloatToStr(Data[Row]);
    if Value > 30 then
      Value := '#'+Value;
  end;
end;
    • Hallo Mike, nochmals vielen Dank für das Beispiel, Sie sind in der Tat die "TGrid-guru". Den blog - /board-post sind hervorragend und sehr gut präsentiert. Ich habe es geschafft, Folgen Ihr überarbeitet/bearbeitet Beispiel und Holen Sie sich die Fett und rot arbeiten gut. - Vielen Dank nochmal; ein wahrer gent...! Ian. (PS. Gibt es eine Möglichkeit, Recht-richten Sie die überschrift der Spalte, als auch mit der gleichen Methodik für die TFinancial Spalten..?)
    • Hallo Mike - eine leichte Frage, die ich stellte fest, in Bezug auf die oben genannten? Sieht alles gut aus, bis ich das Fenster scrollen. Wenn es Schriftrollen, die rot/Fett gehen out of line/sync. Ich bin nicht sicher, ob es ein repaint Problem mit FM-oder etwas anderes? Ich kann nach meinem code, wenn Ihr in Ordnung? Thx im Voraus, Ian.
    • Mein schlechtes. Styling muss erneuert werden, von der SetData-Methode, so habe ich aktualisiert, die obigen code zu extrahieren, eine ApplyStyles-Methode, und rufen Sie es von ApplyStyle, SetData und SetIsImportant.
    • Wie für den Kopf, sollte es einfach sein. In den Spalten Konstruktor hinzufügen, wenn die (Netz - <> nil) und (Grid.FHeader <> nil) dann Grid.FHeader.Items[Index].TextAlign := TTextAlign.alTrailing; - Aber Fheader ist ein privates Mitglied, so müssen Sie Unterklasse TGrid zu setzen. (Und das TColumn nicht aussetzen, entweder - es ist die Header-Eigenschaft ist einfach ein string, kein THeader).
    • Danke für das Bearbeiten, kein problem. Ich noch zu bekommen scheinen ein seltsames Problem, wenn ich scrolle jedoch, dass einige der Werte sind Fett gelegentlich beim scrollen, wenn du dann Blättern Sie zurück - Sie sind es nicht? Ich hatte auch die Veränderung des "ApplyStyling" zu "TFinancialCell.ApplyStyling"; war das richtig - oder habe ich das Problem verursachen? - Thx Ian.
    • Hallo Mike, vielleicht habe ich entdeckt, was die Ursache für die redraw-Problem für mich in meinem Beispiel (könnte ein FM bug?). Wenn Sie mit der Maus Blättern (Rad) die grid content; dann funktioniert es, wie Sie entworfen. Wenn Sie ziehen Sie die scroll - Leiste nicht? - Nicht sicher, ob das hilft?
    • Oops. Ich habe nicht bemerkt, dass man. So, die CellFromIndex Zeug funktioniert nicht an diesem Punkt. Die nächste option (z.B. pro aktualisiert code oben) ist zu pass " - Wert als string, und voranstellen eines # - char, um anzuzeigen, Fett Element. Eine andere alternative wäre, ein Ereignis hinzufügen, um Ihre Zellen-Klasse, die müssten eingestellt werden, indem die CreateCellControl Ihrer Spalte (was natürlich braucht ein zusätzliches Ereignis-Eigenschaft). Rufen Sie das Ereignis aus der SetData-Methode und es können alle Eigenschaften der Zelle, die Sie ändern wollen. Oder übergeben Sie ein Objekt als Ergebnis von GetValue und entpacken Sie es in SetData.
    • Arbeitete - vielen Dank für ausdauernd, Mike. Die TGrid ist eine schnelle Kontrolle; aber auf jeden Fall ein FM-v1.0-Kontrolle. - Superstar...!

    InformationsquelleAutor Mike Sutton
  2. 1

    Code oben ist in Ordnung für Versionen vor XE4, aber für XE4 und XE5 funktioniert nicht. Farbe und Stil der text wird nicht geändert.

    Dies ist ein fester code für XE4 und XE5:

    procedure TFinancialCell.ApplyStyling;
begin
  StyledSettings := [TStyledSetting.ssFamily, TStyledSetting.ssSize];
  if IsNegative then
    FontColor := claRed
  else
    FontColor := claBlack;
  Font.Style := [TFontStyle.fsItalic];
  if IsImportant then
    Font.Style := [TFontStyle.fsBold]
  else
    Font.Style := [];
  if Assigned(Font.OnChanged) then
    Font.OnChanged(Font);
  Repaint;
end;
    InformationsquelleAutor Alex Egorov
Schreibe einen Kommentar